Si të hiqni grupe të gjitha adresat e postës elektronike me një domen specifik nga kontaktet tuaja të Outlook

Ndonjëherë, mund të shpresoni të hiqni të gjitha adresat e emailit me një domen specifik nga kontaktet tuaja. Në këtë situatë, nuk duhet të jeni të gatshëm ta bëni atë një nga një. Kështu, kjo post do t'ju mësojë një metodë shumë më të zgjuar.

Për shembull, një kompani ndryshon emrin e saj. Ndërkohë, domeni i kompanisë gjithashtu ndryshon. Megjithatë, në Outlook, ju keni ruajtur shumë kontakte në këtë kompani, adresat e emailit të të cilëve janë me domenin e vjetër. Sigurisht, këto adresa emaili nuk janë më të vlefshme. Prandaj, në këtë rrethanë, nëse dëshironi t'i hiqni këto adresa emaili menjëherë, mund të përdorni mënyrën e mëposhtme.

Hiq grupe të gjitha adresat e emailit me një domen specifik nga Kontaktet

1. Për sitart, hyni në redaktorin VBA të Outlook me shkurtoren e tastit - "Alt + F11".
2. Pastaj, në dritaren e re, vendosni kodin e mëposhtëm VBA në një modul bosh.

Dim strDomain As String

Sub BatchRemoveAllEmailAddressesInSpecificDomain()
    Dim objStore As Store
    Dim objFolder As Folder
    Dim lTotalCount As Long
 
    'Input the specific domain
    strDomain = InputBox("Enter the specific domain:", , "@false.com")
 
    If Len(strDomain) <> 0 Then
       lTotalCount = 0
       'Process all Contact folders in your Outlook
       For Each objStore In Application.Session.Stores
           For Each objFolder In objStore.GetRootFolder.Folders
               If objFolder.DefaultItemType = olContactItem Then
                  Call ProcessContactFolders(objFolder, lTotalCount)
               End If
           Next
       Next
 
       'Prompt you
       MsgBox lTotalCount & " email addresses in " & strDomain & " are removed!", vbInformation + vbOKOnly
    End If
End Sub

Sub ProcessContactFolders(ByVal objCurrentFolder As Folder, ByRef lCount As Long)
    Dim objContacts As Items
    Dim i As Long
    Dim objContact As ContactItem
 
    Set objContacts = objCurrentFolder.Items
 
    For i = objContacts.Count To 1 Step -1
        If TypeName(objContacts(i)) = "ContactItem" Then
           Set objContact = objContacts(i)
 
           'Check 3 email addresses of each contact
           If InStr(objContact.Email1Address, strDomain) > 0 Then
              lCount = lCount + 1
              objContact.Email1Address = ""
              objContact.Email1DisplayName = ""
           ElseIf InStr(objContact.Email2Address, strDomain) > 0 Then
              lCount = lCount + 1
              objContact.Email2Address = ""
              objContact.Email2DisplayName = ""
           ElseIf InStr(objContact.Email3Address, strDomain) > 0 Then
              lCount = lCount + 1
              objContact.Email3Address = ""
              objContact.Email3DisplayName = ""
           End If
 
           objContact.Save
        End If
     Next
 
     If objCurrentFolder.Folders.Count > 0 Then
        For Each objSubfolder In objCurrentFolder.Folders
            Call ProcessContactFolders(objSubfolder, lCount)
        Next
     End If
End Sub

3. Pas kësaj, vendosni kursorin në nënprogramin "BatchRemoveAllEmailAddressesInSpecificDomain".
4. Më në fund, klikoni butonin "F5" për të aktivizuar këtë makro.
5. Më pas, futni domenin specifik në kutinë e dialogut që shfaqet.
6. Pasi të klikoni "OK", makro do të ekzekutohet.
7. Kur të përfundojë, do të merrni një mesazh për rezultatet.
8. Tani mund të kontrolloni kontaktet. Të gjitha adresat e emailit me domenin specifik duhet të jenë zhdukur.

Ruani skedarin tuaj Outlook

Me gjithnjë e më shumë rreziqe që rrethojnë Outlook-in tuaj, është gjithnjë e më e vështirë të mbroni të dhënat tuaja të vlefshme të Outlook. Për shembull, jo vetëm që duhet të vazhdoni në kopjimin e rregullt të të dhënave, por gjithashtu duhet të keni kujdes për operacionet tuaja. Nuk është e mençur të besosh lehtësisht në çdo email nga dërgues të panjohur. Përndryshe, nëse mbart virus, skedari juaj Outlook do të infektohet. Në atë kohë, ju duhet të përpiqeni Riparimi i parashikimeve nëpërmjet një mjeti të shquar rregullues, si p.sh DataNumen Outlook Repair.

Hyrje e autorit:

Shirley Zhang është një eksperte për rikuperimin e të dhënave DataNumen, Inc., e cila është lider botëror në teknologjitë e rikuperimit të të dhënave, duke përfshirë shërohem Sql Server dhe produkte softuerike të riparimit të pamjes. Për më shumë informacion vizitoni www.datanumen.com