Si të eksportoni shpejt kohën totale të shpenzuar në takimet e Outlook në secilën kategori ngjyrash

Nëse dëshironi të krijoni një raport për kohën totale që shpenzoni në takimet në secilën kategori ngjyrash, mund të përdorni metodën e prezantuar në këtë artikull. Mund t'ju ndihmojë ta përmbushni këtë në kohë të shpejtë pa pasur nevojë të numëroni manualisht.

Shumë përdorues janë mësuar të regjistrojnë shumicën e aktiviteteve të tyre në kalendarin e Outlook. Gjithashtu, për t'i menaxhuar dhe dalluar ato më lehtë, ata i caktojnë kategori secilës prej tyre. Në këtë rast, disa përdorues dëshirojnë të gjenerojnë një raport që tregon kohën totale të kaluar në artikujt e kalendarit në secilën kategori ngjyrash. Pa dyshim, është e vështirë të numërohen dhe futen manualisht. Prandaj, këtu do të ndajmë një mënyrë që mund ta kryejë këtë detyrë me një klikim të thjeshtë.

Eksportoni kohën totale të shpenzuar në takimet në secilën kategori ngjyrash

1. Në radhë të parë, hapni aplikacionin tuaj Outlook.
2. Më pas, pasi të keni hyrë në dritaren e Outlook, mund të prekni butonat "Alt + F11".
3. Më pas, do të keni akses në dritaren "Microsoft Visual Basic për Aplikacione".
4. Më pas, do t'ju kërkohet të aktivizoni "Microsoft Excel Object Library". Mund të klikoni "Tools" > "Reference" për ta aktivizuar atë.
5. Pastaj, ju duhet të gjeni dhe hapni një modul që nuk është në përdorim.
6. Pas kësaj, duhet të kopjoni kodin e mëposhtëm VBA në këtë modul.

Sub ExportTimeSpentOnAppointmentsInEachColorCategory()
    Dim objDictionary As Object
    Dim objAppointments As Outlook.Items
    Dim objAppointment As Outlook.AppointmentItem
    Dim strCategory As String
    Dim arrCategory As Variant
    Dim varCategory As Variant
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim arrKey As Variant
    Dim arrItem As Variant
    Dim i As Long
    Dim nLastRow As Integer
 
    Set objDictionary = CreateObject("Scripting.Dictionary")
    Set objAppointments = Application.Session.PickFolder.Items
  
    For Each objAppointment In objAppointments
        arrCategory = Split(objAppointment.Categories, ",")
        For Each varCategory In arrCategory
            strCategory = Trim(varCategory)
            If objDictionary.Exists(strCategory) Then
               objDictionary.Item(strCategory) = objDictionary.Item(strCategory) + objAppointment.Duration
            Else
               objDictionary.Add strCategory, objAppointment.Duration
            End If
        Next
    Next
 
    'Create a new Excel workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
    objExcelApp.Visible = True
    objExcelWorkbook.Activate
 
    With objExcelWorksheet
         .Cells(1, 1) = "Color Category"
         .Cells(1, 1).Font.Bold = True
         .Cells(1, 1).Font.Size = 14
         .Cells(1, 2) = "Total Time (min)"
         .Cells(1, 2).Font.Bold = True
         .Cells(1, 2).Font.Size = 14
    End With
 
    arrKey = objDictionary.Keys
    arrItem = objDictionary.Items
 
    For i = LBound(arrKey) To UBound(arrKey)
        nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.count).End(xlUp).Row + 1
 
        objExcelWorksheet.Cells(nLastRow, 1) = arrKey(i)
        objExcelWorksheet.Cells(nLastRow, 2) = arrItem(i)
    Next

    objExcelWorksheet.Columns("A:B").AutoFit
End Sub

7. Më në fund mund ta aktivizoni këtë makro, pa marrë parasysh duke klikuar ikonën "Run" në shiritin e veglave ose duke shtypur butonin "F5".
8. Pastaj, do t'ju kërkohet të zgjidhni një kalendar specifik.
9. Pasi të zgjidhni dhe shtypni "OK", makro do të vazhdojë të funksionojë. Pasi të përfundojë, do të ketë një skedar të ri Excel që shfaqet në sfond.
10. Ju mund të hyni në të. Do të duket si pamja e mëposhtme e ekranit:

Mbani një sy për kërcënimet e mundshme rreth Outlook-it tuaj

Përdoruesit e Outlook duhet të kujdesen për të gjitha rreziqet e mundshme, duke përfshirë bashkëngjitjet e panjohura të postës elektronike, lidhjet e integruara dhe gabimet njerëzore. Përndryshe, Outlook juaj mund të korruptohet në çdo kohë. Gjithashtu, krijimi i kopjeve rezervë të rregullt të të dhënave të Outlook dhe mbajtja e një mjeti të specializuar riparimi janë çështje të domosdoshme. DataNumen Outlook Repair është një nga mjetet më të rekomanduara për rregullimin e problemeve. Mund të riparimi i Outlook problemet në një moment.

Hyrje e autorit:

Shirley Zhang është një eksperte për rikuperimin e të dhënave DataNumen, Inc., e cila është lider botëror në teknologjitë e rikuperimit të të dhënave, duke përfshirë mdf i dëmtuar dhe produkte softuerike të riparimit të pamjes. Për më shumë informacion vizitoni www.datanumen.com