Si të eksportoni grupe të gjitha emailet në një bisedë si skedarë teksti përmes Outlook VBA

Ndonjëherë, ju mund të dëshironi të kapni të gjitha emailet në një bashkëbisedim specifik dhe më pas t'i eksportoni ato në dosjen lokale si skedarë teksti. Ky artikull do t'ju mësojë se si ta merrni atë në kohë të shpejtë.

Për disa arsye, mund t'ju duhet të eksportoni të gjitha emailet në një bisedë të caktuar në diskun tuaj lokal. Nëse e bëni këtë me dorë, domethënë të gjeni dhe kurseni një nga një, do të jetë një detyrë e lodhshme dhe e mundimshme. Prandaj, është më mirë të kërkoni një metodë tjetër më të shpejtë, siç është ajo e mëposhtme. Ai do të përdorë një pjesë të kodit VBA për ta marrë atë pa u lodhur.

Eksportoni në grup të gjitha postat në një bisedë si skedarë teksti

1. Që në fillim, hapni aplikacionin tuaj Outlook.
2. Më pas shtypni butonat "Alt + F11" për të hyrë në redaktuesin VBA të Outlook.
3. Më pas, në dritaren e re, duhet të hapni një modul që nuk është në përdorim ose të futni drejtpërdrejt një modul të ri.
4. Më pas duhet të kopjoni dhe ngjisni kodet e mëposhtme VBA në këtë modul.

Public strFilePath, strFileName As String

Sub ExportMailsInConversationAsTXT()
    Dim objSelectedMail As Outlook.MailItem
    Dim objConversation As Outlook.Conversation
    Dim objMail As Outlook.MailItem

    Set objSelectedMail = ActiveExplorer.Selection.Item(1)
    Set objConversation = objSelectedMail.GetConversation
 
    If Not (objConversation Is Nothing) Then
       'Get all root items in this conversation
       For Each objMail In objConversation.GetRootItems
 
          strFileName = objMail.Subject
 
          'Remove the unsupported characters in email subject
          strFileName = Replace(strFileName, "/", " ")
          strFileName = Replace(strFileName, "\", " ")
          strFileName = Replace(strFileName, ":", "")
          strFileName = Replace(strFileName, "?", " ")
          strFileName = Replace(strFileName, Chr(34), " ")

          strFileName = Format(objMail.ReceivedTime, "YYYY-MM-DD") & "_" & strFileName & ".txt"
 
         'Export as Text files
         'Change "E:\" to other local folder path as per your needs
         strFilePath = "E:\" & strFileName
         objMail.SaveAs strFilePath, OLTXT

         'Process all children as well
         Call ProcessChildren(objMail, objConversation)
      Next
   End If

   MsgBox "Complete!", vbExclamation
End Sub

Sub ProcessChildren(objCurMail As Outlook.MailItem, objCurConversation As Outlook.Conversation)
    Dim objItems As Outlook.SimpleItems
    Dim objItem As Outlook.MailItem
 
    Set objItems = objCurConversation.GetChildren(objCurMail)

    If objItems.Count > 0 Then
       For Each objItem In objItems
 
           strFileName = objItem.Subject
 
           strFileName = Replace(strFileName, "/", " ")
           strFileName = Replace(strFileName, "\", " ")
           strFileName = Replace(strFileName, ":", "")
           strFileName = Replace(strFileName, "?", " ")
           strFileName = Replace(strFileName, Chr(34), " ")
 
           strFileName = Format(objItem.ReceivedTime, "yyyy-mm-dd") & "_" & strFileName & ".txt"
 
           strFilePath = "E:\" & strFileName
           objItem.SaveAs strFilePath, OLTXT
 
           'Process all children recursively
           Call ProcessChildren(objItem, objCurConversation)
       Next
    End If
End Sub

5. Pas kësaj, ju mund të shtoni projektin e ri VBA në shiritin e veglave të aksesit të shpejtë si zakonisht.
6. Më vonë sigurohu që niveli i sigurisë makro Outlook të jetë i ulët.
7. Së fundi, mund të provoni.

• Së pari, zgjidhni një email.
• Pastaj klikoni butonin e ri makro në shiritin e veglave të aksesit të shpejtë.
• Kur të merrni mesazhin "Përfunduar", mund të hapni dosjen e paracaktuar lokale, në të cilën do të shihni emailet në formatin "TXT".

Këshilla për rivendosjen e të dhënave PST pas korrupsionit

Shpesh, në Outlook, mund të hasni gabime të ndryshme të Outlook, disa prej të cilave mund të jenë jashtëzakonisht serioze, në mënyrë që të çojnë drejtpërdrejt në korrupsionin e PST. Në atë kohë, duhet të ndërmerrni veprime për të riparim PST skedar për të gjetur të dhënat tuaja të vlefshme. Në këtë rast, thjesht mund të ktheheni te një mjet me reputacion dhe i provuar mirë, si p.sh DataNumen Outlook Repair.

Hyrje e autorit:

Shirley Zhang është një eksperte për rikuperimin e të dhënave DataNumen, Inc., e cila është lider botëror në teknologjitë e rikuperimit të të dhënave, duke përfshirë shërohem sql server dhe produkte softuerike të riparimit të pamjes. Për më shumë informacion vizitoni www.datanumen.com