Si të bashkoni shpejt artikujt nga dosje të shumta pa dublikatë në Outlook

Zgjidhjet e Outlook Shtator 29, 2025

Nëse dëshironi të bashkoni të gjithë artikujt nga dosje të shumta të Outlook dhe të siguroheni që të mos ketë dublikatë, mund të përdorni metodën e prezantuar në këtë artikull. Ai po përdor kodin VBA për t'ju ndihmuar ta përmbushni atë si një tapë.

Bashkoni shpejt artikujt nga dosje të shumta pa dublikatë në Outlook

Ndonjëherë, mund të dëshironi të bashkoni artikuj nga disa dosje të Outlook, si p.sh. bashkimi i të gjitha kontakteve të disa dosjeve të kontakteve të Outlook. Në këtë situatë, nëse ka disa kontakte të dyfishta midis këtyre dosjeve, duhet të shpresoni që dublikatat mund të hiqen automatikisht gjatë bashkimit. Në këtë rrethanë, ju mund të përdorni kodin e mëposhtëm VBA për ta realizuar atë me lehtësi.

Bashkoni artikujt nga dosje të shumta pa dublikatë

  1. Të start me, nisni aplikacionin tuaj Outlook.
  2. Më pas, duhet të hyni në redaktuesin VBA të Outlook duke shtypur butonin "Alt + F11" në ekranin kryesor të Outlook.
  3. Më pas, në dritaren "Microsoft Visual Basic për Aplikacione", duhet të hapni një modul që nuk po përdoret.
  4. Pas kësaj, duhet të kopjoni kodin e mëposhtëm VBA në këtë modul.
'Here we take "merging two folders" as an example
Sub MergeOutlookFolders_WithoutDuplicates()
    Dim objSourceFolder As Outlook.Folder
    Dim objTargetFolder As Outlook.Folder
    Dim i, n, x As Long
    Dim objItem As Object
    Dim objDictionary As Object
    Dim strKey As String
 
    Set objSourceFolder = Application.Session.PickFolder
    Set objTargetFolder = Application.Session.PickFolder

    If objSourceFolder.DefaultItemType <> objTargetFolder.DefaultItemType Then
       MsgBox "Error: The two folders are not in same type!", vbExclamation + vbOKOnly
    Else
       'Merge the two folders
       For i = objSourceFolder.Items.count To 1 Step -1
           Set objItem = objSourceFolder.Items.Item(i)
           objItem.Move objTargetFolder
       Next i
 
       Set objDictionary = CreateObject("scripting.dictionary")
 
       'Remove the duplicates
       x = 0
       For n = objTargetFolder.Items.count To 1 Step -1
           Set objItem = objTargetFolder.Items.Item(n)
 
           Select Case objItem.Class
                  Case olMail
                       strKey = objItem.Subject & "," & objItem.Body & "," & objItem.SentOn
                  Case olAppointment
                       strKey = objItem.Subject & "," & objItem.Start & "," & objItem.Duration & "," & objItem.Location & "," & objItem.Body
                  Case olContact
                       strKey = objItem.FullName & "," & objItem.Email1Address & "," & objItem.Email2Address & "," & objItem.Email3Address
                  Case olTask
                       strKey = objItem.Subject & "," & objItem.StartDate & "," & objItem.DueDate & "," & objItem.Body
           End Select
 
           strKey = Replace(strKey, ", ", Chr(32))
 
           If objDictionary.Exists(strKey) = True Then
              objItem.Delete
              x = x + 1
           Else
              objDictionary.Add strKey, True
           End If
      Next n
 
      'Prompt you of the count of removed duplicates
      If x <> 0 Then
         MsgBox x & " duplicates removed when merging!", vbInformation + vbOKOnly
      End If
    End If
End Sub

Kodi VBA - Bashkoni artikujt nga dosje të shumta pa dublikatë

  1. Më vonë duhet të kontrolloni cilësimet e makrove të Outlook, duke u siguruar që makroja është aktivizuar.
  2. Më në fund mund të provoni.
  • Së pari, kthehuni te dritarja e modulit të ri.
  • Më pas shtypni butonin e tastit F5 për të aktivizuar këtë makro.
  • Pastaj ju duhet të zgjidhni dy dosjet që do të bashkohen. E para është burimi, dhe e dyta është ajo tarMerr një.
  • Pas kësaj, Outlook do të fillojë të lëvizë të gjithë artikujt nga dosja burimore në tarMerr një. Gjithashtu, ndërkohë, dublikatat do të hiqen automatikisht.
  • Në fund të fundit, mund të merrni një mesazh që kërkon numërimin e dublikatave të hequra, si pamja e ekranit më poshtë:Mesazh që kërkon numërimin e dublikatave të hequra

Gabimet e vogla mund të çojnë në përplasje të mëdha

Pavarësisht se është i ngarkuar me shumë funksione të shkëlqyera, Outlook është ende i ndjeshëm ndaj gabimeve dhe korrupsionit. Ndoshta ju keni hasur probleme të ndryshme të Outlook. Shumë përdorues janë të prirur të injorojnë gabimet e rastësishme. Megjithatë, është gabimi i vogël që shkakton përplasje serioze të Outlook, të cilat do të rrezikojnë skedarin e Outlook. Prandaj, nuk duhet të shpërfillni asnjë gabim të vogël. Në vend të kësaj, ju duhet t'i eliminoni ato sa më shpejt të jetë e mundur. Për më tepër, është më mirë të mbani një prirje Riparimi i PST mjet, si p.sh DataNumen Outlook Repair. Nëpërmjet shkallës së lartë të rikuperimit, ky shërbim ka kaluar mbi kolegët e tij.

Hyrje e autorit:

Shirley Zhang është një eksperte për rikuperimin e të dhënave DataNumen, Inc., e cila është lider botëror në teknologjitë e rikuperimit të të dhënave, duke përfshirë sql i korruptuar dhe produkte softuerike të riparimit të pamjes. Për më shumë informacion vizitoni www.datanumen.com

Komentet janë të mbyllura.