Si të caktoni kohë të ndryshme rikujtuese të paracaktuar për lloje të ndryshme artikujsh të shënuar në Outlook-un tuaj

Si parazgjedhje, Outlook do të përdorë automatikisht kohën e paracaktuar të kujtesës së detyrave për të gjitha llojet e artikujve të shënuar. Megjithatë, nëse dëshironi të përdorni kohë të ndryshme rikujtuese për artikujt e shënuar në bazë të llojit të artikullit, mund t'i referoheni metodës së paraqitur në këtë artikull.

Outlook ju lejon të caktoni kohën e paracaktuar të kujtesës për të gjithë artikujt e shënuar, pavarësisht nga lloji i artikullit. Mund të shkoni te menyja "File" dhe të klikoni "Opsionet". Më pas, në dritaren "Opsionet e Outlook", mund të shihni opsionin "Koha e parazgjedhur e kujtesës" në skedën "Detyrat", siç tregohet në pamjen e mëposhtme të ekranit.

Megjithatë, shumica e përdoruesve shpresojnë të përdorin kohë të ndryshme përkujtese për lloje të ndryshme të artikujve të shënuar, siç është "9:00" për emailet e shënuara dhe "17:30" për kontaktet e shënuara. Tani, në vijim, do të përqendrohemi në këtë shembull për të prezantuar një metodë.

Cakto kohë të ndryshme rikujtuese të paracaktuar për lloje të ndryshme artikujsh të shënuar

1. Për të filluar, hapni aplikacionin Outlook.
2. Pastaj, hyni në redaktorin VBA të Outlook duke iu referuar "Si të ekzekutoni kodin VBA në Outlook tuaj".
3. Në dritaren pasuese "Microsoft Visual Basic për Aplikacione", kopjoni kodin e mëposhtëm në projektin "ThisOutlookSession".

Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objMail As Outlook.MailItem
Public WithEvents objContact As Outlook.ContactItem

Private Sub Application_Startup()
    Set objExplorer = Outlook.Application.ActiveExplorer
    Set objInspectors = Outlook.Application.Inspectors
End Sub

Private Sub objExplorer_SelectionChange()
    On Error Resume Next
    If objExplorer.Selection.Item(1).Class = olMail Then
       Set objMail = objExplorer.Selection.Item(1)
    ElseIf TypeOf objExplorer.Selection.Item(1) Is ContactItem Then
       Set objContact = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If Inspector.CurrentItem.Class = olMail Then
       Set objMail = Inspector.CurrentItem
    ElseIf Inspector.CurrentItem.Class = olContact Then
       Set objContact = Inspector.CurrentItem
    End If
End Sub

Private Sub objMail_PropertyChange(ByVal Name As String)
    If Name = "ToDoTaskOrdinal" Then
       If objMail.IsMarkedAsTask = True Then
          If objMail.TaskDueDate <> "1/1/4501" Then
             With objMail
                  .ReminderSet = True
                  'Change the reminder time for flagged emails
                  .ReminderTime = objMail.TaskDueDate & " 10:00"
                  .Save
             End With
          End If
       End If
    End If
End Sub

Private Sub objContact_PropertyChange(ByVal Name As String)
    If Name = "ToDoTaskOrdinal" Then
       If objContact.IsMarkedAsTask = True Then
          If objContact.TaskDueDate <> "1/1/4501" Then
             With objContact
                  .ReminderSet = True
                  'Change the reminder time for flagged contacts
                  .ReminderTime = objContact.TaskDueDate & " 17:30"
                  .Save
             End With
          End If
       End If
    End If
End Sub

4. Pas kësaj, rinisni Outlook-un për të aktivizuar këtë makro.
5. Që tani e tutje, çdo herë kur shënoni një email, ora rikujtuese do të caktohet në "10:00" në datën e caktuar të flamurit.
6. Dhe kur shënoni një kontakt, ora rikujtuese do të caktohet në "17:30" në datën e caktuar të flamurit.

Trajtoni problemet e Outlook në mënyrë fleksibël

Mund të hasni të gjitha llojet e problemeve në Outlook-un tuaj. Pra, duhet të mësoni disa masa për t'i trajtuar ato paraprakisht. Për shembull, nëse Outlook-u juaj riniset shpesh, duhet të riparoni Office-in ose të çaktivizoni shtesat e palëve të treta, etj. Ose nëse PST-ja juaj e Outlook-ut kompromentohet, së pari mund të provoni mjet për riparimin e kutisë hyrëse. Kur dështon, mund të vazhdoni të përdorni një mjet të jashtëm të fuqishëm, si p.sh DataNumen Outlook Repair.

Hyrje e autorit:

Shirley Zhang është një eksperte për rikuperimin e të dhënave DataNumen, Inc., e cila është lider botëror në teknologjitë e rikuperimit të të dhënave, duke përfshirë rikuperimi mdf dhe produkte softuerike të riparimit të pamjes. Për më shumë informacion vizitoni www.datanumen.com