6 mënyra për të mbajtur bashkëngjitjet origjinale të emailit kur përgjigjeni në Outlook

Shumë përdorues shpresojnë të konfigurojnë Outlook-in e tyre për të mbajtur bashkëngjitjet origjinale të emailit kur i përgjigjen një emaili. Ky artikull do të ekspozojë 5 zgjidhje, si dhe një mënyrë të zgjuar, e cila është përdorimi i VBA për ta realizuar atë automatikisht.

Kam dëgjuar një numër të madh përdoruesish që ankohen se Outlook nuk ka një veçori origjinale për të mbajtur bashkëngjitjet origjinale kur i përgjigjen një emaili. Prandaj, këtu do t'ju ndajmë 6 metoda, njëra prej të cilave është mjaft e dobishme pasi përdor VBA për të bërë Outlook të bashkëngjisë automatikisht bashkëngjitjet origjinale në emailin që përgjigjet. Tani lexoni për t'i marrë ato në detaje.

1. Përgjigju me email origjinal të bashkangjitur

Megjithëse Outlook nuk ofron një veçori për mbajtjen e bashkëngjitjeve origjinale të emailit kur i përgjigjen një emaili, ai i lejon përdoruesit të mbajnë të bashkangjitur emailin origjinal. Prandaj, është një zgjidhje opsionale për ju. Mund të shkoni te "Skedari" > "Opsionet" > "Mail" > "Përgjigjet dhe përcjelljet" seksioni për të ndryshuar cilësimet e përgjigjes. Për më shumë detaje, ju sugjerojmë t'i referoheni artikullit tim të mëparshëm - "5 hapa për t'u përgjigjur me bashkëngjitjet origjinale në Outlook“. Por, nëse ende shpresoni të mbani vetëm bashkëngjitjet origjinale, vazhdoni të mësoni mjetet e tjera.

2. Tërhiq dhe lësho me dorë bashkëngjitjet

1. Për të filluar, klikoni dy herë mbi një email të tillë burimor për ta hapur atë në dritaren e vet.
2. Pastaj klikoni në butonin "Përgjigju", i cili do të shfaqë emailin që përgjigjet.
3. Më pas duhet t'i tkurni të dy dritaret e mesazheve derisa t'i shihni në të njëjtin ekran.
4. Pas kësaj, zgjidhni të gjitha bashkëngjitjet në emailin origjinal.
5. Së fundi, tërhiqni dhe lëshoni ato në rreshtin "Bashngjitur" në emailin që ju përgjigjeni.

3. Kopjoni dhe ngjisni manualisht bashkëngjitjet

1. Në radhë të parë, pasi hapni emailin burimor, zgjidhni të gjitha bashkëngjitjet.
2. Pastaj klikoni butonin "Kopjo" nën skedën "Bashkëngjitjet".
3. Pas kësaj, klikoni butonin "Përgjigju" nën skedën "Mesazhi" për të hapur një postë përgjigjeje.
4. Në fund të fundit, në emailin që ju përgjigjeni, klikoni në rreshtin "Bashngjitur" dhe shtypni butonin "Ctrl + V" për të ngjitur bashkëngjitjet e kopjuara më parë.

4. Përcillni Email dhe Plotësoni Marrësin

1. Fillimisht, zgjidhni një email të tillë dhe më pas klikoni butonin "Përpara" në fjongo.
2. Në dritaren e sapohapur të Mesazhit, mbahen bashkëngjitjet origjinale. Tani duhet të plotësoni fushën "Për" dërguesit të emailit origjinal.
3. Opsionale, mund ta ndryshoni temën sipas nevojave tuaja.

5. Ridërgojeni këtë email dhe ndryshoni marrësit

1. Për të filluar, hapni emailin burimor.
2. Pastaj klikoni në butonin "Veprimet" në grupin "Lëviz".
3. Pastaj zgjidhni "Ridërgo këtë mesazh" nga lista rënëse.
4. Ndoshta do të merrni një alarm duke përmendur se ju nuk jeni dërguesi origjinal. Thjesht injorojeni dhe shtypni "Po".
5. Në emailin e ri pasues, duhet të modifikoni fushën "Për" tek dërguesi i emailit origjinal.
6. Gjithashtu, mos harroni të ndryshoni dërgimin duke përdorur llogarinë e emailit në llogarinë tuaj.

6. Shtoni automatikisht bashkëngjitjet origjinale nëpërmjet VBA

