Si të bashkëngjitni shpejt rrëshqitjet specifike të a PowerPoint Prezantimi në emailin tuaj të Outlook

Nëse dëshironi të nxirrni sllajdet specifike të a PowerPoint prezantimi në një prezantim të ri të veçantë dhe bashkëngjitni atë në një email të Outlook, ju mund të përdorni mënyrën e ndarë në këtë artikull.

Në vend që të bashkëngjitni një të tërë PowerPoint prezantimi në një email, nëse dëshironi të bashkëngjitni sllajde specifike të prezantimit, në përgjithësi, fillimisht duhet të kopjoni sllajdet specifike në një prezantim të ri. Është shumë e mundimshme. Prandaj, këtu do t'ju tregojmë një metodë që mund ta realizojë atë me një lëvizje.

Bashkangjitni Slides Specifike të a PowerPoint Prezantimi në një email

1. Së pari, hapni specifikën PowerPoint prezantim.
2. Pastaj, në PowerPoint dritaren e aplikacionit, shtypni butonat "Alt + F11" për të hyrë në redaktuesin VBA.
3. Më pas, në dritaren e re, krijoni një modul të ri duke shtypur "Fut" > "Moduli".
4. Më pas, kopjoni dhe ngjisni kodin e mëposhtëm VBA në këtë modul.

Sub AttachSpecificSlidesToOutlookEmail()
    Dim objActivePresetation As Presentation
    Dim objSlide As Slide
    Dim n As Long
    Dim strName As String
    Dim strTempPresetation As String
    Dim objTempPresetation As Presentation
    Dim objOutlookApp As Object
    Dim objMail As Object
 
    Set objActivePresetation = ActivePresentation
 
    For Each objSlide In objActivePresetation.Slides
        objSlide.Tags.Delete ("Selected")
    Next
 
    'Add a tag "Selected" to the selected slides
    For n = 1 To ActiveWindow.Selection.SlideRange.Count
        ActiveWindow.Selection.SlideRange(n).Tags.Add "Selected", "YES"
    Next n
 
    strName = objActivePresetation.Name
    strName = Left(strName, InStrRev(strName, ".") - 1)
    strTempPresetation = Environ("TEMP") & "\" & strName & ".pptx"
 
    'Copy the active presentation to a temp presentation
    objActivePresetation.SaveCopyAs strTempPresetation
    Set objTempPresetation = Presentations.Open(strTempPresetation)
 
    'Remove the untagged slides
    For n = objTempPresetation.Slides.Count To 1 Step -1
        If objTempPresetation.Slides(n).Tags("Selected") <> "YES" Then
           objTempPresetation.Slides(n).Delete
        End If
    Next n
 
    objTempPresetation.Save
    objTempPresetation.Close
 
    'Attach the temp presentation to a new email
    Set objOutlookApp = CreateObject("Outlook.Application")
    Set objMail = objOutlookApp.CreateItem(olMailItem)
 
    'Change the email details as per your needs
    With objMail
         .To = "test@datanumen.com"
         .Subject = strName
         .Body = "Dear," & vbCr & vbCr & vbTab & "Specific slides are extracted and attached."
         .Attachments.Add strTempPresetation
         .Display
    End With
End Sub

5. Pas kësaj, ju mund të mbyllni dritaren aktuale.
6. Më vonë, shkoni te "Skedari" > "Opsionet" > "Shiri i veglave të aksesit të shpejtë" për të shtuar makro të re në shiritin e veglave të aksesit të shpejtë.
7. Më në fund, mund ta provoni këtë makro.

• Për të filluar, zgjidhni diapozitivat specifike që dëshironi të nxirrni.
• Pastaj, klikoni butonin makro në shiritin e veglave të aksesit të shpejtë.
• Menjëherë, do të shfaqet një email i Outlook, në të cilin ka një PowerPoint prezantim që nxirret nga prezantimi burimor.

Përdorni një mjet efektiv të rimëkëmbjes

Siç e dimë të gjithë, Outlook është i pajisur me një mjet riparimi të integruar - scanpst. Megjithatë, ai thjesht mund të përballojë defekte të vogla në Outlook. Nëse ajo me të cilën përballeni është një dëm serioz, nuk do të ketë efekte. Në atë pikë, nuk keni zgjidhje tjetër veçse të ktheheni te një mjet tjetër riparimi i fuqishëm dhe i besueshëm, si p.sh DataNumen Outlook Repair. Me të, do të jeni në gjendje të shpëtoni skedarin tuaj të dëmtuar të Outlook.

Hyrje e autorit:

Shirley Zhang është një eksperte për rikuperimin e të dhënave DataNumen, Inc., e cila është lider botëror në teknologjitë e rikuperimit të të dhënave, duke përfshirë mdf i korruptuar dhe produkte softuerike të riparimit të pamjes. Për më shumë informacion vizitoni www.datanumen.com