Si të gjeni shpejt paragrafë me një fjali në dokumentin tuaj Word

Në këtë postim, duam t'ju tregojmë mënyrën e shpejtë për të gjetur të gjitha paragrafët me një fjali në dokumentin tuaj Word përmes VBA-së.

Herë pas here, disa dokumente mund të kenë kërkesa shumë specifike për formatimin dhe strukturën e tyre. Për shembull, mund të mos ju lejohet të keni paragrafë me vetëm një fjali. Këta paragrafë nuk janë të vështirë për t'u njohur, por kërkon kohë, veçanërisht është një dokument i gjatë.

Sot, ne do t'ju ofrojmë mënyrën e shpejtë për të specifikuar të gjithë paragrafët me një fjali në dokumentin tuaj.

Gjeni të gjithë paragrafët me një fjali në një dokument

1. Së pari, Word numëron një pikë si një fjali. Pra, nëse ka fjalë të tilla si "Z.". ose “Zonja”, Fjala e konsideron si fjali. Për të përjashtuar një shpërqendrim të tillë, duhet të zëvendësoni "Z.". me “z. Dhe kur të mbaroni gjeni paragrafin e fjalisë së vetme, mund t'i ndryshoni ato përsëri. Për të zëvendësuar fjalët, mund t'i referoheni kësaj lidhjeje: Si të gjeni dhe zëvendësoni disa artikuj në dokumentin tuaj Word
2. Së dyti, shtypni "Alt+ F11" për të aktivizuar redaktorin VBA.
3. Pastaj klikoni projektin "Normal".
4. Klikoni në skedën "Fut" në shiritin e menusë dhe zgjidhni "Modul" në menunë e tij rënëse.
5. Pastaj klikoni dy herë në modul për ta hapur atë.
6. Ngjitni kodet e mëposhtme në modul:

Sub HighlightParagraphsWithSingleSentence()
  Dim nParagraphNum As Integer
  Dim nCountParagraph As Integer
  Dim objParagraphRange As Range
  Dim nCountSentence As Integer
  Dim nHighlightNum As Integer
 
  nCountParagraph = ActiveDocument.Paragraphs.Count
  nHighlightNum = 0
 
  For nParagraphNum = 1 To nCountParagraph
    Set objParagraphRange = ActiveDocument.Paragraphs(nParagraphNum).Range
    nCountSentence = objParagraphRange.Sentences.Count
    ' Highlight all paragraphs with single-sentence.
    If nCountSentence = 1 And objParagraphRange.Characters.Count > 1 Then
      nHighlightNum = nHighlightNum + 1
      objParagraphRange.HighlightColorIndex = wdYellow
    End If
  Next

  If nHighlightNum > 0 Then
    MsgBox ("There are " & nHighlightNum & " paragraphs with single sentence and they are highlighted.")
  Else
    MsgBox ("There are no paragraphs with single sentence")
  End If

End Sub

7. E fundit, por jo më pak e rëndësishmja, klikoni butonin "Run" ose shtypni "F5".

Ju do të merrni një kuti të tillë mesazhi, duke ju thënë se puna ka përfunduar.

Gjeni të gjithë paragrafët me një fjali në shumë dokumente

1. Për të filluar, duhet të vendosni të gjitha dokumentet e synuara në një dosje.
2. Pastaj instaloni dhe ekzekutoni makronë e mëposhtme:

Sub HighlightParagraphsWithSingleSentenceInMultipleFiles()
  Dim nParagraphNum As Integer
  Dim nCountParagraph As Integer
  Dim objParagraphRange As Range
  Dim nCountSentence As Integer
  Dim StrFolder As String
  Dim strFile As String
  Dim objDoc As Document
  Dim dlgFile As FileDialog
  Dim nHighlightNum As Integer
  Dim strSummary As String

  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)

  With dlgFile
    If .Show = -1 Then
      StrFolder = .SelectedItems(1) & "\"
    Else
      MsgBox ("No Folder is selected!")
      Exit Sub
    End If
  End With
 
  strFile = Dir(StrFolder & "*.doc*", vbNormal)
 
  While strFile <> ""
    nHighlightNum = 0
    Set objDoc = Documents.Open(FileName:=StrFolder & strFile)
    Set objDoc = ActiveDocument
    nCountParagraph = ActiveDocument.Paragraphs.Count
 
    For nParagraphNum = 1 To nCountParagraph
      Set objParagraphRange = ActiveDocument.Paragraphs(nParagraphNum).Range
      nCountSentence = objParagraphRange.Sentences.Count
      ' Highlight all paragraphs with single-sentence.
      If nCountSentence = 1 And objParagraphRange.Characters.Count > 1 Then
        nHighlightNum = nHighlightNum + 1
        objParagraphRange.HighlightColorIndex = wdYellow
      End If
    Next
    objDoc.ActiveWindow.ActivePane.View.SeekView = wdSeekMainDocument
    objDoc.Save
    If nHighlightNum = 0 Then
      objDoc.Close
    End If
 
    strSummary = strSummary & strFile & " : " & nHighlightNum & " paragraphs with single sentence." & vbCrLf
    strFile = Dir()
  Wend
  MsgBox (strSummary)
 
End Sub

3. Në dritaren e hapur "Shfleto", zgjidhni dosjen ku mbani dokumentet dhe klikoni "OK".

Më pas makroja do të nxjerrë në pah të gjithë paragrafët me një fjali dhe do t'i lërë dokumentet të hapura. Nëse një dokument nuk përmban një paragraf me një fjali, ai do të mbyllet. Përveç kësaj, ekziston një kuti mesazhesh, që tregon numrin e paragrafëve me një fjali në çdo dokument.

Merreni me incidentin e humbjes së të dhënave

Gabimet e përdoruesit dhe ndërprerja e papritur e energjisë mund të rezultojnë në vdekjen e Word-it. Ndërsa një Fjalë e shembur jo vetëm që mund të ndikojë në punën e përditshme, por edhe të çojë në dëmtimi i dokumentitKjo nuk është aspak pjesa më bezdisëse e një katastrofe të dhënash. Është më mirë të merrni një program riparimi për të rikuperuar të dhënat menjëherë.

Hyrje e autorit:

Vera Chen është një eksperte për rikuperimin e të dhënave DataNumen, Inc., e cila është lider botëror në teknologjitë e rikuperimit të të dhënave, duke përfshirë rikuperoni excel pdf riparimin e produkteve softuerike. Për më shumë informacion vizitoni www.datanumen.com