Si të merrni automatikisht rreshtin e parë të trupit si subjekt përpara se të dërgoni një email të Outlook pa subjekt

Disa përdorues dëshirojnë që Outlook të marrë automatikisht rreshtin e parë të trupit të postës elektronike si temë kur dërgojnë një email pa subjekt. Tani, në këtë artikull, ne do të prezantojmë një metodë për ta realizuar atë përmes kodit VBA.

Përdorues të shumtë shpesh harrojnë të fusin subjektin kur hartojnë dhe dërgojnë një email. Kështu, zakonisht, ata shpresojnë që Outlook mund të plotësojë automatikisht temën nga rreshti i parë i trupit të postës elektronike nëse emaili në dalje nuk ka subjekt. Më pas, ne do të ndajmë me ju një metodë të lehtë dhe të dobishme.

Merrni automatikisht rreshtin e parë të trupit si subjekt përpara se të dërgoni një email pa subjekt

1. Që në fillim, hapni aplikacionin Outlook.
2. Më pas, duke ndjekur hapat në "Si të ekzekutoni kodin VBA në Outlook tuaj“, mund të futeni në redaktorin VBA.
3. Më pas, në redaktorin VBA, shtoni referencën te "MS Word Object Library” në përputhje me “Si të shtoni një Object Library Referenca në VBA".
4. Më vonë, kopjoni kodin më poshtë në projektin "ThisOutlookSession".

Private WithEvents objInspectors As Outlook.Inspectors

Private Sub Application_Startup()
    Set objInspectors = Outlook.Application.Inspectors
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If Inspector.CurrentItem.Class = olMail And Inspector.CurrentItem.Subject = "" Then
       Inspector.CurrentItem.Subject = " "
    End If
End Sub

Private Sub Application_ItemSend(ByVal Item As Object, Cancel As Boolean)
    Dim objMail As Outlook.MailItem
    Dim objMailDocument As Word.Document
    Dim objMailSelection As Word.Selection
 
    If TypeOf Item Is MailItem Then
       Set objMail = Item
 
       If Len(Trim(objMail.Subject)) = 0 Then
          If MsgBox("No subject! Whether to take first line as subject?", vbQuestion + vbYesNo) = vbYes Then
             Set objMailDocument = objMail.GetInspector.WordEditor
             Set objMailSelection = objMailDocument.Application.Selection
 
             objMailDocument.Range(0, 0).Select
             objMailSelection.MoveEnd wdLine
 
             'Take first line of body as subject
             objMail.Subject = objMailSelection.Text
          End If
       End If
     End If
End Sub

5. Pas kësaj, vendosni kursorin në "Application_Startup” dhe shtypni “F5”.
6. Më në fund, mund të provoni.

• Në fillim, krijoni dhe krijoni një email me vetëm temën bosh.
• Më pas, klikoni në butonin "Dërgo".
• Më vonë, do të merrni një mesazh që ju pyet nëse duhet të merrni si subjekt linjën e parë të trupit.
• Për sa kohë që zgjidhni butonin "Po", rreshti i parë i trupit të emailit do të nxirret dhe përdoret si subjekt dhe emaili do të dërgohet.

Mbani të sigurta të dhënat tuaja të Outlook

Absolutisht, ka shumë emaile të rëndësishme dhe artikuj të tjerë në Outlook-un tuaj. Kështu, nuk duhet të jeni të gatshëm të hasni humbje të të dhënave të Outlook. Më pas, duhet të ndërmerrni disa veprime, si p.sh. të bëni kopje rezervë të rregullt të të dhënave të Outlook-it tuaj, të mësoni të përdorni mjetin e integruar të riparimit për të rregulloni Outlook gabimet dhe përgatitja e një mjeti të fuqishëm të rikuperimit të jashtëm. DataNumen Outlook Repair është një zgjedhje e mirë për shkak të shkallës së lartë të rikuperimit të PST.

Hyrje e autorit:

Shirley Zhang është një eksperte për rikuperimin e të dhënave DataNumen, Inc., e cila është lider botëror në teknologjitë e rikuperimit të të dhënave, duke përfshirë shërim sql dhe produkte softuerike të riparimit të pamjes. Për më shumë informacion vizitoni www.datanumen.com