Si të konvertoni në grup dhe të bashkëngjitni dokumente të shumëfishta Word si PDF Skedarët në një email të Outlook

Është e lehtë të bashkëngjitni një dokument Word si një PDF skedar në një email të Outlook. Megjithatë, nëse dëshironi të bashkëngjitni dokumente të shumta Word si PDF skedarë në një email, mund ta lexoni këtë artikull. Këtu do t'ju tregojmë një metodë për ta marrë atë në grup.

Për të bashkangjitur një dokument Word si PDF Për të transferuar skedarin në një email nga Outlook, së pari mund të hapni dokumentin Word dhe të shkoni te menyja "Skedari". Pastaj, mund të kaloni te skeda "Ruaj dhe dërgo", në të cilën ndodhet butoni "Dërgo si PDF", si në pamjen e mëposhtme të ekranit.

Kështu, është mjaft e thjeshtë të bashkëngjitni një dokument Word si PDF në një email. Por, nëse dëshironi të konvertoni dhe bashkëngjitni dokumente të shumta Word si PDF skedarë në një postë, është më mirë të përdorni mënyrën e mëposhtme. Mund t'ju lejojë ta përmbushni atë në masë.

Konvertimi i grupit dhe bashkëngjitni dokumente të shumëfishta Word si PDF Skedarët në një email

1. Për të filluar, mblidhni dokumentet e Word-it që dëshironi në të njëjtën dosje të Windows-it.
2. Pastaj nisni programin Outlook.
3. Më pas, kopjoni kodin e mëposhtëm në një projekt ose modul të papërdorur.

Dim objMail As Outlook.MailItem

Sub BatchAttachMultipleWordDocumentsAsPDFToEmail()
    Dim objShell As Object
    Dim objWindowsFolder As Object
    Dim strWindowsFolder As String

    Set objMail = Outlook.Application.CreateItem(olMailItem)

    'Select the specific Windows folder
    Set objShell = CreateObject("Shell.Application")
    Set objWindowsFolder = objShell.BrowseForFolder(0, "Select a Windows folder:", 0, "")

    If Not objWindowsFolder Is Nothing Then
       strWindowsFolder = objWindowsFolder.self.Path & "\"

       Call ProcessFolders(strWindowsFolder)

       objMail.Display
    End If
End Sub

Sub ProcessFolders(strPath As String)
    Dim objFileSystem As Object
    Dim objFolder As Object
    Dim objFile As Object
    Dim objWordApp As Word.Application
    Dim objWordDocument As Word.Document
    Dim strDocumentName As String
    Dim strPDF As String

    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    Set objFolder = objFileSystem.GetFolder(strPath)

    For Each objFile In objFolder.Files
        strFileExtension = objFileSystem.GetExtensionName(objFile)
        If LCase(strFileExtension) = "doc" Or LCase(strFileExtension) = "docx" Then
           Set objWordApp = CreateObject("Word.Application")
           Set objWordDocument = objWordApp.Documents.Open(objFile.Path)

           'Convert document to pdf
           strDocumentName = Left(objWordDocument.Name, (Len(objWordDocument.Name) - Len(strFileExtension)) - 1)
           strPDF = strPath & strDocumentName & ".pdf"
           objWordDocument.ExportAsFixedFormat strPDF, wdExportFormatPDF

           objWordDocument.Close False

           'Attach the pdf to email
           objMail.Attachments.Add strPDF

           Kill strPDF
        End If
    Next

    'Process all folders and subfolders
    If objFolder.SubFolders.Count > 0 Then
       For Each objSubfolder In objFolder.SubFolders
           If ((objSubfolder.Attributes And 2) = 0) And ((objSubfolder.Attributes And 4) = 0) Then
              ProcessFolders (objSubfolder.Path)
           End If
       Next
    End If
End Sub

4. Pas kësaj, zhvendoseni kursorin në nënprogramin e parë.
5. Më pas, shtypni "F5" për të ekzekutuar këtë makro menjëherë.
6. Në kutinë e dialogut të vogël që shfaqet, zgjidhni dosjen Windows ku ruhen dokumentet burimore Word.
7. Menjëherë, do të krijohet një email i ri, në të cilin mund të shihni të bashkangjitur PDF skedarë, si screenshost-i i mëposhtëm.

I rrënuar nga problemet e Outlook

Jeni të shqetësuar nga probleme të ndryshme të Outlook? Për shembull, Outlook shpesh ngec në gjendjen "nuk përgjigjet" ose skedari PST i Outlook bëhet i paarritshëm, etj. Në përgjithësi, fillimisht mund të provoni mjetin e riparimit të kutisë hyrëse, scanpst, për të rregulluar problemet e PST. Megjithatë, ndonjëherë, problemet mund të jenë përtej asaj që mund të bëjë mjeti i integruar. Prandaj, është më mirë të mbani një mjet të jashtëm më të fuqishëm në afërsi, si p.sh DataNumen Outlook Repair.

Hyrje e autorit:

Shirley Zhang është një eksperte për rikuperimin e të dhënave DataNumen, Inc., e cila është lider botëror në teknologjitë e rikuperimit të të dhënave, duke përfshirë riparimi sql dhe produkte softuerike të riparimit të pamjes. Për më shumë informacion vizitoni www.datanumen.com