Si të eksportoni shpejt numrin total të artikujve në secilën dosje të Outlook në Excel

Nëse dëshironi të merrni një raport për numrin e artikujve në çdo dosje Outlook, mund të përdorni metodën e prezantuar në këtë artikull. Ai shpejt do të bëjë numërimin dhe do të eksportojë rezultatet në një skedar Excel.

Në artikullin tim të mëparshëm - "Si të merrni shpejt numrin total të artikujve në një dosje dhe të gjithë nëndeshet e tij përmes Outlook VBA”, mund të mësoni një metodë duke përdorur VBA për të marrë numrin e artikujve në një dosje. Sidoqoftë, në këtë mënyrë, nëse doni të numëroni artikujt në të gjitha dosjet, duhet të zgjidhni çdo dosje dhe të ekzekutoni makro një nga një. Është pak e lodhshme. Prandaj, ne do t'ju mësojmë një metodë tjetër, e cila do të eksportojë numërimin në një skedar Excel.

Eksportoni numrin total të artikujve në secilën dosje të Outlook në Excel

1. Në fillim, nisni programin tuaj Outlook.
2. Pastaj shtypni butonat "Alt + F11" në dritaren kryesore të Outlook.
3. Më pas do të futeni në dritaren "Microsoft Visual Basic për Aplikacione", në të cilën duhet të hapni një modul që nuk është në përdorim.
4. Më pas, kopjoni dhe ngjisni kodin e mëposhtëm VBA në këtë modul.

Public strExcelFile As String
Public objExcelApp As Excel.Application
Public objExcelWorkbook As Excel.Workbook
Public objExcelWorksheet As Excel.Worksheet

Sub Export_CountOfItems_InEachFolder_toExcel()
    Dim objSourcePST As Outlook.Folder
    Dim objFolder As Outlook.Folder
 
    'Create a new Excel file
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets("Sheet1")
    objExcelWorksheet.Cells(1, 1) = "Folder"
    objExcelWorksheet.Cells(1, 2) = "Count Items"
 
    'Select a source PST file
    Set objSourcePST = Outlook.Application.Session.PickFolder

    For Each objFolder In objSourcePST.folders
        Call ProcessFolders(objFolder)
    Next
 
    'Fit the columns from A to B
    objExcelWorksheet.Columns("A:B").AutoFit
 
    strExcelFile = "E:\Outlook\" & objSourcePST.Name & " Folder Items Count (" & Format(Now, "yyyy-mm-dd hh-mm-ss") & ").xlsx"
    objExcelWorkbook.Close True, strExcelFile

    MsgBox "Complete!", vbExclamation
End Sub

Sub ProcessFolders(ByVal objCurrentFolder As Outlook.Folder)
    Dim objItem As Object
    Dim lCurrentFolderItemCount As Long
    Dim nLastRow As Integer
 
    lCurrentFolderItemCount = objCurrentFolder.Items.Count
 
    nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1

    'Add the values into the columns
    objExcelWorksheet.Range("A" & nLastRow) = objCurrentFolder.FolderPath
    objExcelWorksheet.Range("B" & nLastRow) = lCurrentFolderItemCount
 
    If objCurrentFolder.folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.folders
           Call ProcessFolders(objSubfolder)
       Next
    End If
End Sub

5. Pas kësaj, duhet të ndryshoni nivelin e sigurisë makro Outlook në të ulët.
6. Më pas mund të ktheheni te makroja e sapo shtuar dhe të shtypni butonin e tastit F5 për të ekzekutuar këtë makro.
7. Tjetra ju duhet të zgjidhni një skedar burimi PST dhe shtypni "OK".
8. Pasi të përfundojë makroja, mund të shkoni në dosjen e paracaktuar lokale për të gjetur skedarin e ri Excel, i cili do të duket si pamja e mëposhtme e ekranit:

Zgjidh gabimet e bezdisshme PST

Ndoshta ju keni hasur në probleme të ndryshme gjatë përdorimit të Outlook. Për t'u marrë me çështjet e vogla, thjesht mund t'i drejtoheni mjet për riparimin e kutisë hyrëse. Megjithatë, nëse problemet janë aq serioze sa kanë qenë përtej asaj që mund të bëjë mjeti i integruar, duhet të përdorni një mjet më të fuqishëm, si p.sh. DataNumen Outlook Repair.

Hyrje e autorit:

Shirley Zhang është një eksperte për rikuperimin e të dhënave DataNumen, Inc., e cila është lider botëror në teknologjitë e rikuperimit të të dhënave, duke përfshirë riparim mdf dhe produkte softuerike të riparimit të pamjes. Për më shumë informacion vizitoni www.datanumen.com