3 mënyra për të marrë statistikat e numërimit të fjalëve në lidhje me kutitë e tekstit, shënimet në fund të faqes dhe shënimet fundore në dokumentin tuaj

Në artikullin e sotëm, ka 3 mënyra të shpejta për të marrë statistika të numrit të fjalëve në lidhje me kutitë e tekstit, shënimet në fund të faqes dhe shënimet fundore në dokumentin tuaj.

Nuk është e vështirë të marrësh numrin total të fjalëve në një dokument. Por nëse doni të merrni numrin e fjalëve të llojeve të ndryshme të teksteve, atëherë do të kërkohen më shumë operacione. Më poshtë janë 3 metoda. Lexoni për të parë se çfarë mund të përdorni. 

Metoda 1: Numëroni fjalët duke përfshirë tekstet nga kutitë e tekstit, fusnotat dhe shënimet fundore

Si parazgjedhje, Word numëron të gjitha fjalët që shfaqen në dokument, duke përfshirë tekstet në kutitë e tekstit dhe fjalët nga fusnotat dhe shënimet fundore gjithashtu.

1. Para së gjithash, shkoni te shiriti i statusit dhe klikoni te "Fjalët" për të hapur kutinë "Numri i fjalëve".
2. Aty do të shihni të gjitha llojet e statistikave. Sigurohuni që të keni zgjedhur kutinë "Përfshi kutitë e tekstit, shënimet në fund të faqes dhe shënimet fundore".
3. Pastaj klikoni "Mbyll".
4. Nëse nuk mund ta gjeni komandën "Fjalët" në shiritin e statusit, klikoni me të djathtën atje.
5. Më pas kontrolloni "Numërimin e Fjalëve".

Metoda 2: Përjashtoni tekstet nga kutitë e tekstit, fusnotat dhe shënimet fundore nga numërimi i fjalëve

Kjo është e kundërta me metodën 1. Kështu që ju vetëm duhet të zgjidhni kutinë "Përfshi kutitë e tekstit, fusnotat dhe shënimet fundore".

Metoda 3: Ekzekutoni makro Word për të marrë numërimin e veçantë të fjalëve nga kutitë e tekstit, fusnotat dhe shënimet fundore

1. Së pari, aktivizoni kutinë "Numërimi i fjalëve" duke përdorur mënyrën në metodën 1 dhe sigurohuni që kutia e opsioneve të jetë e kontrolluar.
2. Më pas shtypni "Alt+ F11" për të hapur redaktorin VBA.
3. Më pas futni një modul të ri në projektin “Normal” duke klikuar fillimisht “Normal”.
4. Dhe klikoni "Fut" më pas.
5. Zgjidhni "Moduli" më pas.
6. Klikoni dy herë mbi modulin për të hapur zonën e kodimit dhe ngjitni kodet e mëposhtme atje:

Sub SeparateCountNumberOfTextboxFootnoteEndnote()
  Dim lTextboxWords As Long
  Dim lTextboxChars As Long
  Dim lDocumntWords As Long
  Dim lDocumntChars As Long
  Dim objTextboxShape As Shape
  Dim objTemp As Dialog
  Dim bDone As Boolean
  Dim objRange As Range
  Dim lFootnoteWords As Long
  Dim lFootnoteChars As Long
  Dim lEndnoteWords As Long
  Dim lEndnoteChars As Long
 
  Application.ScreenUpdating = False

 Do
   bDone = True
   For Each objTextboxShape In ActiveDocument.Shapes
     If objTextboxShape.Type = msoGroup Then
       objTextboxShape.Ungroup
       bDone = False
     End If
   Next objTextboxShape
 Loop Until bDone

 '  Count the words and characters in the whole document.
 Selection.HomeKey Unit:=wdStory
 Set objTemp = Dialogs(wdDialogToolsWordCount)
   objTemp.Update
   objTemp.Execute
   lDocumntWords = objTemp.Words
   lDocumntChars = objTemp.Characters
 
 With ActiveDocument
 '  Count the words and characters in all textboxes.
   lTextboxWords = 0
   lTextboxChars = 0
   If ActiveDocument.Shapes.Count > 0 Then
     For Each objTextboxShape In .Shapes
       objTextboxShape.Select
       objTemp.Execute
       lTextboxWords = lTextboxWords + objTemp.Words
       lTextboxChars = lTextboxChars + objTemp.Characters
     Next objTextboxShape
   Else
     MsgBox ("There is no text box in this document")
   End If

   '  Count the words and characters in all footnotes.
   lFootnoteWords = 0
   lFootnoteChars = 0
   If ActiveDocument.Footnotes.Count > 0 Then
     For Each objRange In .StoryRanges
       If objRange.StoryType = wdFootnotesStory Then
         objRange.Select
         objTemp.Execute
         lFootnoteWords = lFootnoteWords + objTemp.Words
         lFootnoteChars = lFootnoteChars + objTemp.Characters
       End If
     Next objRange
   Else
     MsgBox ("There is no footnote in this document")
   End If

   '  Count the words and characters in all endnotes. 
   lEndnoteWords = 0
   lEndnoteChars = 0
   If ActiveDocument.Endnotes.Count > 0 Then
     For Each objRange In .StoryRanges
       If objRange.StoryType = wdEndnotesStory Then
         objRange.Select
         objTemp.Execute
         lEndnoteWords = lEndnoteWords + objTemp.Words
         lEndnoteChars = lEndnoteChars + objTemp.Characters
       End If
     Next objRange
   Else
     MsgBox ("There is no Endnote in this document")
   End If
 End With
 
 Application.ScreenUpdating = True

 MsgBox (" In this document there are totally" & vbCr _
   & Str(lDocumntWords) & " word(s) and" & Str(lDocumntChars) & " characters" & vbCr & vbCr _
   & "Including:" & vbCr _
   & Str(ActiveDocument.Shapes.Count) & " textboxes contain(s)" & vbCr _
   & Str(lTextboxWords) & " word(s)," & Str(lTextboxChars) & " characters" & vbCr & vbCr _
   & Str(ActiveDocument.Footnotes.Count) & " footnotes contain(s)" & vbCr _
   & Str(lFootnoteWords) & " word(s)," & Str(lFootnoteChars) & " characters" & vbCr & vbCr _
   & Str(ActiveDocument.Endnotes.Count) & " Endnotes contain(s)" & vbCr _
   & Str(lEndnoteWords) & " word(s)," & Str(lEndnoteChars) & " characters")
End Sub

7. Në fund, klikoni në butonin "Run".

Nëse nuk ka kuti teksti, fusnotë ose shënim fundor, do të merrni një kuti mesazhi si kjo:

Thjesht klikoni "OK" për të vazhduar. Pastaj do të shihni një kuti tjetër, duke renditur të gjitha detajet e numërimit të fjalëve.

Merrni një mjet rikuperimi

Meqenëse Word mund të shembet krejt papritur, këshillohet që të merrni një produkt të avancuar riparimi për të kryer punën e ndreqjes. Një mjet i tillë mund të jetë një kursim i madh për Fjalë e korruptuar. Prandaj, shfrytëzoni kohën për të marrë një të tillë sa më shpejt të jetë e mundur.

Hyrje e autorit:

Vera Chen është një eksperte për rikuperimin e të dhënave DataNumen, Inc., e cila është lider botëror në teknologjitë e rikuperimit të të dhënave, duke përfshirë rregulloni xls pdf riparimin e produkteve softuerike. Për më shumë informacion vizitoni www.datanumen.com