Si të nxirrni shpejt të gjitha adresat e postës elektronike nga trupat e emaileve të shumëfishta të Outlook

Shumë përdorues dëshirojnë një metodë për të nxjerrë me shpejtësi të gjitha adresat e emailit nga trupi i një emaili të Outlook, apo edhe emaile të shumta. Prandaj, ky artikull do të shqyrtojë këtë çështje dhe do t'ju ndajë një metodë të shpejtë e cila është duke përdorur VBA.

Kur dikush ju dërgon një email, trupi i të cilit përmban një listë të adresave të postës elektronike, nëse doni të përdorni këto adresa emaili për disa arsye, si shtimi në dosjen tuaj të Kontakteve ose të tjera, duhet së pari të nxirrni të gjitha adresat e emailit në trup. . Prandaj, në vijim do t'ju tregojmë se si ta arrini atë me VBA.

Ekstraktoni të gjitha adresat e postës elektronike nga trupi i emaileve të shumëfishta të Outlook

1. Që në fillim, hapni aplikacionin tuaj Outlook.
2. Pastaj, pasi të keni hyrë në dritaren kryesore të Outlook, mund të shtypni butonat "Alt + F11".
3. Më pas, në dritaren e re "Microsoft Visual Basic për Aplikacione", duhet të hapni një modul të papërdorur ose thjesht të futni një të ri.
4. Më vonë, duhet të kopjoni dhe ngjisni kodin e mëposhtëm VBA në këtë modul.

Sub ExtractEmailAddresses_BodyofMultipleEmails()
    Dim objSelection As Outlook.Selection
    Dim objMail As Outlook.MailItem
    Dim i, n As Long
    Dim objWordApp As Word.Application
    Dim objWordDocument As Word.Document
    Dim strEmailAddresses As String
    Dim objFileSystem As Object
    Dim strTextFile As String
    Dim objTextFile As Object
 
    Set objSelection = Outlook.Application.ActiveExplorer.Selection
 
    If Not (objSelection Is Nothing) Then
 
       i = 0
       n = 1
       On Error Resume Next
       For i = objSelection.count To 1 Step -1
           Set objMail = objSelection.Item(i)
 
           objMail.Display
 
           Set objWordDocument = objMail.GetInspector.WordEditor
           Set objWordApp = objWordDocument.Application
           Set objSearchRange = objWordDocument.Range

           'Find the email addresses via wildcards
           With objWordApp.Selection.Find
                .Text = "[A-z,0-9]{1,}\@[A-z,0-9,.]{1,}"
                .MatchWildcards = True
                .Execute
           End With
 
           While objWordApp.Selection.Find.Found
                 'Get a list of email addresses in the body
                 strEmailAddresses = strEmailAddresses & n & ": " & objWordApp.Selection.Text & vbCrLf
                 objWordApp.Selection.Find.Execute
                 n = n + 1
           Wend
           objMail.Close olDiscard
      Next
    End If
 
    'Create a new Text file
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    strTextFile = "E:\Extracted Email Addresses-" & Format(Date, "YYYYMMDD") & ".txt"
    Set objTextFile = objFileSystem.CreateTextFile(strTextFile, True)
 
    'Input the list of extracted email addresses into this Text file
    objTextFile.WriteLine (strEmailAddresses)
    objTextFile.Close
 
    MsgBox "Completed!", vbInformation, "Extract Email Addresses"
End Sub

5. Më vonë, mund të dilni nga dritarja aktuale e redaktuesit VBA dhe të vazhdoni të shtoni makro të re në shiritin e veglave të aksesit të shpejtë.
6. Pas kësaj, duhet të ndryshoni nivelin e sigurisë makro Outlook në të ulët.
7. Më në fund, mund të provoni.

• Së pari, në listën e postës elektronike, zgjidhni emaile të shumta të Outlook, nga trupi i të cilëve duhet të nxirrni adresat e emailit.
• Pastaj klikoni në butonin e ri në shiritin e veglave të aksesit të shpejtë.
• Kur merrni një mesazh që ju kërkon "Përfunduar", mund të shkoni te dosja e paracaktuar në kodin VBA për të gjetur një skedar të ri .TXT.
• Hapeni këtë skedar dhe do të shihni se të gjitha adresat e postës elektronike të nxjerra, shfaqen si pamja e mëposhtme e ekranit:

Mbrojtja e Outlook kundër makrove me qëllim të keq

Nëse e keni vendosur Outlook-un tuaj që të lejojë të gjitha makrot, duhet të mbani një sy për të gjitha makrot e maskuara në emailet e panjohura. Kjo është për shkak se ato mund të përmbajnë shumë viruse të fshehura, të cilat mund të shkaktojnë drejtpërdrejt korrupsionin e Outlook. Skedari PST i infektuar me virus është mjaft i vështirë për t'u rikuperuar. Në atë kohë, ndoshta mjeti juaj i fundit është i fuqishëm dhe i besueshëm Rregullimi i Outlook dobi, si p.sh DataNumen Outlook Repair. Mund të riparojë skedarin Outlook pa marrë parasysh sa ekstrem është dëmtimi.

Hyrje e autorit:

Shirley Zhang është një eksperte për rikuperimin e të dhënave DataNumen, Inc., e cila është lider botëror në teknologjitë e rikuperimit të të dhënave, duke përfshirë sql e korruptuar dhe produkte softuerike të riparimit të pamjes. Për më shumë informacion vizitoni www.datanumen.com