Si të parandaloni dërgimin e emaileve në një adresë të veçantë emaili në Outlook tuaj

Shumë përdorues shpresojnë të bllokojnë dërgimin aksidental të emaileve në një adresë të caktuar emaili në Outlook. Kështu, në këtë artikull, ne do të prezantojmë një metodë për ta realizuar atë.

Outlook nuk ofron veçori të brendshme për bllokimin e dërgimit të email-eve në një adresë specifike email-i. Prandaj, nëse doni ta kuptoni, kërkohet pak skriptim. Tani, në vijim, do të ndajmë një pjesë të tillë të kodit VBA. Nëse nuk dini si ta përdorni VBA-në, mund të lexoni postimin e mëparshëm – “Si të ekzekutoni kodin VBA në Outlook tuaj".

Parandaloni dërgimin e emaileve në një adresë të veçantë emaili

1. Në fillim, hyni në redaktorin VBA të Outlook përmes "Alt + F11".
2. Më pas, vendosni kodin e mëposhtëm në projektin "ThisOutlookSession".

Private Sub Application_ItemSend(ByVal Item As Object, Cancel As Boolean)
    Dim objMail As Outlook.MailItem
    Dim objRecipients As Outlook.Recipients
    Dim ContactGroupFound As Boolean
    Dim i, n As Long
    Dim objRecipient As Outlook.Recipient
 
    If TypeOf Item Is MailItem Then
       Set objMail = Item
 
       'Expand the contact groups in Recipients
       ContactGroupFound = True
       Do While ContactGroupFound = True
          Set objRecipients = objMail.Recipients
          ContactGroupFound = False
 
          For i = objRecipients.Count To 1 Step -1
              If objRecipients(i).AddressEntry.DisplayType <> olUser Then
                 For n = 1 To objRecipients(i).AddressEntry.Members.Count
                     If objRecipients(i).AddressEntry.Members.Item(n).DisplayType = olUser Then
                        objMail.Recipients.Add (objRecipients(i).AddressEntry.Members.Item(n).Address)
                     Else
                        objMail.Recipients.Add (objRecipients(i).AddressEntry.Members.Item(n).Name)
                        ContactGroupFound = True
                     End If
                 Next
                 objRecipients(i).Delete
              End If
          Next i
          objRecipients.ResolveAll
       Loop
 
       'Remove specific email address
       For Each objRecipient In objRecipients
           If objRecipient.Address = "shelly@datanumen.com" Then
              If MsgBox("Do you want to email to " & Chr(34) & "shelly@datanumen.com" & Chr(34) & "?", vbExclamation + vbYesNo) = vbNo Then
                 objRecipient.Delete
              End If
           End If
       Next
    End If
End Sub

3. Pas kësaj, dilni nga dritarja "Microsoft Visual Basic për aplikacione".
4. Përfundimisht, provojeni me hapat e mëposhtëm.

• Për të filluar, shkruani një email dhe plotësoni marrësit.
• Më pas, klikoni në butonin "Dërgo".
• Menjëherë, makro do të punojë për të zgjeruar grupet e kontaktit në marrës nëse ka dhe do të zbulojë nëse marrësit përmbajnë adresën specifike të emailit.
• Nëse adresa gjendet, do të merrni një mesazh, siç tregohet në figurën e mëposhtme.
• Nëse zgjidhni "Jo", adresa specifike e emailit do të fshihet menjëherë.
• Pasi të dërgohet posta, mund të kontrolloni marrësit e saj, të cilët definitivisht nuk përmbajnë adresën specifike të emailit.

Riparoni skedarin tuaj të korruptuar të Outlook

A është dëmtuar ndonjëherë skedari juaj i Outlook-ut? Ky është padyshim problemi më bezdisës në Outlook. Kur i nënshtroheni këtij problemi, duhet të manipuloni... Riparimi i PST, e cila është pak me nyje. Si zakonisht, do të mendoni të përdorni Scanpst herën e parë. Por, për fat të keq, mund të dështojë në raste të tilla. Vendpushimi juaj duhet të jetë ose një mjet më me përvojë, si p.sh DataNumen Outlook Repair, ose shërbimi profesional i rikuperimit të PST.

Hyrje e autorit:

Shirley Zhang është një eksperte për rikuperimin e të dhënave DataNumen, Inc., e cila është lider botëror në teknologjitë e rikuperimit të të dhënave, duke përfshirë riparimi sql dhe produkte softuerike të riparimit të pamjes. Për më shumë informacion vizitoni www.datanumen.com