Si të nxirrni në grup të gjithë faqeshënuesit nga dokumenti juaj Word

Në artikullin e sotëm, ne dëshirojmë të ndajmë me ju hapat për të nxjerrë në grup të gjithë faqerojtësit nga dokumenti juaj Word për t'i parë ato menjëherë.

Në Word, mund të gjeneroni një tabelë të përmbajtjes ose një tabelë me figura me funksionin e integruar. Por, në fund do të zbuloni se nuk ka asnjë mënyrë të zakonshme për të nxjerrë të gjithë faqerojtësit e një dokumenti dhe për t'i rregulluar ato në një dokument të ri.

Si gjithmonë, misioni ynë është t'ju udhëheqim përmes mitit dhe t'ju ofrojmë mënyrën makro për të eksportuar të gjithë faqeshënuesit si dhe tekstet e tyre në një dokument të ri bosh.

Ekstraktimi i grupit të të gjithë faqeshënuesve nga një dokument i vetëm

1. Për të filluar, hapni dokumentin e synuar dhe shtypni "Alt + F11" për të thirrur redaktorin VBA.
2. Pastaj klikoni "Normal" dhe më pas "Fut".
3. Dhe zgjidhni "Modul" për të krijuar një të ri nën projektin "Normal".
4. Pastaj klikoni dy herë mbi të për të nxjerrë hapësirën e redaktimit.
5. Ngjit makronë e mëposhtme atje:

Sub ExtractBookmarksInADoc()
  Dim objBookmark As Bookmark
  Dim objTable As Table
  Dim nRow As Integer
  Dim objDoc As Document, objNewDoc As Document
  Dim objParagraph As Paragraph
 
  Set objDoc = ActiveDocument
 
  If objDoc.Bookmarks.Count = 0 Then
    MsgBox ("There is no bookmark in this document.")
  Else
    Set objNewDoc = Documents.Add
 
    Selection.TypeText Text:="Bookmarks in " & "'" & objDoc.Name & "'"
 
    Set objTable = Selection.Tables.Add(Range:=Selection.Range, numrows:=1, numcolumns:=3)
    objTable.Borders.Enable = True
    nRow = 1
 
    For Each objParagraph In objNewDoc.Paragraphs
      If objParagraph.Range.Style = "Caption" Then
        objParagraph.Range.Delete
      End If
    Next objParagraph
 
    With objTable
      .Cell(1, 1).Range.Text = "Name"
      .Cell(1, 2).Range.Text = "Texts"
      .Cell(1, 3).Range.Text = "Page Number"
 
      For Each objBookmark In objDoc.Bookmarks
        objTable.Rows.Add
        nRow = nRow + 1
        .Cell(nRow, 1).Range.Text = objBookmark.Name
        .Cell(nRow, 2).Range.Text = objBookmark.Range.Text
        .Cell(nRow, 3).Range.Text = objBookmark.Range.Information(wdActiveEndAdjustedPageNumber)
        objDoc.Hyperlinks.Add Anchor:=.Cell(nRow, 3).Range, Address:=objDoc.Name, _
          SubAddress:=objBookmark.Name, TextToDisplay:=.Cell(nRow, 3).Range.Text
      Next objBookmark
    End With
  End If
  objNewDoc.SaveAs2 FileName:=objDoc.Path & "\" & "Bookmarks in " & objDoc.Name
End Sub

6. E fundit, por jo më pak e rëndësishmja, klikoni "Run".

Të gjithë faqerojtësit e dokumentit aktual do të vendosen në një tabelë në një dokument të ri të ruajtur në të njëjtën direktori si skedari origjinal.

Ju mund të shihni tabelën me 3 kolona në dokumentin e ri. Dhe nëse ndiqni "Ctrl+ Click", do t'ju çojë në faqerojtësin në dokumentin origjinal.

Ekstrakt i grupit të faqeshënuesve nga shumë dokumente

Ndiqni të njëjtat hapa të mësipërm për të instaluar dhe ekzekutuar një makro. Vetëm këtë herë, ju zëvendësoni kodet me ato të mëposhtme:

Sub ExtractBookmarksInMultiDoc()
  Dim objBookmark As Bookmark
  Dim objTable As Table
  Dim nRow As Integer
  Dim objDoc As Document, objNewDoc As Document
  Dim objParagraph As Paragraph
  Dim strFolder As String, strFile As String
 
  strFolder = InputBox("Enter folder path here: ")
  strFile = Dir(strFolder & "*.docx", vbNormal)
 
  While strFile <> ""
    Set objDoc = Documents.Open(FileName:=strFolder & strFile)
    Set objDoc = ActiveDocument
    Set objNewDoc = Documents.Add
 
    Selection.TypeText Text:="Bookmarks in " & "'" & objDoc.Name & "'"
 
    Set objTable = Selection.Tables.Add(Range:=Selection.Range, numrows:=1, numcolumns:=3)
    objTable.Borders.Enable = True
    nRow = 1
 
    For Each objParagraph In objNewDoc.Paragraphs
      If objParagraph.Range.Style = "Caption" Then
        objParagraph.Range.Delete
      End If
    Next objParagraph
 
    With objTable
      .Cell(1, 1).Range.Text = "Name"
      .Cell(1, 2).Range.Text = "Texts"
      .Cell(1, 3).Range.Text = "Page Number"
 
      For Each objBookmark In objDoc.Bookmarks
        objTable.Rows.Add
        nRow = nRow + 1
        .Cell(nRow, 1).Range.Text = objBookmark.Name
        .Cell(nRow, 2).Range.Text = objBookmark.Range.Text
        .Cell(nRow, 3).Range.Text = objBookmark.Range.Information(wdActiveEndAdjustedPageNumber)
        objDoc.Hyperlinks.Add Anchor:=.Cell(nRow, 3).Range, Address:=objDoc.Name, _
          SubAddress:=objBookmark.Name, TextToDisplay:=.Cell(nRow, 3).Range.Text
      Next objBookmark
    End With
    objNewDoc.SaveAs2 FileName:=objDoc.Path & "\" & "Bookmarks in " & objDoc.Name
    objDoc.Close
    strFile = Dir()
  Wend
End Sub

Pasi të keni ekzekutuar makro, ka një kuti hyrëse. Futni shtegun e dosjes ku ruani të gjitha dokumentet. Dhe mbani mend shtoni "\" në fund të shtegut nëse thjesht e kopjoni atë nga kutia e tekstit të dosjes. Pastaj klikoni "OK".

Si të shpëtoni shpejt veten nga fatkeqësia e të dhënave

Fatkeqësia e të dhënave për të cilën flasim në Word mund të ndodhë sa herë që ndalon së punuari në mënyrë jonormale. Ndonjëherë, ju keni fat dhe i keni të gjitha informacionet të paprekura. Dhe herë të tjera, ju bini viktimë e fatkeqësisë. Prandaj, mënyra më e shpejtë për të marrë sa më shumë të dhëna të jetë e mundur është të merrni një mjet për të rregulloni docx.

Hyrje e autorit:

Vera Chen është një eksperte për rikuperimin e të dhënave DataNumen, Inc., e cila është lider botëror në teknologjitë e rikuperimit të të dhënave, duke përfshirë riparim xlsx pdf riparimin e produkteve softuerike. Për më shumë informacion vizitoni www.datanumen.com