2 metoda për të fshirë në grup të gjitha kontaktet pa adresë emaili në Outlook tuaj

Nëse vini re se disa kontakte nuk kanë adresë email-i në Outlook-un tuaj, mund të dëshironi të përpunoni çdo dosje Kontaktesh për të fshirë të gjitha kontaktet e tilla. Ky postim do të ndajë 2 mënyra me ju.

Ndoshta keni shumë kontakte në Outlook dhe disa prej tyre nuk kanë adresë emaili. Nëse mendoni se ato nuk janë më të dobishme, duhet të shpresoni të fshini të gjitha kontaktet pa adresë emaili. Në mënyrën standarde, mund të përdorni "Kërkimin e menjëhershëm" për t'i gjetur dhe pastaj t'i fshini manualisht, si metoda 1 e mëposhtme. Megjithatë, është pak e lodhshme. Prandaj, në metodën 2, ne do t'ju mësojmë një mënyrë tjetër më efikase.

Metoda 1: Fshij manualisht pasi të gjesh kontaktet pa adresë emaili

1. Për të filluar, shtypni tastet "Ctrl + 3" për të hyrë në panelin "Kontaktet".
2. Pastaj, klikoni në kutinë e kërkimit.
3. Më pas, në shiritin e shfaqur "Kërko", kliko "Të gjitha artikujt e kontaktit".
4. Më pas, klikoni "Ka adresë" > "Ka adresë emaili".
5. Pas kësaj, kriteri “NUK adresat e emailit:=[]” do të shtohet në kutinë e kërkimit. Ju duhet të hiqni "JO".
6. Më pas, të gjitha kontaktet pa adresë emaili do të renditen.
7. Tani, duhet të zgjidhni manualisht kontaktet në rezultatet e kërkimit, pasi grupet tuaja të kontakteve duhet të jenë gjithashtu në listë.
8. Së fundi, shtypni butonin "Del" për të fshirë të gjitha kontaktet e zgjedhura.

Metoda 2: Fshij në grup të gjitha kontaktet pa adresë emaili me VBA

1. Në fillim, trokitni lehtë mbi "Alt + F11" për të nisur redaktorin VBA në Outlook.
2. Në ekranin e ri, kopjoni kodin e mëposhtëm VBA në një modul.

Sub BatchDeleteAllContactsWithoutEmailAddress()
    Dim objStore As Outlook.Store
    Dim lTotalCount As Long
 
    lTotalCount = 0
    'Process all stores in your Outlook
    For Each objStore In Application.Session.Stores
       Call ProcessContactFolders(objStore.GetRootFolder.Folders, lTotalCount)
    Next
 
    MsgBox lTotalCount & " contacts are deleted!", vbInformation + vbOKOnly, "Delete Contacts"
End Sub

Sub ProcessContactFolders(ByVal objFolders As Outlook.Folders, lCount As Long)
    Dim objFolder As Outlook.Folder
    Dim i As Long
    Dim objContact As Outlook.ContactItem
    Dim objSubfolder As Outlook.Folder

    For Each objFolder In objFolders
        If (objFolder.DefaultItemType = olContactItem) And (objFolder.Name <> "Skype Contacts") Then
           For i = objFolder.Items.Count To 1 Step -1
               If objFolder.Items(i).Class = olContact Then
                  Set objContact = objFolder.Items(i)
                  'Delete the contact w/o email address
                  If (objContact.Email1Address = "") And (objContact.Email2Address = "") And (objContact.Email3Address = "") Then
                     objContact.Delete
                     lCount = lCount + 1
                  End If
               End If
           Next
 
           'Process subfolders recursively
           If objFolder.Folders.Count > 0 Then
              Call ProcessContactFolders(objFolder.Folders, lCount)
           End If
       End If
    Next
End Sub

3. Më vonë, klikoni në nënprogramin "BatchDeleteAllContactsWithout Email Address".
4. Përfundimisht, shtypni "F5" për të aktivizuar këtë makro.
5. Kur të përfundojë, do të merrni një mesazh në lidhje me rezultatet, si imazhi më poshtë.
6. Të gjitha kontaktet pa adresë emaili janë zhvendosur në dosjen "Artikuj të fshirë".

Mbani larg nga të gjitha rreziqet e mundshme

Outlook mund të dëmtohet për shkak të një sërë faktorësh, të tillë si viruset, gabimet e përdoruesit, dështimet e softuerit si dhe defektet e harduerit. Ju duhet të hezitoni të përjetoni dëmtime të Outlook, kështu që duhet t'i mbani larg të gjitha këto rreziqe të mundshme. Për shembull, duhet të montoni softuer të fuqishëm antivirus në kompjuterin tuaj. Plus, duhet të kopjoni rregullisht të dhënat tuaja të Outlook. E fundit, por jo më pak e rëndësishme, është më mirë të përgatisni një mjet riparimi të fortë dhe të besueshëm, si p.sh DataNumen Outlook Repair. Mund ta rregullojë tuajën PST e korruptuar skedar me lehtësi.

Hyrje e autorit:

Shirley Zhang është një eksperte për rikuperimin e të dhënave DataNumen, Inc., e cila është lider botëror në teknologjitë e rikuperimit të të dhënave, duke përfshirë SQL Server korrupsioni dhe produkte softuerike të riparimit të pamjes. Për më shumë informacion vizitoni www.datanumen.com