Si të dërgoni së bashku të gjithë skedarët në një dosje të Windows përmes emaileve të veçanta të Outlook

Nëse dëshironi t'i dërgoni dikujt të gjithë skedarët në një dosje Windows përmes emaileve individuale të Outlook, mund të përdorni metodën e prezantuar në këtë artikull. Ai po përdor kodin VBA, i cili është mjaft efektiv.

Pasi lexova artikullin tim të mëparshëm - "3 metoda të shpejta për të bashkangjitur të gjithë skedarët në një dosje lokale në një email të Outlook”, disa përdorues duan të dërgojnë të gjithë skedarët në një dosje lokale përmes emaileve të veçanta. Në mënyrë standarde, duhet të krijoni email dhe t'i bashkëngjitni skedarët një nga një. Është mjaft e mundimshme. Prandaj, në vijim do t'ju prezantojmë një mënyrë më efektive.

Dërgoni në grup të gjithë skedarët në një dosje të Windows përmes emaileve të veçanta

1. Së pari, nisni programin tuaj Outlook.
2. Pastaj, në Outlook, hyni në redaktorin VBA në lidhje me artikullin - "Si të ekzekutoni kodin VBA në Outlook tuaj".
3. Më pas, kopjoni dhe ngjisni kodin e mëposhtëm VBA në një projekt ose një modul.

Sub SendAllFilesInSeparateEmails()
    Dim objShell As Object
    Dim objWindowsFolder As Object
    Dim objFile As Object
    Dim strWindowsFolder As String
    Dim objFileSystem As Object
    Dim objMail As Outlook.MailItem
 
    'Select a Windows folder
    Set objShell = CreateObject("Shell.Application")
    Set objWindowsFolder = objShell.BrowseForFolder(0, "Select a Windows Folder:", 0, "")
 
    If Not objWindowsFolder Is Nothing Then
       strWindowsFolder = objWindowsFolder.self.Path & "\"
       Set objFileSystem = CreateObject("Scripting.FileSystemObject")
       Set objWindowsFolder = objFileSystem.GetFolder(strWindowsFolder)
 
       'Send each file in an email
       For Each objFile In objWindowsFolder.Files
 
           'Create a new mail
           Set objMail = Outlook.Application.CreateItem(olMailItem)
           'Change the details as per your needs
           With objMail
                .Subject = Left(objFile.Name, Len(objFile.Name) - (Len(objFileSystem.GetExtensionName(objFile.Name)) + 1))
                .Attachments.Add objFile.Path
                .Recipients.Add ("someone@datanumen.com")
                .Recipients.ResolveAll
                .Send
          End With
       Next
 
       'Prompt you when completing sending
       MsgBox "All done!", vbOKOnly + vbExclamation
    End If
End Sub

4. Pas kësaj, mund ta ekzekutoni këtë makro menjëherë. Thjesht shtypni butonin "F5".
5. Më pas, do t'ju kërkohet të zgjidhni dosjen burimore të Windows në kutinë e dialogut që shfaqet.
6. Në fund të fundit, Outlook do t'i bashkëngjisë të gjithë skedarët në këtë dosje të Windows në email të veçantë dhe do t'i dërgojë ato te marrësi i paracaktuar.
7. Kur të përfundojë, do të merrni një mesazh që kërkon "Gjithçka u krye!".

Mbani një sy në Outlook Health

Edhe pse Outlook është reklamuar si klienti më i popullarizuar i email-it në treg, ai ende ka një të metë fatale. Kjo është dobësia e tij. Me fjalë të tjera, Outlook është i prirur ndaj gabimeve dhe korruptimeve të ndryshme. Prandaj, duhet t'i kushtoni shumë rëndësi gjendjes së Outlook-ut tuaj, duke e mbrojtur atë nga dëmtimet. Përveç kësaj, duhet të bëni kopje rezervë të skedarëve tuaj të Outlook-ut në intervale të rregullta. Përveç kësaj, rekomandohet të merrni një mjet për rregullimin e PST-së, si p.sh. DataNumen Outlook Repair. Mundet riparimi i Outlook çështje pa asnjë telash.

Hyrje e autorit:

Shirley Zhang është një eksperte për rikuperimin e të dhënave DataNumen, Inc., e cila është lider botëror në teknologjitë e rikuperimit të të dhënave, duke përfshirë rregullim sql dhe produkte softuerike të riparimit të pamjes. Për më shumë informacion vizitoni www.datanumen.com