Si të eksportoni në grup fotot dhe informacionet e kontakteve të shumëfishta me Outlook VBA

Nëse dëshironi të nxirrni fotot e kontakteve dhe informacionin e tyre parësor në një dosje në diskun tuaj lokal në grupe, duhet të përdorni Outlook VBA. Ky artikull do t'ju mësojë se si ta arrini atë në detaje.

Outlook ju lejon të eksportoni informacionin e kontaktit përmes veçorisë "Import dhe eksport". Mund të shkoni te "File" > "Print" > "Import" > "Eksport në një skedar".

Megjithatë, kjo veçori nuk ju lejon të eksportoni fotot e kontaktit. Kështu, nëse dëshironi të nxirrni informacionin e kontaktit dhe fotot, duhet të ktheheni te Outlook VBA. Më poshtë janë kodet dhe hapat VBA që mund të ruajnë fotot e kontaktit në një dosje të caktuar lokale dhe të nxjerrin informacionin e kontaktit në një skedar teksti.

Eksportoni në grup Fotot dhe Informacionin e Kontakteve të Shumëfishta

1. Në radhë të parë, hapni Outlook dhe shtypni butonat "Alt + F11".
2. Pastaj do të keni akses në redaktuesin VBA. Tani duhet të hapni një modul që nuk është në përdorim ose të krijoni një modul të ri duke “Insert” > “Module”.
3. Më pas, kopjoni dhe ngjisni kodet e mëposhtme VBA në modulin e ri.

Sub BatchExportContactPhotosandInformation()
    Dim objContacts As Outlook.Items
    Dim objContact As ContactItem
    Dim strContactInfo As String
    Dim objFileSystem As Object
    Dim objTextfile As Object
    Dim objAttachments As Attachments
    Dim objAttachment As Attachment
    Dim strName As String
 
    'Specify the contacts in the default contact folder
    Set objContacts = Outlook.Application.Session.GetDefaultFolder(olFolderContacts).Items
 
    For Each objContact In objContacts
        If TypeOf objContact Is ContactItem Then
           'Get the contact's primary informtaion
           strContactInfo = "Name: " & objContact.FullName & vbCrLf & "Email: " & objContact.Email1Address & vbCrLf & "Company: " & objContact.Companies & vbCrLf & "Job Title: " & objContact.JobTitle & vbCrLf & "Business Address: " & objContact.BusinessAddress & vbCrLf & "Business Phone: " & objContact.BusinessTelephoneNumber
           'Create a Text file
           Set objFileSystem = CreateObject("Scripting.FileSystemObject")
           'You can change the folder path as per your needs
           Set objTextfile = objFileSystem.CreateTextFile("C:\Outlook Contacts\" & objContact.FullName & ".txt", True)
           objTextfile.WriteLine (strContactInfo)
 
           'Save the contact photos
           If objContact.Attachments.Count > 0 Then
              Set objAttachments = objContact.Attachments
              For Each objAttachment In objAttachments
                  If InStr(LCase(objAttachment.filename), "contactpicture.jpg") > 0 Then
                     strName = objContact.FullName & ".jpg"
                     objAttachment.SaveAsFile ("C:\Outlook Contacts\" & strName)
                  End If
              Next
           End If
       End If
    Next
End Sub

Shënim: Kodet e mësipërme do të eksportojnë fotot dhe informacionin e kontakteve në dosjen tuaj të parazgjedhur të kontakteve. Mund të ndryshoni kontaktet e specifikuara.

• Nëse dëshironi të eksportoni fotot dhe informacionin e kontakteve në dosjen e hapur aktualisht, atëherë duhet të zëvendësoni "Set objContacts = ...." me:

Set objContacts = Outlook.Application.ActiveExplorer.CurrentFolder.Items

• Nëse shpresoni vetëm të eksportoni fotot dhe informacionin e kontakteve të zgjedhura, atëherë mund të përdorni linjat e mëposhtme:

Dim objSelection as Selection
Set objSelection = Outlook.Application.ActiveExplorer.Selection
For each objContact in objSelection

4. Pas kësaj, mund të mbyllni redaktorin VBA dhe të vazhdoni të shtoni projektin e ri në Shiritin e Veglave të Qasjes së Shpejtë si zakonisht.
5. Më në fund mund të klikoni butonin makro në shiritin e veglave të aksesit të shpejtë. Menjëherë, fotot dhe informacionet e kontaktit do të eksportohen në dosjen e specifikuar në diskun lokal.

Mund të hapni një skedar teksti, në të cilin do të renditen informacionet kryesore, si pamja e mëposhtme e ekranit:

Trajtoni korrupsionin e papritur të opinionit

Është një fakt i padiskutueshëm që Outlook është i prekshëm. Prandaj, nëse vuani nga korrupsioni i Outlook, ajo që duhet të bëni së pari është të qetësoheni. Pastaj mund të vazhdoni të riparoni Email i korruptuar i Outlook PST. Ju mund të përdorni mjetin e riparimit të kutisë hyrëse për të provuar. Nëse dështon, atëherë nuk keni zgjidhje tjetër veçse të përdorni një mjet shumë më të fuqishëm, si p.sh DataNumen Outlook Repair.

Hyrje e autorit:

Shirley Zhang është një eksperte për rikuperimin e të dhënave DataNumen, Inc., e cila është lider botëror në teknologjitë e rikuperimit të të dhënave, duke përfshirë riparimi i bazës së të dhënave SQL mdf të dëmtuar dhe produkte softuerike të riparimit të pamjes. Për më shumë informacion vizitoni www.datanumen.com