Si të eksportoni shpejt të gjitha hiperlidhjet në shumë emaile të Outlook në Excel

Kur duhet të nxirrni të gjitha hiperlidhjet në një ose më shumë email-e, është budallallëk t'i kopjoni ato një nga një. Ky postim do t'ju mësojë një metodë për të eksportuar shpejt të gjitha hiperlidhjet në shumë email-e në Excel.

Për disa arsye, të tilla si regjistrimi i hiperlidhjeve në të gjitha emailet tuaja të dërguara, do t'ju duhet të nxirrni hiperlidhjet. Pa asnjë dyshim, është e padëshirueshme të nxirren dhe kopjohen ato me dorë. Ju duhet të dëshironi një qasje shumë më të zgjuar, siç është përdorimi i VBA. Këtu do t'ju ndajmë një pjesë të tillë të kodit VBA, i cili është në gjendje të eksportojë të gjitha hiperlidhjet në shumë email në Excel me një klikim të lehtë.

Eksporto të gjitha hiperlidhjet në shumë emaile në Excel

1. Për të filluar, hapni programin Outlook si zakonisht.
2. Pastaj, në dritaren e Outlook, duhet të shtypni butonat "Alt + F11".
3. Menjëherë, do të keni akses në redaktuesin VBA të Outlook.
4. Më pas, duhet të aktivizoni “Microsoft Word Object Library” si dhe “Microsoft Excel Object Library”. Klikoni “Tools” > “References” dhe më pas aktivizojini ato në kutinë e dialogut që shfaqet.
5. Më pas, duhet të hapni një modul të papërdorur, në të cilin duhet të kopjoni kodin VBA më poshtë në këtë modul.

Dim objExcelApp As Excel.Application
Dim objExcelWorkbook As Excel.Workbook
Dim objExcelWorksheet As Excel.Worksheet

Sub ExportAllHyperlinksInMultipleEmailsToExcel()
    Dim objSelection As Selection
    Dim objMail As MailItem
    Dim objMailDocument As Document
    Dim objHyperlink As Hyperlink
    Dim i As Long
 
    Set objSelection = Outlook.Application.ActiveExplorer.Selection
 
    If Not (objSelection Is Nothing) Then
 
       Set objExcelApp = CreateObject("Excel.Application")
       Set objExcelWorkbook = objExcelApp.Workbooks.Add
       Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
       objExcelApp.Visible = True
       objExcelWorkbook.Activate
 
       With objExcelWorksheet
            .Cells(1, 1) = "No."
            .Cells(1, 2) = "Displaying Text"
            .Cells(1, 3) = "Address"
            .Cells(1, 4) = "Source Mail"
      End With
 
      On Error Resume Next
      i = 0
      For Each objMail In objSelection
          objMail.Display
          Set objMailDocument = objMail.GetInspector.WordEditor
          If objMailDocument.Hyperlinks.Count > 0 Then
             For Each objHyperlink In objMailDocument.Hyperlinks
                 If InStr(objHyperlink.Address, "www.") > 0 Then
                    i = i + 1
                    Call ExportToExcel(i, objMail, objHyperlink)
                 End If
             Next
          End If
          objMail.Close olDiscard
      Next
 
      objExcelWorksheet.Columns("A:D").AutoFit
    End If
End Sub

Sub ExportToExcel(n As Long, objCurrentMail As MailItem, objCurrentHyperlink As Hyperlink)
    Dim nLastRow As Integer
 
    nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
 
    objExcelWorksheet.Range("A" & nLastRow) = n
    objExcelWorksheet.Range("B" & nLastRow) = objCurrentHyperlink.TextToDisplay
    objExcelWorksheet.Range("C" & nLastRow) = objCurrentHyperlink.Address
    objExcelWorksheet.Range("D" & nLastRow) = objCurrentMail.Subject
End Sub

6. Pas kësaj, mund të dilni nga dritarja aktuale e redaktuesit VBA.
7. Më vonë hyni në "Opsionet e Outlook" për të personalizuar Shiritin e Veglave të Qasjes së Shpejtë për të shtuar makronë e sapo shtuar në Shiritin e Veglave të Qasjes së Shpejtë.
8. Më në fund mund të bëni një fotografi:

• Së pari, në listën e postës elektronike, zgjidhni emailet, lidhjet e të cilave dëshironi të nxirrni.
• Pastaj, klikoni në butonin makro në shiritin e veglave të aksesit të shpejtë.
• Kur makro të përfundojë, do të merrni një skedar Excel, si imazhi më poshtë:

Rregulloni problemet e papritura të Outlook

Problemet me Outlook mund të ndodhin herë pas here pa asnjë shenjë. Por, për sa i përket gabimeve të vogla, Outlook mund të rikuperohet me një rinisje të thjeshtë ose... mjet për riparimin e kutisë hyrëse. Por nëse hasni disa telashe të rënda, mjetet e brendshme nuk do të japin efekte. Në këtë pikë, mjeti juaj i fundit është padyshim një mjet më i njohur dhe më i fortë, si p.sh DataNumen Outlook Repair.

Hyrje e autorit:

Shirley Zhang është një eksperte për rikuperimin e të dhënave DataNumen, Inc., e cila është lider botëror në teknologjitë e rikuperimit të të dhënave, duke përfshirë mdf i korruptuar dhe produkte softuerike të riparimit të pamjes. Për më shumë informacion vizitoni www.datanumen.com