Si të hapni të gjitha lidhjet në grup me një domen specifik në emailin tuaj të Outlook

Kur shikoni një email të Outlook që përmban shumë hiperlidhje në trup, ndonjëherë mund të dëshironi vetëm të hapni shpejt hiperlidhjet me një domen specifik. Këtu do të ndajmë një metodë për të hapur hiperlidhje të tilla në masë.

Përballë hiperlidhjeve të shumta në një email, mund të shpresoni të kontrolloni disa prej tyre, në vend të të gjithave. Për shembull, ju dëshironi të hapni hiperlidhjet në grup vetëm me një domen specifik. Në përgjithësi, duhet të klikoni një nga një për t'i hapur ato. Është shumë e mundimshme. Prandaj, në vijim do t'ju mësojmë një mënyrë më të përshtatshme.

Hapni në grup të gjitha hiperlidhjet me një domen specifik në email

1. Për sitart, hyni në redaktorin VBA të Outlook sipas "Si të ekzekutoni kodin VBA në Outlook tuaj".
2. Më pas, në dritaren "Microsoft Visual Basic për aplikacione", aktivizoni referencën për "MS Word Object Library” duke iu referuar “Si të shtoni një Object Library Referenca në VBA".
3. Pastaj, kopjoni kodin e mëposhtëm VBA në një modul ose projekt të papërdorur.

Sub BatchOpenHyperlinksWithSpecificDomain()
    Dim objMail As MailItem
    Dim objMailDocument As Word.Document
    Dim objHyperlink As Word.Hyperlink
    Dim objDictionary As Object
    Dim i As Integer
    Dim varHyperlinks As Variant
    Dim varHyperlink As Variant
    Dim objInternetExplorer As Object
 
    'Get the source email
    Select Case Outlook.Application.ActiveWindow.Class
           Case olInspector
                Set objMail = ActiveInspector.CurrentItem
           Case olExplorer
                Set objMail = ActiveExplorer.Selection.Item(1)
    End Select
 
    Set objDictionary = CreateObject("Scripting.Dictionary")
 
    Set objMailDocument = objMail.GetInspector.WordEditor
    For Each objHyperlink In objMailDocument.Hyperlinks
        If InStr(1, objHyperlink.Address, "www.datanumen.com") > 0 Then
           'Add Hyperlinks to Dictionary
           If objDictionary.Exists(objHyperlink.Address) = False Then
              objDictionary.Add objHyperlink.Address, 1
           End If
        End If
    Next
 
    'Batch Open Hyperlinks on different tabs in same Internet Explorer window
    Set objInternetExplorer = CreateObject("InternetExplorer.Application")
    varHyperlinks = objDictionary.Keys
    For i = LBound(varHyperlinks) To UBound(varHyperlinks)
        varHyperlink = varHyperlinks(i)
 
        If i = 0 Then
           objInternetExplorer.Visible = True
           objInternetExplorer.navigate varHyperlink
        Else
           objInternetExplorer.navigate varHyperlink, CLng(2048)
        End If
    Next
End Sub

4. Më pas, shtoni këtë makro në shiritin ose shiritin e veglave të aksesit të shpejtë.
5. Së fundi, ndërmerrni hapat e mëposhtëm për të provuar.

• Së pari, zgjidhni ose hapni një email të Outlook.
• Pastaj, klikoni butonin makro.
• Menjëherë, hiperlidhjet me domenin e paracaktuar në email do të hapen në grup në Internet Explorer, siç tregohet në imazhin e mëposhtëm:

Hiqni qafe korrupsionin irritues të opinionit

Edhe pse Outlook është i ndjeshëm ndaj gabimeve dhe korrupsionit, në fakt, për sa kohë që kujdeseni për të gjitha rreziqet, mund t'i shpëtoni me lehtësi prej tyre. Për shembull, ju duhet të bëni kopje rezervë të të dhënave për Outlook në baza të rregullta. Përveç kësaj, duhet të keni kujdes për emailet e dyshimta që mund të përmbajnë viruse. E fundit, por jo më pak e rëndësishme, është më mirë të përgatisni një Riparimi i parashikimeve dobi, si p.sh DataNumen Outlook Repair. Është në gjendje t'ju ndihmojë në rast të korrupsionit të Outlook.

Hyrje e autorit:

Shirley Zhang është një eksperte për rikuperimin e të dhënave DataNumen, Inc., e cila është lider botëror në teknologjitë e rikuperimit të të dhënave, duke përfshirë i korruptuar SQL Server dhe produkte softuerike të riparimit të pamjes. Për më shumë informacion vizitoni www.datanumen.com