Si të dërgoni të gjitha fletët e punës në një libër pune në Excel si email të veçantë të Outlook

Nëse dëshironi të dërgoni të gjitha fletët e punës në një libër pune Excel si email të veçantë të Outlook, mund të përdorni metodën e prezantuar në këtë artikull. Mund t'ju udhëzojë që ta realizoni me shumicë pa e dërguar në mënyrë të mundimshme një nga një.

Në postimin tim të mëparshëm ""2 Metoda të shpejta për të dërguar një fletë pune në Excel si një email të Outlook", mund të mësoni dy mënyra për të dërguar një fletë pune Excel si email. Nëse dëshironi të dërgoni në grup të gjitha fletët e punës në një libër pune si emaile individuale, përdorimi i njërës prej dy mjeteve të përmendura në atë postim do të jetë mjaft i lodhshëm dhe problematik. Kështu, këtu do të prezantojmë një mënyrë tjetër, e cila mund të realizojë një "Dërgim Grumbull" të tillë në një kohë të shpejtë.

Dërgoni në grup të gjitha fletët e punës në një libër pune në Excel si email të veçantë

1. Në radhë të parë, duhet të hapni librin burimor të Excel-it.
2. Pastaj, pasi të keni hyrë në dritaren e Excel, duhet të klikoni në shkurtoret e tastit "Alt + F11".
3. Më pas, do të shfaqet një dritare tjetër e quajtur "Microsoft Visual Basic për aplikacione".
4. Në të, ju duhet të hapni një modul të papërdorur ose të futni një modul të ri.
5. Më pas, mund të kopjoni kodin e mëposhtëm VBA në këtë modul.

Sub SendEachWorksheet_inOutlookEmail()
    Dim objWorksheet As Excel.Worksheet
    Dim objRange As Excel.Range
    Dim objTempWorkbook As Excel.Workbook
    Dim objTempWorksheet As Excel.Worksheet
    Dim strTempFolder As String
    Dim strHTMLFile As String
    Dim objHTMLFile As Object
    Dim objFileSystem As Object
    Dim objTextStream As Object
    Dim objOutlookApp As Outlook.Application
    Dim objMail As Outlook.MailItem
 
    For Each objWorksheet In ActiveWorkbook.Sheets
        Set objRange = objWorksheet.UsedRange
        objRange.Copy
 
        Set objTempWorkbook = Excel.Application.Workbooks.Add(1)
        Set objTempWorksheet = objTempWorkbook.Sheets(1)
        With objTempWorksheet.Cells(1)
             .PasteSpecial xlPasteValues
             .PasteSpecial xlPasteColumnWidths
             .PasteSpecial xlPasteFormats
        End With
 
        strTempFolder = CStr(Environ("USERPROFILE")) & "\AppData\Local\Temp"
        strHTMLFile = strTempFolder & "\Temp" & Format(Now, "yyyymmddhhmmss") & ".htm"
        Set objHTMLFile = objTempWorkbook.PublishObjects.Add(xlSourceRange, strHTMLFile, objTempWorksheet.Name, objTempWorksheet.UsedRange.Address)
        objHTMLFile.Publish (True)
 
        Set objOutlookApp = CreateObject("Outlook.Application")
        Set objMail = objOutlookApp.CreateItem(olMailItem)
 
        Set objFileSystem = CreateObject("Scripting.FileSystemObject")
        Set objTextStream = objFileSystem.OpenTextFile(strHTMLFile)
        objMail.HTMLBody = objTextStream.ReadAll
 
        'Change the email details as per your needs
        With objMail
             .To = "test@datanumen.com"
             .Subject = objWorksheet.Name
             .Display
        End With
 
        objTextStream.Close
        objTempWorkbook.Close False
        Kill strHTMLFile
    Next
End Sub

6. Pas kësaj, mund ta aktivizoni këtë makro duke shtypur butonin e tastit F5 ose duke klikuar ikonën "Run" në shiritin e veglave.
7. Menjëherë, emailet, të cilat korrespondojnë me të gjitha fletët e punës në këtë libër pune në Excel, do të shfaqen në Outlook.
8. Së fundi, mund të rishikoni të gjitha detajet e emaileve dhe në fund të klikoni butonin "Dërgo" për t'i dërguar emailet.

Aplikoni një mjet të fuqishëm rikuperimi nëse nuk ka kopje rezervë

Gjithnjë e më shumë përdorues e kanë kuptuar rëndësinë e kopjeve rezervë të të dhënave. Për sa kohë që keni rezervuar skedarin tuaj PST, Rimëkëmbja e PST pas dëmtimit do të jetë mjaft i thjeshtë. Por nëse nuk ka një kopje rezervë efektive dhe të përditësuar të PST-së, nuk keni zgjidhje tjetër veçse të merrni ndihmën e një mjeti të jashtëm riparimi PST, si p.sh. DataNumen Outlook Repair. Mund të riparojë skedarët e komprometuar PST si një fllad.

Hyrje e autorit:

Shirley Zhang është një eksperte për rikuperimin e të dhënave DataNumen, Inc., e cila është lider botëror në teknologjitë e rikuperimit të të dhënave, duke përfshirë rikuperoni sql dhe produkte softuerike të riparimit të pamjes. Për më shumë informacion vizitoni www.datanumen.com