Si të hapni automatikisht bashkëngjitjet e emaileve hyrëse të Outlook nga një dërgues specifik

Nëse dëshironi që Outlook të hapë automatikisht bashkëngjitjet e emaileve hyrëse nga një dërgues specifik, mund ta lexoni këtë artikull. Këtu do t'ju udhëzojmë se si ta arrini atë.

Për shembull, shefi juaj shpesh ju dërgon email me disa bashkëngjitje të rëndësishme skedarësh. Për të reaguar sa më shpejt ndaj shefit tuaj, duhet të hapni bashkëngjitjet kur t'i merrni. Në këtë skenar, mund të dëshironi një metodë më të zgjuar për të lejuar që Outlook të hapë automatikisht bashkëngjitjet e postës elektronike në hyrje nga shefi juaj. Tani do t'ju tregojmë një metodë të tillë.

Hapni automatikisht bashkëngjitjet e emaileve hyrëse nga një dërgues specifik

1. Për të filluar, hapni aplikacionin Outlook.
2. Pastaj, hyni në redaktorin VBA përmes shkurtores - "Alt + F11"
3. Më pas, vendosni kodin e mëposhtëm VBA në projektin "ThisOutlookSession".

Private Declare Function GetShortPathName Lib "kernel32" _
 Alias "GetShortPathNameA" (ByVal lpszLongPath As String, _
 ByVal lpszShortPath As String, ByVal cchBuffer As Long) As Long

Private WithEvents objItems As Outlook.Items

Private Sub Application_Startup()
    Set objItems = Outlook.Application.Session.GetDefaultFolder(olFolderInbox).Items
End Sub

'Occurs when new item arrives in Inbox
Private Sub objItems_ItemAdd(ByVal Item As Object)
    Dim objMail As Outlook.MailItem
    Dim objWsShell As Object
    Dim strTempFolder As String
    Dim objAttachments As Outlook.Attachments
    Dim objAttachment As Attachment
    Dim strFileName As String
 
    If Item.Class = olMail Then
       Set objMail = Item
       'Change sender email address
       If objMail.SenderEmailAddress = "boss@datanumen.com" Then
          Set objWShell = CreateObject("WScript.Shell")
          strTempFolder = Environ("Temp") & "\"
 
          Set objWsShell = CreateObject("WScript.Shell")
          Set objAttachments = objMail.Attachments
          If objAttachments.Count > 0 Then
             For Each objAttachment In objAttachments
                 strFileName = objAttachment.DisplayName
                 On Error Resume Next
                 Kill strTempFolder & strFileName
                 On Error GoTo 0
 
                 'Save the attachment
                 objAttachment.SaveAsFile strTempFolder & strFileName
 
                 'Open the attachment
                 strFileName = GetShortFileName(strTempFolder & strFileName)
                 On Error Resume Next
                 objWsShell.Run strFileName
             Next
          End If
        End If
    End If
End Sub

Function GetShortFileName(ByVal FullPath As String) As String
    Dim lAns As Long
    Dim sAns As String
    Dim iLen As Integer
 
    On Error Resume Next

    If Dir(FullPath) <> "" Then
       sAns = Space(255)
       lAns = GetShortPathName(FullPath, sAns, 255)
       GetShortFileName = Left(sAns, lAns)
    End If
End Function

4. Më pas, mbyllni redaktorin VBA.
5. Përfundimisht, rinisni aplikacionin tuaj Outlook për të aktivizuar makron e re.
6. Që tani e tutje, sa herë që një postë e re nga dërguesi specifik arrin në kutinë tuaj hyrëse, Outlook do të hapë automatikisht bashkëngjitjet në këtë postë.

Aplikoni mjetin e riparimit të kutisë hyrëse

Kur skedari juaj i të dhënave Outlook është i dëmtuar, çfarë do të bënit atëherë? Në fakt, së pari, mund të përdorni mjetin e integruar të rregullimit të Outlook - scanpst. Është në gjendje të zgjidhë disa probleme të vogla që lidhen me Outlook-un tuaj. Me kusht që ky shërbim dështon, është koha për të përdorur një mjet të jashtëm shumë më me përvojë dhe të besueshëm, si p.sh. DataNumen Outlook Repair.

Hyrje e autorit:

Shirley Zhang është një eksperte për rikuperimin e të dhënave DataNumen, Inc., e cila është lider botëror në teknologjitë e rikuperimit të të dhënave, duke përfshirë mdf i korruptuar dhe produkte softuerike të riparimit të pamjes. Për më shumë informacion vizitoni www.datanumen.com