3 mënyra të shpejta për të fshirë rreshtat dhe kolonat bosh në tabelën tuaj të Word-it

Në këtë postim, do t'ju shpjegojmë 3 mënyra të shpejta për të fshirë rreshtat dhe kolonat bosh në tabelën tuaj Word.

Tabelat janë thelbësore për një dokument, veçanërisht në mbajtjen e llojeve të ndryshme të të dhënave. Ndonjëherë, një tabelë e gjatë mund të tejkalojë një faqe dhe të shtrihet në disa. Pra, sapo një tabelë bëhet e gjatë dhe e ndërlikuar, ka masa që mund të bëni për ta thjeshtuar atë. Për shembull, mund të fshini rreshtat dhe kolonat bosh të panevojshme.

Më poshtë janë 3 metoda që mund të përdorni.

Metoda 1: Fshini me dorë rreshtat dhe kolonat bosh

1. Së pari, zgjidhni një rresht ose një kolonë bosh.
2. Pastaj kliko me të djathtën për të marrë menynë kontekstuale. Në meny, zgjidhni "Fshi rreshtat" ose "Fshi kolonat" në përputhje me rrethanat.

Fatkeqësisht, nuk mund të zgjidhni rreshta ose kolona të shumta jo të njëpasnjëshme dhe t'i fshini ato së bashku me këtë mënyrë. Për këtë kërkesë, mund t'i referoheni artikullit tonë të mëparshëm: 5 metoda të shpejta për të fshirë në grup rreshta ose kolona të shumta në tabelën tuaj të Word-it

Metoda 2: Fshini në grup të gjitha rreshtat dhe kolonat bosh në një tabelë

Metoda 1 ka kufizimet e saj. Pra, ne do t'ju ofrojmë mënyrën për të hequr rreshtat dhe kolonat në grup në një tabelë nëpërmjet kodeve VBA.

1. Për të filluar, vendosni kursorin brenda një tabele të synuar.
2. Së dyti, aktivizoni redaktorin VBA duke shtypur "Alt+ F11".
3. Në redaktues, klikoni fillimisht projektin "Normal".
4. Pastaj klikoni në skedën "Fut" në shiritin e menusë.
5. Në menunë rënëse, zgjidhni "Modul".
6. Klikoni dy herë në modul për ta hapur atë dhe ngjitni kodet e mëposhtme atje:

Sub DeleteBlankRowsAndTablesInATable()
  Dim objCell As Cell
  Dim nRowIndex As Integer, nRows As Integer, nColumns As Integer, nColumnIndex As Integer
  Dim varCellEmpty As Boolean
 
  Application.ScreenUpdating = False
 
  If Selection.Information(wdWithInTable) = False Then
    MsgBox ("Put cursor inside a table first!")
    Exit Sub
  Else
    With Selection.Tables(1)
      nRows = .Rows.Count
      For nRowIndex = nRows To 1 Step -1
        varCellEmpty = True
        For Each objCell In .Rows(nRowIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            .Rows(nRowIndex).Delete
          End If
      Next nRowIndex
 
      nColumns = .Columns.Count
      For nColumnIndex = nColumns To 1 Step -1
        varCellEmpty = True
        For Each objCell In .Columns(nColumnIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            .Columns(nColumnIndex).Delete
          End If
      Next nColumnIndex
    End With
  End If

  Set objCell = Nothing

  Application.ScreenUpdating = True
End Sub

7. Së fundi, klikoni butonin "Run" në shiritin e menusë ose shtypni "F5".

Në sekonda, do të hiqni të gjitha rreshtat dhe kolonat bosh në atë tabelë.

Metoda 3: Fshij në grup të gjitha rreshtat dhe kolonat bosh në të gjitha tabelat në një dokument

1. Së pari, përsëritni hapat në metodën 2 për të instaluar dhe ekzekutuar një makro.
2. Vetëm këtë herë, zëvendësojeni atë makro me sa vijon:

Sub DeleteBlankRowsAndColumnsInAllTables()
  Dim objCell As Cell
  Dim objTable As Table
  Dim nRowIndex As Integer, nRows As Integer, nColumns As Integer, nColumnIndex As Integer
  Dim varCellEmpty As Boolean
 
  Application.ScreenUpdating = False
 
  With ActiveDocument
    For Each objTable In .Tables
      nRows = objTable.Rows.Count
      For nRowIndex = nRows To 1 Step -1
        varCellEmpty = True
        For Each objCell In objTable.Rows(nRowIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            objTable.Rows(nRowIndex).Delete
          End If
      Next nRowIndex
    Next objTable
 
    For Each objTable In .Tables
      nColumns = objTable.Columns.Count
      For nColumnIndex = nColumns To 1 Step -1
        varCellEmpty = True
        For Each objCell In objTable.Columns(nColumnIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            objTable.Columns(nColumnIndex).Delete
          End If
      Next nColumnIndex
    Next objTable
  End With

  Set objCell = Nothing
  Set objTable = Nothing

  Application.ScreenUpdating = True
End Sub

Rikuperoni dokumentin e thyer

Në ditët e sotme ka më shumë se një mënyrë për të rikuperuar të dhënat e humbura. Për shembull, përdorimi i kopjeve rezervë mbetet gjithmonë përparësia juaj kryesore. Nëse kjo nuk e plotëson nevojën tuaj për të rikuperuar informacionin më të fundit, atëherë mund të provoni një riparim dok mjet.

Hyrje e autorit:

Vera Chen është një eksperte për rikuperimin e të dhënave DataNumen, Inc., e cila është lider botëror në teknologjitë e rikuperimit të të dhënave, duke përfshirë riparim xlsx pdf riparimin e produkteve softuerike. Për më shumë informacion vizitoni www.datanumen.com