Si të hiqni bashkëngjitjet nga artikujt e vjetëruar të kalendarit në Outlook tuaj

Nëse dëshironi të hiqni bashkëngjitjet nga takimet dhe takimet e vjetruara në Outlook, mund ta lexoni këtë artikull. Këtu do t'ju prezantojmë se si ta realizoni atë me një hap.

Për të zvogëluar madhësinë e skedarit tuaj Outlook, është shumë e këshillueshme që të pastroni artikujt e vjetër. Kjo mund të realizohet nga veçoria e integruar "AutoArchive", e cila mund të fshijë automatikisht artikujt e vjetër në intervale të rregullta. Megjithatë, disa përdorues thjesht dëshirojnë të fshijnë bashkëngjitjet në artikujt e vjetër pa ndikuar vetë artikujt. Në vijim, ne do t'ju mësojmë të hiqni në masë bashkëngjitjet nga artikujt e vjetër të kalendarit.

Hiq në grup bashkëngjitjet nga artikujt e vjetëruar të kalendarit

1. Për të filluar, hyni në redaktorin VBA të Outlook nga "Alt + F11".
2. Më pas, në dritaren "Microsoft Visual Basic për Aplikacione", kopjoni kodin VBA në një modul.

Sub BatchDeleteAttachmentsOfOldCalendarItems()
    Dim objOutlookFile As Outlook.Folder
    Dim objFolder As Outlook.Folder
 
    'Change to your own Outlook file
    Set objOutlookFile = Outlook.Application.Session.Folders("John Smith")
 
    For Each objFolder In objOutlookFile.Folders
        If objFolder.DefaultItemType = olAppointmentItem Then
           Call LoopCalendars(objFolder)
        End If
    Next
End Sub

Sub LoopCalendars(ByVal objCalendar As Outlook.Folder)
    Dim i, n As Long
    Dim objCalendarItem As Outlook.AppointmentItem
    Dim nDateDiff As Integer
    Dim objAttachments As Outlook.Attachments
    Dim objSubCalendar As Outlook.Folder
 
    For i = objCalendar.Items.Count To 1 Step -1
        Set objCalendarItem = objCalendar.Items(i)
 
        'Remove attachments from items that are more than 2 months old
        'Change the datediff as per your needs
        nDateDiff = DateDiff("m", objCalendarItem.End, Now) '=> "m" refers to month; "d" for day; "y" for year
        If nDateDiff > 2 Then
           Set objAttachments = objCalendarItem.Attachments
           If objAttachments.Count > 0 Then
              For n = objAttachments.Count To 1 Step -1
                  objAttachments(n).Delete
              Next
           End If
           objCalendarItem.Save
        End If
    Next

    'Process all subfolders recursively
    If objCalendar.Folders.Count > 0 Then
       For Each objSubCalendar In objCalendar.Folders
           Call LoopCalendars(objSubCalendar)
       Next
    End If
End Sub

3. Më pas, klikoni në makro "BatchDeleteAttachmentsOfOldCalendarItems".
4. Në fund të fundit, shtypni butonin "F5" për të ekzekutuar këtë makro.
5. Kur makro të përfundojë, mund të kontrolloni të gjithë kalendarët tuaj të Outlook.
6. Outlook duhet të ketë fshirë të gjitha bashkëngjitjet e artikujve të kalendarit që janë më shumë se 2 muaj të vjetër.

Përballuni me skedarët e korruptuar të Outlook

A keni hasur ndonjëherë në korrupsionin e Outlook? Si e hidhni atë zakonisht? Më shpesh sesa jo, së pari do të provonit mjetin e riparimit të kutisë hyrëse - scanpst. Por, në rast dëmtimi serioz të PST, programi i integruar nuk mund t'ju ndihmojë. Kështu, sugjerohet që të mbani një mjet më me përvojë dhe më të shquar të palës së tretë në afërsi, si p.sh DataNumen Outlook Repair.

Hyrje e autorit:

Shirley Zhang është një eksperte për rikuperimin e të dhënave DataNumen, Inc., e cila është lider botëror në teknologjitë e rikuperimit të të dhënave, duke përfshirë riparimi sql dhe produkte softuerike të riparimit të pamjes. Për më shumë informacion vizitoni www.datanumen.com