Si të eksportoni shpejt statistikat e votimit nga një email i Outlook në një fletë pune në Excel

Nëse keni dërguar një email me butona votimi, pasi marrësit t'ju dërgojnë përgjigjet e tyre, mund të dëshironi të numëroni dhe eksportoni statistikat e votimit në një fletë pune në Excel. Pra, në këtë fqost, ne do t'ju mësojmë se si ta arrini atë me shpejtësi.

Outlook është aq i fuqishëm sa që ofron edhe një veçori "Votimi". Artikulli im i mëparshëm "Përdorimi i shkathët i MS Outlook për votim” ka mësuar se si të përdoret në mënyrë efektive. Gjithashtu, most me kalimin e kohës, pas votimit, mund të vazhdoni të eksportoni statistikat e votimit në një fletë pune në Excel për disa arsye, të tilla si dëshira për të printuar statistikat. Por Outlook nuk e mbështet këtë si parazgjedhje. Kështu, në vijim do t'ju mësojmë se si ta realizoni këtë si tapë.

Eksportoni statistikat e votimit në një email në një fletë pune në Excel

1. Që në fillim, hapni aplikacionin tuaj Outlook.
2. Pastaj duhet të shtypni butonat "Alt + F11" në dritaren kryesore të Outlook.
3. Më pas në dritaren "Microsoft Visual Basic për Aplikime", duhet të aktivizoni "Microsoft Excel Object Lib"rary”. Klikoni "Mjetet" > "Referenca". Më pas në kutinë e dialogut që shfaqet, shënoni kutinë e kontrollit përpara "Microsoft Excel Object Library” dhe më në fund shtypni “OK”.
4. Pas kësaj, mund të futni një modul të ri ose të hapni një që nuk është në përdorim.
5. Më pas, kopjoni dhe ngjisni kodet e mëposhtme VBA në këtë modul.

Sub ExportVotingStatistics _Excel ()
    Dim objMail As Outlook.MailItem
    Dim objRecipient As Outlook.recipient
    Dim objVoteDictionary As Object
    Dim varVotingCounts As Variant
    Dim varVotingOptions As Variant
    Dim varVotingOption As Variant
    Dim i As Long
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim nRow As Integer
 
    Set objMail = Application.ActiveExplorer.Selection(1)
 
    'Create a new excel worksheet
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
 
    'Fill in the predefined values
    With objExcelWorksheet
         .Cells.Font.Name = "Cambria"
         .Cells(1, 1) = "Voting Results for Email:"
         .Cells(1, 2) = Chr(34) & objMail.Subject & Chr(34)
         .Cells(3, 1) = "Voting Options"
         .Cells(3, 2) = "Voting Counts"
    End With
 
    Set objVoteDictionary = CreateObject("Scripting.Dictionary")
    'get the default voting options
    varVotingOptions = Split(objMail.VotingOptions, ";")
    'Add the voting responses to the dictionary
    For Each varVotingOption In varVotingOptions
        objVoteDictionary.Add varVotingOption, 0
    Next
    'Add a custom voting response - "No Reply"
    objVoteDictionary.Add "No Reply", 0
 
    'Process the all voting responses
    For Each objRecipient In objMail.Recipients
        If objRecipient.TrackingStatus = olTrackingReplied Then
           If objVoteDictionary.Exists(objRecipient.AutoResponse) Then
              objVoteDictionary.Item(objRecipient.AutoResponse) = objVoteDictionary.Item(objRecipient.AutoResponse) + 1
           Else
              objVoteDictionary.Add objRecipient.AutoResponse, 1
           End If
        Else
           objVoteDictionary.Item("No Reply") = objVoteDictionary.Item("No Reply") + 1
        End If
    Next
 
    'Get the voting options and vote counts
    varVotingOptions = objVoteDictionary.Keys
    varVotingCounts = objVoteDictionary.Items
 
    'Fill in the values in specific cells
    nRow = 4
    For i = LBound(varVotingOptions) To UBound(varVotingOptions)
        With objExcelWorksheet
             .Cells(nRow, 1) = varVotingOptions(i)
             .Cells(nRow, 2) = varVotingCounts(i)
        End With
        nRow = nRow + 1
    Next
 
    'Save the new Excel file
    objExcelWorksheet.Columns("A:B").AutoFit
    strExcelFile = "E:\Voting Results " & Format(Now, "YYYY-MM-DD hh-mm-ss") & ".xlsx"
    objExcelWorkbook.Close True, strExcelFile

    MsgBox "Complete!", vbExclamation
End Sub

5. Pas kësaj, për akses të përshtatshëm, është më mirë të shtoni makro të re në shiritin e veglave të aksesit të shpejtë.
6. Më në fund, mund të provoni.

• Së pari, zgjidhni një email burimor që përmban butona votimi.
• Pastaj klikoni butonin makro në shiritin e veglave të aksesit të shpejtë.
• Pasi kjo makro të përfundojë ekzekutimin, mund të shfletoni në dosjen e paracaktuar lokale, në të cilën do të shihni një libër të ri pune në Excel.
• Hapni këtë libër pune në Excel. Tani do të shihni statistikat e votimit, të paraqitura si imazhi më poshtë:

Askush nuk mund t'i shmangë plotësisht gabimet e Outlook

Megjithëse Outlook është i pajisur me një sërë aftësish, nuk ka një veçori të tillë që të na ndihmojë të shmangim gabimet e Outlook. Të gjitha llojet e faktorëve mund të shkaktojnë gabime të Outlook. Për shembull, nëse shpesh dilni nga Outlook në mënyrë jo të duhur, do të keni gjasa të vuani Korrupsioni i PST. Në një skenar të tillë, ju nuk keni zgjidhje tjetër veçse të përdorni disa mjete të fuqishme për të shpëtuar skedarin tuaj PST, si p.sh. DataNumen Outlook Repair. Ajo ka fituar shumë lavdërime për shkak të shkallës së lartë të rikuperimit.

Hyrje e autorit:

Shirley Zhang është një eksperte për rikuperimin e të dhënave DataNumen, Inc., e cila është lider botëror në teknologjitë e rikuperimit të të dhënave, duke përfshirë mdf i korruptuar dhe produkte softuerike të riparimit të pamjes. Për më shumë informacion vizitoni www.datanumen.com