Si të krijoni shpejt një grup kontakti nga të gjitha kontaktet e Outlook me një titull specifik pune

Për të komunikuar më lehtë me kontaktet me një titull specifik pune, mund të dëshironi të krijoni shpejt një grup kontakti nga këto kontakte. Tani, në këtë artikull, ne do të ndajmë me ju një metodë të shpejtë.

Nëse dërgoni shpesh emaile, detyra ose ftesa takimesh në grup tek kontaktet që kanë një titull specifik pune, do të jetë shumë më e përshtatshme nëse krijoni një grup kontakti prej tyre. Në përgjithësi, në mënyrën standarde, së pari duhet të krijoni një grup të ri kontakti dhe më pas t'i shtoni kontaktet grupit si anëtarë një nga një. Është pak e mundimshme. Prandaj, në vijim do t'ju mësojmë një mënyrë shumë më të shpejtë për ta marrë atë.

Krijoni një grup kontakti nga të gjitha kontaktet me një titull specifik pune

1. Në fillim, në një dosje Kontaktet, zgjidhni një kontakt që ka titullin specifik të punës.
2. Më pas, shtypni "Alt + F11" për të hyrë në redaktuesin VBA të Outlook.
3. Më pas, kopjoni kodin e mëposhtëm VBA në një modul ose projekt bosh.

Dim objContact As Outlook.ContactItem
Dim strJobTitle As String
Dim objNewGroup As Outlook.DistListItem
Dim objTempMail As Outlook.MailItem

Sub CreateContactGroupfromContactsSameJobTitle()
    Dim objStore As Outlook.Store
    Dim objOutlookFile As Outlook.Folder
    Dim objFolder As Outlook.Folder
 
    Set objContact = Outlook.Application.ActiveExplorer.Selection(1)
    strJobTitle = objContact.JobTitle
 
    Set objNewGroup = Outlook.Application.CreateItem(olDistributionListItem)
    Set objTempMail = Outlook.Application.CreateItem(olMailItem)
 
    'Process all Contacts folders
    For Each objStore In Outlook.Application.Session.Stores
        Set objOutlookFile = objStore.GetRootFolder
        For Each objFolder In objOutlookFile.Folders
            If objFolder.DefaultItemType = olContactItem Then
               Call ProcessContactsFolders(objFolder)
            End If
        Next
    Next
 
    objNewGroup.AddMembers objTempMail.Recipients
    objNewGroup.Display
End Sub

Sub ProcessContactsFolders(ByVal objCurFolder As Outlook.Folder)
    Dim objItem As Object
    Dim objSubfolder As Outlook.Folder
 
    For Each objItem In objCurFolder.Items
        If objItem.Class = olContact Then
           If objItem.JobTitle = strJobTitle Then
              'Add the contact having the specific job title to the new group
              objTempMail.Recipients.Add (objItem.Email1Address)
              objTempMail.Recipients.ResolveAll
           End If
        End If
    Next
 
    'Process all subfolders recursively
    If objCurFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurFolder.Folders
           Call ProcessContactsFolders(objSubfolder)
       Next
    End If
End Sub

4. Pas kësaj, zhvendoseni kursorin në nënprogramin e parë.
5. Më në fund, trokitni lehtë mbi butonin "F5" për të ekzekutuar këtë makro.
6. Kur makro të përfundojë, do të shfaqet një grup i ri kontakti. Ai përmban të gjitha kontaktet me të njëjtin titull pune të kontaktit të zgjedhur në Hapin 1.

Mbroni në mënyrë efektive të dhënat e Outlook

Megjithëse Outlook është i pasur me veçori, ai nuk mund të heqë qafe faktin se është i prekshëm. Pra, nëse nuk doni të humbni të dhënat tuaja të çmuara të Outlook, duhet të bëni përpjekje për t'i mbrojtur ato. Për shembull, ju duhet të bëni kopje rezervë për të dhënat e Outlook në intervale të rregullta. Gjithashtu, nëse është e përballueshme, rekomandohet të keni një mjet riparues të fundit të PST, si p.sh DataNumen Outlook Repair, të cilat munden riparim PST të dhëna në një farë mase.

Hyrje e autorit:

Shirley Zhang është një eksperte për rikuperimin e të dhënave DataNumen, Inc., e cila është lider botëror në teknologjitë e rikuperimit të të dhënave, duke përfshirë sql i korruptuar dhe produkte softuerike të riparimit të pamjes. Për më shumë informacion vizitoni www.datanumen.com