Si të eksportoni strukturën e dosjeve të skedarit tuaj Outlook në Excel

Nëse dëshironi të eksportoni shpejt strukturën e dosjeve të skedarit tuaj të të dhënave Outlook në një libër pune në Excel, mund të përdorni metodën e prezantuar në këtë artikull.

Për disa arsye, të tilla si regjistrimi i dosjeve dhe nëndosjeve aktuale të Outlook, shumë përdorues shpresojnë të eksportojnë strukturën e dosjeve të një skedari Outlook në një skedar të jashtëm, si një libër pune në Excel. Në vijim, ne do t'ju ndajmë një pjesë të kodit VBA, i cili mund t'ju ndihmojë ta arrini atë në një moment.

Eksportoni strukturën e dosjeve të skedarit tuaj Outlook në Excel

1. Për të filluar, hapni aplikacionin tuaj Outlook.
2. Pastaj, në dritaren kryesore të Outlook, shtypni butonat "Alt + F11".
3. Më pas, do të futeni në redaktorin VBA të Outlook, në të cilin duhet të hapni një modul të papërdorur.
4. Më pas, mund të kopjoni kodin e mëposhtëm VBA në këtë modul.

Dim objExcelApp As Excel.Application
Dim objExcelWorkbook As Excel.Workbook
Dim objExcelWorksheet As Excel.Worksheet
Dim lMainFolder As Long

Sub ExportFolderStructureToExcel()
    Dim objSourcePSTFile As Folder
 
    'Add a new Excel workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
 
    With objExcelWorksheet
         .Cells(1, 1) = "Folder Structure"
         .Cells(1, 1).Font.Size = 14
         .Cells(1, 1).Font.Bold = True
    End With
 
    'Select an Outlook PST file
    Set objSourcePSTFile = Application.Session.PickFolder
 
    lMainFolder = Len(objSourcePSTFile.FolderPath) - Len(Replace(objSourcePSTFile.FolderPath, "\", "")) + 1
 
    Call ExportToExcel(objSourcePSTFile.FolderPath, objSourcePSTFile.Name)
    Call ProcessFolders(objSourcePSTFile.Folders)
 
    'Save this Excel workbook
    objExcelWorksheet.Columns("A").AutoFit
    strExcelFile = "E:\Folder Structure (" & Format(Now, "yyyymmddhhmmss") & ").xlsx"
    objExcelWorkbook.Close True, strExcelFile

    MsgBox "Complete!", vbExclamation
End Sub

Sub ProcessFolders(ByVal objFolders As Folders)
    Dim objFolder As Folder
 
    'Process all folders recursively
    For Each objFolder In objFolders
        If objFolder.Name <> "Conversation Action Settings" And objFolder.Name <> "Quick Step Settings" Then
           Call ExportToExcel(objFolder.FolderPath, objFolder.Name)
           Call ProcessFolders(objFolder.Folders)
        End If
    Next
End Sub

Sub ExportToExcel(ByRef strFolderPath As String, strFolderName As String)
    Dim i, n As Long
    Dim strPrefix As String
    Dim nLastRow As Integer
 
    i = Len(strFolderPath) - Len(Replace(strFolderPath, "\", ""))
    For n = lMainFolder To i
        strPrefix = strPrefix & "-"
    Next
    strFolderName = strPrefix & strFolderName
 
    'Input the folder name in Excel
    nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
    objExcelWorksheet.Range("A" & nLastRow) = strFolderName
End Sub

5. Pas kësaj, duhet të siguroheni që Outlook të ketë aktivizuar makro.
6. Më në fund, mund të bëni një goditje:

• Në dritaren aktuale makro, shtypni butonin e tastit F5.
• Pas përfundimit të makro, do të merrni një alarm që kërkon "Përfundo".
• Më vonë, mund të shkoni te dosja e paracaktuar lokale për të gjetur një skedar të ri Excel. Hapeni atë dhe do të duket si pamja e mëposhtme e ekranit:

Asnjëherë mos shpërfillni gabimet e Outlook

Pavarësisht nga sasitë e aftësive, Outlook është po aq i ndjeshëm ndaj gabimeve dhe korrupsionit si klientët e tjerë të postës elektronike. Prandaj, duhet t'i kushtoni rëndësi të gjitha gabimeve në Outlook tuaj. Mos i shpërfillni, ju lutem. Përndryshe, akumulimi i gabimeve mund të çojë më në fund në korrupsionin e Outlook. Nëse ballafaqoheni me gabime me nyje, sugjerohet përdorimi i një mjeti të fuqishëm, si p.sh DataNumen Outlook Repair, të cilat munden riparimi i Outlook gabime brenda sekondave.

Hyrje e autorit:

Shirley Zhang është një eksperte për rikuperimin e të dhënave DataNumen, Inc., e cila është lider botëror në teknologjitë e rikuperimit të të dhënave, duke përfshirë shërim sql dhe produkte softuerike të riparimit të pamjes. Për më shumë informacion vizitoni www.datanumen.com