2 mënyra të shpejta për të nxjerrë seksione nga dokumenti juaj Word

Në këtë artikull, ne do t'ju ofrojmë 2 mënyra të shpejta dhe të lehta për të nxjerrë seksione nga dokumenti juaj Word në një ose disa.

Ndodh mjaft shpesh të nxjerrësh përmbajtje nga një dokument në tjetrin. Dhe në artikullin tonë të mëparshëm, ne kemi diskutuar se si të nxjerrim faqe nga dokumenti. Për informacion të detajuar, mund t'i referoheni këtij artikulli: 2 mënyra të shpejta për të nxjerrë faqe individuale nga dokumenti juaj Word

Sot, ne do t'ju tregojmë se si të nxjerrni sipas seksionit.    

Metoda 1: Ekstraktoni seksionin aktual në një dokument të ri

1. Para së gjithash, poziciononi kursorin në një seksion të synuar.
2. Më pas shtypni "Alt+ F11" për të thirrur redaktorin VBA në Word.
3. Pastaj në kolonën e majtë, klikoni në "Normal".
4. Dhe në shiritin e menusë, klikoni "Fut".
5. Pastaj zgjidhni "Modul" në atë menu rënëse.
6. Klikoni dy herë për të hapur modulin e ri dhe ngjitni kodet e mëposhtme atje:

Sub SaveCurrentSectionAsNewDoc()
  Dim strFolder As String
  Dim dlgFile As FileDialog
  Dim strNewFileName As String
  Dim objDocAdded As Document
  Dim objDoc As Document
 
  ' Initialization
  Set objDoc = ActiveDocument
 
  ' Pick a place to store the new file.
  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
  With dlgFile
    If .Show = -1 Then
      strFolder = .SelectedItems(1) & "\"
    Else
      MsgBox "Select a folder first!"
      Exit Sub
    End If
  End With
 
  strNewFileName = InputBox("Enter new file name here: ", "File Name")
 
  ' Select and copy current section range.
  objDoc.Bookmarks("\Section").Range.Select
  Selection.Copy
 
  ' Open a new document to paste the above selection.
  Set objDocAdded = Documents.Add
  Selection.Paste
 
  ' Save and close the new document.
  objDocAdded.SaveAs FileName:=strFolder & strNewFileName & ".docx"
  objDocAdded.Close
End Sub

7. Më pas, klikoni "Run" në shiritin e menusë ose shtypni "F5".
8. Pastaj do të shfaqet dritarja "Shfleto". Zgjidhni një vend për të ruajtur dokumentin e ri dhe klikoni "OK".
9. Dhe në kutinë "Emri i skedarit", shkruani emrin për skedarin e ri dhe klikoni "OK".

Tani e keni nxjerrë seksionin në një dokument të ri.

Metoda 2: Ekstraktoni çdo seksion në dokument tek të rejat individuale

Kjo mënyrë mund t'ju ndihmojë të përpunoni në grup të gjitha seksionet në një dokument. Natyrisht, do të na duhet gjithashtu një makro.

1. Për të filluar, hapni dokumentin e synuar.
2. Më pas ndiqni hapat në metodën 1 për të instaluar dhe ekzekutuar një makro.
3. Vetëm këtë herë zëvendësojeni atë makro me këtë:

Sub SaveEachSectionAsADoc()
  Dim objDocAdded As Document
  Dim objDoc As Document
  Dim nSectionNum As Integer
  Dim strFolder As String

  Dim dlgFile As FileDialog
 
  ' Initialization
  Set objDoc = ActiveDocument
 
  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
  ' Pick a location to keep new files.
  With dlgFile
    If .Show = -1 Then
      strFolder = .SelectedItems(1) & "\"
    Else
      MsgBox "Select a folder first!"
      Exit Sub
    End If
  End With
 
  ' Step through each section in current document, copy and paste each to a new one.
  For nSectionNum = 1 To ActiveDocument.Sections.Count
    Selection.GoTo What:=wdGoToSection, Which:=wdGoToNext, Name:=nSectionNum
    ActiveDocument.Sections(nSectionNum).Range.Copy
 
    Set objDocAdded = Documents.Add
    Selection.Paste
 
    ' Save and close new documents.
    objDocAdded.SaveAs FileName:=strFolder & "Section " & nSectionNum & ".docx"
    objDocAdded.Close
  Next nSectionNum
End Sub

4. Megjithatë, në dritaren "Shfleto", zgjidhni një shteg ruajtjeje dhe klikoni "OK".

Rregulloni gabimet irrituese të fjalës

Është e zakonshme të hasësh disa gabime të Word-it gjatë përdorimit të tij. Mund të jetë e bezdisshme, duhet të gjejmë kohë për të rikuperoj fjalën sa me shpejt te jete e mundur. Sepse sa më shumë ta vonojmë, aq më e rëndë mund të jetë humbja e të dhënave. Prandaj, sugjerohet që të merrni paraprakisht një pajisje riparimi.

Hyrje e autorit:

Vera Chen është një eksperte për rikuperimin e të dhënave DataNumen, Inc., e cila është lider botëror në teknologjitë e rikuperimit të të dhënave, duke përfshirë xls i korruptuar pdf riparimin e produkteve softuerike. Për më shumë informacion vizitoni www.datanumen.com