Si të përdorni automatikisht ngjyra të ndryshme të shkronjave për përgjigjen dhe përcjelljen e emaileve me Outlook VBA

Zgjidhjet e Outlook Shtator 29, 2025

Si parazgjedhje, nuk mund të lejoni që Outlook automatikisht të përdorë ngjyra të ndryshme të shkronjave për t'u përgjigjur dhe përcjellë emailet. Prandaj, nëse keni një kërkesë të tillë, mund të lexoni këtë fqost për të mësuar një qasje të zgjuar.

Outlook ju lejon vetëm të specifikoni një font të përdorur si për përgjigjen ashtu edhe për përcjelljen e emaileve. Mund të shkoni te "File" > "Opsione". Më pas, në "Opsionet e Outlook", kthehuni te skeda "Mail" dhe klikoni butonin "Stationery and Fonts...". Në dritaren pasuese, mund të shihni butonin "Font" në "Përgjigja ose përcjellja e mesazheve". Klikoni mbi të dhe më pas mund të vendosni një ngjyrë specifike fonti për përgjigjen dhe përcjelljen e emaileve.

Ndryshoni fontin në përgjigjen ose përcjelljen e mesazheve

Megjithatë, shumë përdorues shpresojnë të përdorin ngjyra të ndryshme të shkronjave për t'u përgjigjur ose përcjellë emailet. Megjithëse Outlook nuk ofron ndonjë veçori të drejtpërdrejtë për këtë, ai ende mund të realizohet me kodin VBA. Tani, lexoni për të marrë një pjesë të tillë të kodit VBA.

Përdorni automatikisht ngjyra të ndryshme të shkronjave për përgjigjen dhe përcjelljen e emaileve

  1. Për sitart, hapni aplikacionin Outlook.
  2. Pastaj, aktivizoni redaktorin VBA duke iu referuar "Si të ekzekutoni kodin VBA në Outlook tuaj".
  3. Më pas, në përputhje me "Si të shtoni një Object Library Referenca në VBA“, shtoni referencën te “MS Word Object LibrarY".
  4. Më pas, kopjoni kodin e mëposhtëm në projektin "ThisOutlookSession".
Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objMail As Outlook.MailItem

Private Sub Application_Startup()
    Set objInspectors = Outlook.Application.Inspectors
    Set objExplorer = Outlook.Application.ActiveExplorer
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If TypeOf Inspector.CurrentItem Is MailItem Then
       Set objMail = Inspector.CurrentItem
    End If
End Sub

Private Sub objExplorer_SelectionChange()
    On Error Resume Next
    If TypeOf objExplorer.Selection.Item(1) Is MailItem Then
       Set objMail = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objMail_Reply(ByVal Response As Object, Cancel As Boolean)
    Dim objReply As Outlook.MailItem
    Dim objReplyDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objReply = objMail.Reply
    objReply.Display
    Set objReplyDoc = objReply.GetInspector.WordEditor
    objReplyDoc.Range(0, 0).Select
    Set objDocSelection = objReplyDoc.Application.Selection
    'Use "Pink" font in "Reply"
    objDocSelection.Font.ColorIndex = wdPink
End Sub

Private Sub objMail_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Dim objReplyAll As Outlook.MailItem
    Dim objReplyAllDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objReplyAll = objMail.ReplyAll
    objReplyAll.Display
    Set objReplyAllDoc = objReplyAll.GetInspector.WordEditor
    objReplyAllDoc.Range(0, 0).Select
    Set objDocSelection = objReplyAllDoc.Application.Selection
    'Use "Green" font in "Reply All"
    objDocSelection.Font.ColorIndex = wdGreen
End Sub

Private Sub objMail_Forward(ByVal Forward As Object, Cancel As Boolean)
    Dim objForward As Outlook.MailItem
    Dim objForwardDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objForward = objMail.Forward
    objForward.Display
    Set objForwardDoc = objForward.GetInspector.WordEditor
    objForwardDoc.Range(0, 0).Select
    Set objDocSelection = objForwardDoc.Application.Selection
    'Use "Blue" font in Forward
    objDocSelection.Font.ColorIndex = wdBlue
End Sub

Kodi VBA - Përdorni automatikisht ngjyra të ndryshme të shkronjave për përgjigjen dhe përcjelljen e emaileve

  1. Pas kësaj, restart Outlook për të aktivizuar këtë makro.
  2. Më në fund, mund të provoni.
  • Zgjidhni ose hapni një email.
  • Më pas, klikoni në butonin "Përgjigju". Në përgjigjen e emailit, mund të shkruani disa fjalë në trup. Ngjyra e shkronjave duhet të jetë rozë.Fonti "Rozë" në "Përgjigje"
  • Ose klikoni në butonin "Përgjigju të gjithëve". Në postën e re "përgjigje ndaj të gjithëve", futni fjalët në trup. Ngjyra e shkronjave është me siguri jeshile.Fonti "Green" në "Përgjigju të gjithëve"
  • Në mënyrë të ngjashme, klikoni butonin "Përpara". Në postën e dërguar, fjalët e reja do të shfaqen me blu.Fonti "Blu" në "Përpara"

Përdorni një softuer të besueshëm

Në rast të Perspektiva e korrupsionit, Most përdoruesit priren t'i drejtohen softuerit të rimëkëmbjes Outlook. Ekzistojnë një numër i madh i programeve të tilla në treg. Dhe disa prej tyre janë edhe pa pagesë. Megjithatë, ju duhet të keni kujdes nga ata që vijnë nga burime të panjohura, sepse ato mund ta përkeqësojnë dhe përkeqësojnë rastin aktual. Ju duhet të merrni ndihmën e një mjeti të besueshëm dhe me përvojë, si p.sh DataNumen Outlook Repair.

Hyrje e autorit:

Shirley Zhang është një eksperte për rikuperimin e të dhënave DataNumen, Inc., e cila është lider botëror në teknologjitë e rikuperimit të të dhënave, duke përfshirë sql i korruptuar dhe produkte softuerike të riparimit të pamjes. Për më shumë informacion vizitoni www.datanumen.com

Komentet janë të mbyllura.