Të gjitha qasjet e përmendura më lart, për të qenë i sinqertë, janë zgjidhje. Nëse shpresoni se Outlook mund të mbajë automatikisht bashkëngjitjet origjinale kur përgjigjeni, mund ta përdorni këtë mënyrë.

1. Në dritaren kryesore të Outlook, shtypni butonat "Alt + F11".
2. Më pas, në dritaren "Microsoft Visual Basic për Aplikacione", kopjoni kodin VBA më poshtë në projektin "ThisOutlookSession".

Private WithEvents objExplorer As Outlook.Explorer
Private WithEvents objInspectors As Outlook.Inspectors
Private WithEvents objMail As Outlook.MailItem

Private Sub Application_Startup()
    Set objExplorer = Outlook.Application.ActiveExplorer
    Set objInspectors = Outlook.Application.Inspectors
End Sub

Private Sub objExplorer_Activate()
    On Error Resume Next
    If TypeName(objExplorer.Selection.Item(1)) = "MailItem" Then
       Set objMail = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If TypeName(Inspector.CurrentItem) = "MailItem" Then
       Set objMail = Inspector.CurrentItem
    End If
End Sub

'Occurs when clicking "Reply" button
Private Sub objMail_Reply(ByVal Response As Object, Cancel As Boolean)
    Call KeepOriginalAttachments(objMail, Response)
End Sub

'Occurs when clicking "Reply All" button
Private Sub objMail_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Call KeepOriginalAttachments(objMail, Response)
End Sub

Private Sub KeepOriginalAttachments(ByVal objOriginalMail As MailItem, objReply As Object)
    Dim strEnviro As String
    Dim strTempFolder As String
    Dim strFilePath As String
    Dim objAttachment As Outlook.Attachment
 
    'Get the temp folder in Windows
    strEnviro = CStr(Environ("USERPROFILE"))
    strTempFolder = strEnviro & "\AppData\Local\Temp"
 
    For Each objAttachment In objOriginalMail.Attachments
        'Skip the embedded image attachments
        If IsEmbeddedAttachment(objAttachment) = False Then
           strFilePath = strTempFolder & "\" & objAttachment.filename
           objAttachment.SaveAsFile strFilePath
 
           'Attach the temporarily saved attachments to the Reply
           objReply.Attachments.Add strFilePath
 
           'Delete the temporarily saved attachments
           Kill strFilePath
       End If
    Next
End Sub

'Function for checking if an attachment is embedded image attachment
Function IsEmbeddedAttachment(objCurrentAttachment As Outlook.Attachment) As Boolean
    Dim objPropertyAccessor As Outlook.propertyAccessor
    Dim strProperty As String
 
    Set objPropertyAccessor = objCurrentAttachment.propertyAccessor
    strProperty = objPropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x3712001E")
 
    If InStr(1, strProperty, "@") > 0 Then
       IsEmbeddedAttachment = True
    Else
       IsEmbeddedAttachment = False
    End If
End Function

3. Më vonë nënshkruani këtë makro dhe ndryshoni cilësimet e makrove të Outlook për të lejuar makrotë e nënshkruara.
4. Pas kësaj, rinisni aplikacionin tuaj Outlook për të aktivizuar këtë projekt VBA.
5. Tani e tutje, çdo herë kur klikoni butonin "Përgjigju". Email-i në përgjigje do të shfaqet menjëherë me bashkëngjitjet origjinale.

Përdorni një mjet të shquar riparimi

Outlook ka mbështetur klientët e tjerë të postës elektronike për shkak të karakteristikave të shumta të tij. Por është ende e prirur ndaj korrupsionit. Prandaj, duhet t'i kushtoni më shumë vëmendje shëndetit të tij. Në përgjithësi, kur hasni probleme të vogla, thjesht mund të ktheheni te programi i integruar i riparimit. Megjithatë, nëse vuani nga telashe serioze, është më mirë të ktheheni te një mjet shumë më i aftë, si p.sh DataNumen Outlook Repair. Mundet rregulloni Outlook skedar në një çast.

Hyrje e autorit:

Shirley Zhang është një eksperte për rikuperimin e të dhënave DataNumen, Inc., e cila është lider botëror në teknologjitë e rikuperimit të të dhënave, duke përfshirë rregullim sql dhe produkte softuerike të riparimit të pamjes. Për më shumë informacion vizitoni www.datanumen.com