2 metoda për të dërguar me shpejtësi qelizat e zgjedhura në një fletë pune në Excel si një email të Outlook

Ndonjëherë, mund të dëshironi të futni shpejt qelizat e zgjedhura në një fletë pune Excel në një email të Outlook dhe ta dërgoni këtë email. Ky artikull do të shikojë këtë dëshirë për t'ju ofruar 2 metoda.

Artikulli im i mëparshëm "2 Metoda të shpejta për të dërguar një fletë pune në Excel si një email të Outlook” ju ka mësuar se si të dërgoni një fletë pune të tërë në Excel si email. Megjithatë, ndonjëherë, ju dëshironi të dërgoni vetëm qelizat e zgjedhura në një fletë pune si një email. Në përgjigje të kësaj kërkese, këtu do t'ju ekspozojmë 2 metoda. Ju mund të zgjidhni ose sipas preferencës tuaj.

Metoda 1: Kopjoni manualisht qelizat e zgjedhura në email

1. Për të filluar, hapni skedarin burimor Excel dhe hyni në fletën e punës së duhur të Excel-it.
2. Pastaj zgjidhni qelizat që dëshironi të dërgoni si një email të Outlook.
3. Më pas shtypni shkurtoret e tastit "Ctrl + C" për të kopjuar qelizat e zgjedhura.
4. Pas kësaj, hapni aplikacionin tuaj Outlook.
5. Më pas, klikoni në butonin "Email i ri" në shiritin "Home" për të krijuar një email të ri të Outlook.
6. Më vonë në dritaren e re të Mesazhit, klikoni në seksionin e trupit të mesazhit.
7. Dhe më pas shtypni butonat "Ctrl + V" për të ngjitur qelizat e zgjedhura të Excel të kopjuara më parë.
8. Së fundi, ju mund të shkruani emailin si zakonisht dhe të klikoni butonin "Dërgo" për ta dërguar atë.

Metoda 2: Dërgoni qelizat e zgjedhura si email përmes VBA

1. Që në fillim, hapni librin e punës burim Excel.
2. Më pas shtypni butonat "Alt + F11" për të hyrë në redaktuesin Excel VBA.
3. Në dritaren e re, klikoni "Insert" > "Module" për të futur një modul të ri.
4. Më pas duhet të aktivizohet Microsoft Outlook Object. Klikoni “Tools” > “References”. Në kutinë e dialogut që shfaqet, gjeni dhe kontrolloni “Microsoft Outlook Object Library”.
5. Më pas, kopjoni kodin e mëposhtëm VBA në këtë modul.

Sub SendSelectedCells_inOutlookEmail()
    Dim objSelection As Excel.Range
    Dim objTempWorkbook As Excel.Workbook
    Dim objTempWorksheet As Excel.Worksheet
    Dim strTempHTMLFile As String
    Dim objTempHTMLFile As Object
    Dim objFileSystem As Object
    Dim objTextStream As Object
    Dim objOutlookApp As Outlook.Application
    Dim objNewEmail As Outlook.MailItem
 
    'Copy the selection
    Set objSelection = Selection
    Selection.Copy
 
    'Paste the copied selected ranges into a temp worksheet
    Set objTempWorkbook = Excel.Application.Workbooks.Add(1)
    Set objTempWorksheet = objTempWorkbook.Sheets(1)
 
    'Keep the values, column widths and formats in pasting
    With objTempWorksheet.Cells(1)
         .PasteSpecial xlPasteValues
         .PasteSpecial xlPasteColumnWidths
         .PasteSpecial xlPasteFormats
    End With
 
    'Save the temp worksheet as a HTML file
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    strTempHTMLFile = objFileSystem.GetSpecialFolder(2).Path & "\Temp for Excel" & Format(Now, "YYYY-MM-DD hh-mm-ss") & ".htm"
    Set objTempHTMLFile = objTempWorkbook.PublishObjects.Add(xlSourceRange, strTempHTMLFile, objTempWorksheet.Name, objTempWorksheet.UsedRange.Address)
    objTempHTMLFile.Publish (True)
 
    'Create a new email
    Set objOutlookApp = CreateObject("Outlook.Application")
    Set objNewEmail = objOutlookApp.CreateItem(olMailItem)
 
    'Read the HTML file data and insert into the email body
    Set objTextStream = objFileSystem.OpenTextFile(strTempHTMLFile)
    objNewEmail.HTMLBody = objTextStream.ReadAll
    objNewEmail.Display
    'You can specify the new email recipients, subjects here using the following lines:
    'objNewEmail.To = "johnsmith@datanumen.com"
    'objNewEmail.Subject = "DataNumen Products"
    'objNewEmail.Send --> directly send out this email
 
    objTextStream.Close
    objTempWorkbook.Close (False)
    objFileSystem.DeleteFile (strTempHTMLFile)
End Sub

6. Më në fund, mund të provoni.

• Së pari, zgjidhni qelizat specifike si zakonisht.
• Pastaj kthehuni te makroja e re dhe shtypni tastin F5 për ta aktivizuar atë.
• Menjëherë, do të shfaqet një email i ri i Outlook, në të cilin mund të shihni se qelizat e zgjedhura janë futur në trupin e postës elektronike, si pamja e mëposhtme e ekranit:

Skedari PST është njësoj i cenueshëm si skedari Excel

Siç e dimë, skedarët Excel dhe dokumentet Word janë të prirur ndaj korruptimit. Në fakt, e njëjta gjë vlen edhe për skedarin PST, i cili përmban të gjitha artikujt në kutinë tuaj postare të Outlook. Pra, është një detyrë e vështirë të sigurohen të dhënat tuaja PST. Një nga masat më efektive është të bëni kopje rezervë të skedarit rregullisht. Plus, për të siguruar shpëtim të menjëhershëm, është më mirë të përgatitni një mjet me përvojë, siç është DataNumen Outlook Repair, e cila është në gjendje të rikuperoni Outlook të dhëna pa u djersitur.

Hyrje e autorit:

Shirley Zhang është një eksperte për rikuperimin e të dhënave DataNumen, Inc., e cila është lider botëror në teknologjitë e rikuperimit të të dhënave, duke përfshirë riparim mdf dhe produkte softuerike të riparimit të pamjes. Për më shumë informacion vizitoni www.datanumen.com