Si të eksportoni në grup emaile të shumëfishta të Outlook në një dokument me një fjalë nëpërmjet VBA

Zgjidhjet e Outlook Shtator 29, 2025

Nëse dëshironi të eksportoni disa emaile të Outlook në një dokument të vetëm me fjalë, mund të përdorni kodin VBA të treguar në këtë artikull. Mund t'ju ndihmojë ta përmbushni këtë detyrë brenda sekondave.

Unë kam prezantuar ndonjëherë se si të konvertoj një email të Outlook në një dokument Word në artikullin tim të mëparshëm - "2 Metoda efektive për të kthyer një email të Outlook në një dokument Word“. Megjithatë, të dyja 2 mjetet e përmendura në atë fost do të jetë i pafuqishëm në rastin kur dëshironi të eksportoni shumë emaile në një dokument Word. Prandaj, këtu do t'ju mësojmë një mënyrë tjetër. Tani, lexoni për ta marrë atë në mënyrë të hollësishme.

Eksportoni në grup emaile të shumëfishta të Outlook në një dokument me një fjalë nëpërmjet VBA

Eksportoni në grup emaile të shumëfishta të Outlook në një dokument me një fjalë

  1. Të start me, nisni programin tuaj Outlook.
  2. Pastaj, pasi të keni hyrë në dritaren kryesore të Outlook, duhet të shtypni butonat "Alt + F11".
  3. Më pas do të keni akses në redaktuesin VBA të Outlook, në të cilin duhet të hapni një modul bosh.
  4. Më pas, kopjoni kodin VBA më poshtë në dritaren e hapur të modulit.
Sub ExportMultipleEmails_OneWordDocument()
    Dim objFileSystem As Object
    Dim strTempFolder As String
    Dim objSelection As Outlook.Selection
    Dim objMail As Outlook.MailItem
    Dim strFileName As String
    Dim objWordApp As Word.Application
    Dim objNewWordDocument As Word.Document
    Dim objWordRange As Word.Range
    Dim strWordDocument As String
    Dim i As Long
  
    'Create a temp folder
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    strTempFolder = objFileSystem.GetSpecialFolder(2).Path & "\Temp" & Format(Now, "YYYYMMDDhhmmss")
    MkDir (strTempFolder)
 
    On Error Resume Next
    'Save each selected email as an individual Word document in a temp folder
    Set objSelection = Outlook.Application.ActiveExplorer.Selection
    For Each objMail In objSelection
        strFileName = objMail.Subject
 
        'Remove the unsupported characters in email subject
        strFileName = Replace(strFileName, "/", " ")
        strFileName = Replace(strFileName, "\", " ")
        strFileName = Replace(strFileName, ":", "")
        strFileName = Replace(strFileName, "?", " ")
        strFileName = Replace(strFileName, Chr(34), " ")
 
        objMail.SaveAs strTempFolder & "\" & strFileName & ".doc", olDoc
    Next
 
    'Merge all the Word documents into a single document
    Set objWordApp = CreateObject("Word.Application")
    Set objNewWordDocument = objWordApp.Documents.Add
 
    strWordDocument = Dir(strTempFolder & "\" & "*.doc")
    i = 0
    Do Until strWordDocument = ""
       i = i + 1
       Set objWordRange = objNewWordDocument.Range
       With objWordRange
           .Collapse wdCollapseEnd
           If i > 1 Then
             .InsertBreak wdSectionBreakNextPage
             .End = objNewWordDocument.Range.End
             .Collapse wdCollapseEnd
           End If
           .InsertFile strTempFolder & "\" & strWordDocument
      End With
      strWordDocument = Dir()
    Loop
 
    'Change the path as per your own needs
    objNewWordDocument.SaveAs "E:\Exported Emails " & Format(Now, "YYYY-MM-DD hh-mm-ss")
    objWordApp.Quit
 
    'Delete the temp folder
    objFileSystem.DeleteFolder (strTempFolder)
End Sub

Kodi VBA - Eksportoni në grup emaile të shumëfishta të Outlook në një dokument me një fjalë

  1. Pas kësaj, është më mirë ta shtoni këtë projekt të ri VBA në shiritin ose shiritin e veglave të aksesit të shpejtë.
  2. Në fund të fundit, mund të provoni.
  • Në radhë të parë, zgjidhni emaile të shumta të Outlook.
  • Më pas gjeni dhe klikoni në butonin makro të sapo shtuar.
  • Pasi t'ju kërkohet "Përfundo", mund të shfletoni në dosjen e paracaktuar lokale për të gjetur një dokument të ri Word.
  • Hapni këtë dokument, në të cilin mund të shihni se të gjitha emailet e zgjedhura janë eksportuar.

Mbani një mjet të fuqishëm rikuperimi afër

Pavarësisht nga funksionet e shumta, Outlook ende nuk mund të jetë i imunizuar nga gabimet. Nëse jeni mësuar t'i lini të qetë gabimet, me rritjen e tyre, përplasja e Outlook do të ndodhë patjetër. Në atë pikë, është thelbësore të ktheheni te një mjet rikuperimi i fuqishëm dhe efektiv, si p.sh DataNumen Outlook Repair. Është njohës i mirë Rregullim PST. Për sa kohë që me të, nuk do të duhet të shqetësoheni më për humbjen e të dhënave të Outlook.

Hyrje e autorit:

Shirley Zhang është një eksperte për rikuperimin e të dhënave DataNumen, Inc., e cila është lider botëror në teknologjitë e rikuperimit të të dhënave, duke përfshirë mdf i korruptuar dhe produkte softuerike të riparimit të pamjes. Për më shumë informacion vizitoni www.datanumen.com

Komentet janë të mbyllura.