Si të eksportoni shpejt të gjitha bashkëngjitjet e imazhit të një emaili të Outlook në një fletë pune në Excel

Nëse dëshironi të eksportoni me shpejtësi të gjitha bashkëngjitjet e imazheve të një emaili të Outlook në një fletë pune në Excel, mund t'i referoheni këtij artikulli. Këtu do t'ju tregojmë një mënyrë më efektive sesa eksportimi manual.

Kur merrni një email që përmban një mori bashkëngjitjesh me fotografi, nëse doni t'i përdorni ato për të krijuar një raport në Excel, duhet të kërkoni një mënyrë për të eksportuar këto imazhe në një fletë pune në Excel në grupe. Tani, do t'ju prezantojmë një qasje të tillë në vijim.

Eksporto të gjitha bashkëngjitjet e imazhit të një emaili në një fletë pune në Excel

1. Për të filluar, hyni në aplikacionin tuaj Outlook në mënyrë normale.
2. Më pas, në dritaren e Outlook, shtypni shkurtoret e tastit "Alt + F11", të cilat do të shfaqin dritaren "Microsoft Visual Basic për Aplikacione".
3. Në këtë ekran, ju duhet të hapni një modul që nuk po përdoret ose të futni një të ri drejtpërdrejt.
4. Më pas, duhet të kopjoni pjesën e kodit VBA më poshtë në këtë modul.

Sub ExportAllImageAttachmentsToExcelWorksheet()
    Dim objSourceMail As Outlook.MailItem
    Dim objAttachment As Outlook.Attachment
    Dim strImage As String
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim objFile As Object
    Dim objFiles As Object
    Dim nRow As Integer
 
    Select Case Outlook.Application.ActiveWindow.Class
           Case olInspector
                Set objSourceMail = ActiveInspector.currentItem
           Case olExplorer
                Set objSourceMail = ActiveExplorer.Selection.Item(1)
    End Select
 
    If Not (objSourceMail Is Nothing) Then
 
       'Save the image attachments to a temporary folder
       strTempFolder = Environ("Temp") & "\" & Format(Now, "yyyymmddhhmmss") & "\"
       MkDir (strTempFolder)
       Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
       For Each objAttachment In objSourceMail.Attachments
           If IsEmbedded(objAttachment) = False Then
              Select Case LCase(objFileSystem.GetExtensionName(objAttachment.filename))
                     Case "jpg", "jpeg", "png", "bmp", "gif"
                          objAttachment.SaveAsFile strTempFolder & objAttachment.filename
              End Select
           End If
       Next
 
       'Create a new Excel workbook
        Set objExcelApp = CreateObject("Excel.Application")
        Set objExcelWorkbook = objExcelApp.Workbooks.Add
        Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
        objExcelApp.Visible = True
        objExcelWorkbook.Activate
 
        'Get the images in the temporary folder
        Set objFiles = objFileSystem.GetFolder(strTempFolder).Files
 
        'Insert the images into this new Excel worksheet
        For Each objFile In objFiles
            strImage = strTempFolder & Trim(objFile.Name)
            nRow = nRow + 1
            With objExcelWorksheet
                 .Range("A" & nRow).value = objFile.Name
                 'Change the height and width as per your needs
                 .Range("B" & nRow).ColumnWidth = 10
                 .Range("B" & nRow).RowHeight = 80
                 .Range("B" & nRow).Activate
                 With .Pictures.insert(strImage)
                      With .ShapeRange
                           .LockAspectRatio = msoTrue
                           .Width = 50
                           .Height = 70
                      End With
                 End With
                 .Columns("A").AutoFit
                 .Activate
            End With
       Next
    End If
End Sub

Function IsEmbedded(objCurAttachment As Outlook.Attachment) As Boolean
    Dim objPropertyAccessor As Outlook.propertyAccessor
    Dim strProperty As String
 
    Set objPropertyAccessor = objCurAttachment.propertyAccessor
    strProperty = objPropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x3712001E")
 
    If InStr(1, strProperty, "@") > 0 Then
       IsEmbedded = True
    Else
       IsEmbedded = False
    End If
End Function

5. Pas kësaj, mund të dilni nga makro.
6. Më pas, shkoni te "Skedari" > "Opsionet" > "Shiri i veglave të aksesit të shpejtë" për të shtuar këtë makro në shiritin e veglave të aksesit të shpejtë.
7. Më në fund, mund ta provoni këtë makro tani.

• Së pari, zgjidhni ose hapni një email burimor.
• Pastaj, klikoni butonin makro në shiritin e veglave të aksesit të shpejtë.
• Kur makro të përfundojë, do të merrni një fletë pune në Excel, e paraqitur si pamja e mëposhtme e ekranit:

Mbroni skedarin Outlook nga korruptimi

Dihet që Outlook është i prirur ndaj korrupsionit. Prandaj, ne duhet të kuptojmë se si të mbrojmë Outlook nga korrupsioni. Së pari, për të bllokuar sulmet e viruseve, është e nevojshme të instaloni softuer antivirus dhe të mos shkarkoni kurrë një bashkëngjitje të panjohur. Përveç kësaj, është më mirë të marrim një mjet të fuqishëm riparimi, si p.sh DataNumen Outlook RepairMund të ofrojë ilaçin më efektiv në rast të Perspektiva e korrupsionit.

Hyrje e autorit:

Shirley Zhang është një eksperte për rikuperimin e të dhënave DataNumen, Inc., e cila është lider botëror në teknologjitë e rikuperimit të të dhënave, duke përfshirë shërim sql dhe produkte softuerike të riparimit të pamjes. Për më shumë informacion vizitoni www.datanumen.com