Si të shënoni automatikisht takimet e fundjavës si private në Outlook

Për most përdoruesve, takimet e planifikuara në fundjavë janë zakonisht private. Prandaj, ata duan që Outlook të shënojë dhe t'i shfaqë takime të tilla si private. Në këtë artikull, ne do ta bëjmë këtë realitet me pak skriptim.

Për të dalluar më lehtë ndërmjet takimeve të biznesit dhe atyre private, Outlook u lejon përdoruesve të shënojnë takimet si private. Në këtë mënyrë, do ta gjeni mjaft të përshtatshëm dhe të lehtë për të printuar kalendarin pa takime private. Në këtë situatë, mund të dëshironi që Outlook juaj të njohë automatikisht dhe të shënojë takime specifike si private. Për shembull, në përgjithësi, takimet në fundjavë janë private, kështu që ju dëshironi të lejoni që Outlook t'i shënojë automatikisht si private. Pas kësaj, ne do t'ju udhëzojmë për ta arritur atë.

Shënoni automatikisht takimet e fundjavës si private

1. Fillimisht, hapni redaktorin VBA të Outlook sipas "Si të ekzekutoni kodin VBA në Outlook tuaj".
2. Më pas, në dritaren "Microsoft Visual Basic për Aplikacione", vendosni kodin e mëposhtëm në projektin "ThisOutlookSession".

Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objAppointment As Outlook.AppointmentItem

Private Sub Application_Startup()
    Set objInspectors = Outlook.Application.Inspectors
    Set objExplorer = Outlook.Application.ActiveExplorer
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If Inspector.CurrentItem.Class = olAppointment Then
       Set objAppointment = Inspector.CurrentItem
    End If
End Sub

Private Sub objExplorer_Activate()
    On Error Resume Next
    If objExplorer.Selection.Item(1).Class = olAppointment Then
       Set objAppointment = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objAppointment_Open(Cancel As Boolean)
    Call MarkWeedendAppointmentPrivate(objAppointment)
End Sub

Private Sub objAppointment_PropertyChange(ByVal Name As String)
    If Name = "Start" Or Name = "End" Then
       Call MarkWeedendAppointmentPrivate(objAppointment)
    End If
End Sub

Private Sub MarkWeedendAppointmentPrivate(ByVal objAppointment As Outlook.AppointmentItem)
    Dim dStartDate As Date
 
    dStartDate = Format(objAppointment.Start, "Short Date")
 
    'If the appointment start falls on weekend
    Select Case Weekday(dStartDate)
           Case 7, 1
                'Mark it private
                objAppointment.Sensitivity = olPrivate
    End Select
End Sub

3. Pas kësaj, restart Outlook për të aktivizuar makro.
4. Që tani e tutje, sa herë që krijoni një takim të ri ose ndryshoni një takim ekzistues në fundjavë, Outlook do ta shënojë automatikisht atë si privat.

Zgjidh problemet e bezdisshme të Outlook

Është e mundur që të keni hasur disa probleme kur keni të bëni me Outlook, të tilla si ngrirja e papritur e aplikacionit, mesazhet e gabimit në dritare etj. Kur i vuan, do të shqetësoheshe. Te lutem qetesohu! Paniku nuk do të ndihmojë asgjë, por do ta përkeqësojë rastin. Në radhë të parë, mund të kontrolloni nëse mund të përdorni skedarin PST si zakonisht. Nëse po, ju duhet të riparoni skedarin PST, i cili mund të realizohet nëpërmjet mjet për riparimin e kutisë hyrëse ose një mjet i jashtëm më i fuqishëm, si p.sh DataNumen Outlook Repair.

Hyrje e autorit:

Shirley Zhang është një eksperte për rikuperimin e të dhënave DataNumen, Inc., e cila është lider botëror në teknologjitë e rikuperimit të të dhënave, duke përfshirë riparim mdf dhe produkte softuerike të riparimit të pamjes. Për më shumë informacion vizitoni www.datanumen.com