Si të tregohen moshat përkatëse të personave për të gjitha ngjarjet e ditëlindjes në pamjen e listës së kalendarit Outlook

Disa përdorues dëshirojnë të shohin gjithashtu moshën e personit përkatës kur shikojnë një ngjarje ditëlindjeje në kalendar. Prandaj, në këtë artikull, ne do të ndajmë një metodë për ta realizuar këtë ide me lehtësi.

Kur shtoni informacionin e ditëlindjes në një kontakt, Outlook do të krijojë automatikisht një ngjarje ditëlindjeje në kalendar. Në këtë rrethanë, sa herë që shihni ngjarjet e ditëlindjes në kalendar, mund të dëshironi të merrni edhe moshat përkatëse të personave. Kështu, këtu do t'ju prezantojmë një mënyrë për ta realizuar atë.

Trego moshat përkatëse të personave për të gjitha ngjarjet e ditëlindjes në pamjen e listës

1. Në fillim, hapni redaktorin VBA të Outlook.
2. Pastaj, kopjoni kodin e mëposhtëm në një modul.

Sub ShowAgesOfBirthdayEventsListView()
    Dim objStore As Outlook.Store
    Dim objOutlookFile As Outlook.Folder
    Dim objFolder As Outlook.Folder
 
    'Process All Calendar Folders in Your Outlook
    For Each objStore In Outlook.Application.Session.Stores
        Set objOutlookFile = objStore.GetRootFolder
        For Each objFolder In objOutlookFile.Folders
            If objFolder.DefaultItemType = olAppointmentItem Then
               Call ProcessFolders(objFolder)
            End If
        Next
    Next
End Sub

Sub ProcessFolders(ByVal objCalendar As Outlook.Folder)
    Dim i As Integer
    Dim objItem As Object
    Dim objBirthdayEvent As Outlook.AppointmentItem
    Dim dStart, dBirth As Date
    Dim nAge As Integer
    Dim objNewProperty As Outlook.UserProperty
    Dim objSubCalendar As Outlook.Folder

    For i = objCalendar.Items.Count To 1 Step -1
        Set objItem = objCalendar.Items.Item(i)
        'Add "Age" Property to Birthday Events
        If (objItem.MeetingStatus = olNonMeeting) And (objItem.IsRecurring = True) And (Right(objItem.Subject, 11) = "'s Birthday") Then
           Set objBirthdayEvent = objItem
           dStart = objBirthdayEvent.Start
 
           'Count Age
           dCurrentBirthday = DateSerial(Year(Now), Month(dStart), Day(dStart))
           nAge = DateDiff("yyyy", dStart, dCurrentBirthday)
 
           Set objNewProperty = objBirthdayEvent.UserProperties.Find("Age", True)
           If objNewProperty Is Nothing Then
              Set objNewProperty = objBirthdayEvent.UserProperties.Add("Age", olText, True)
           End If
 
           objNewProperty.value = nAge
           objBirthdayEvent.Save
        End If
    Next
 
    'Process All Sub-Calendar Folders Recursively
    If objCalendar.Folders.Count > 0 Then
       For Each objSubCalendar In objCalendar.Folders
           Call ProcessFolders(objSubCalendar)
       Next
    End If
End Sub

3. Pas kësaj, vendosni kursorin në nënprogramin e parë dhe shtypni "F5" për të ekzekutuar këtë makro.
4. Kur makro të përfundojë, dilni nga redaktori VBA dhe hapni një dosje kalendarike.
5. Më pas, shkoni te skeda "Shiko" dhe klikoni "Ndrysho pamjen" > "Lista".
6. Tjetra, klikoni në butonin "Shiko cilësimet".
7. Në kutinë e dialogut që shfaqet, zgjidhni "Kollonat".
8. Pastaj, në kutinë tjetër të dialogut të "Shfaq kolonat", zgjidhni "Fushat e përcaktuara nga përdoruesi në dosje" nga lista e "Zgjidhni fushat e disponueshme nga".
9. Më vonë, vendosni "Mosha" në kutinë "Kollonat e disponueshme" dhe klikoni butonin "Shto ->".
10. Përfundimisht, klikoni një seri "OK" derisa të ktheheni në listën e artikujve të kalendarit.
11. Tani, në listë, mund të shihni moshat e personave të të gjitha ngjarjeve të ditëlindjeve, siç tregohet në figurën e mëposhtme.

Rregulloni skedarin e kompromentuar të Outlook

Ju mund të keni panik kur hasni Outlook i korruptuar skedar i cili përmban shumë nga emailet dhe oraret tuaja të vlefshme. Pavarësisht se një çështje e tillë është mjaft e dëshpëruar, ju duhet të qetësoheni menjëherë dhe të merrni parasysh masa efektive. Nëse vazhdoni të shqetësoheni, situata mund të përkeqësohet dhe përkeqësohet. Në fakt, ka shumë mënyra dhe shërbime që mund të riparojnë skedarin e dëmtuar, si mjeti i riparimit të kutisë hyrëse dhe një mjet më i fuqishëm dhe me përvojë, si p.sh. DataNumen Outlook Repair.

Hyrje e autorit:

Shirley Zhang është një eksperte për rikuperimin e të dhënave DataNumen, Inc., e cila është lider botëror në teknologjitë e rikuperimit të të dhënave, duke përfshirë SQL Server fix dhe produkte softuerike të riparimit të pamjes. Për më shumë informacion vizitoni www.datanumen.com