Si të fshini në grup të gjitha faturat e leximit në Outlook tuaj

Për të konfirmuar që marrësit e kanë lexuar emailin tuaj, mund të kërkoni faturën e leximit kur shkruani emailin. Në këtë situatë, kutia juaj postare mund të jetë e mbushur me fatura të tilla leximi. Tani, kjo post do t'ju mësojë se si t'i fshini ato përgjithmonë.

Pas leximit të artikullit "Si të fshini në grup të gjitha faturat e dorëzimit në Outlook tuaj“, ju mund të mendoni për mënyrën e fshirjes në masë të të gjitha faturave të leximit. Në fakt, ndryshimi i dukshëm midis dy llojeve të faturave është subjekti i tyre. Fatura e dorëzimit përmban "Dorëzuar" në temë, por fatura e leximit përmban "Lexo". Prandaj, mund të përdorni të njëjtën mënyrë për të fshirë në grup të gjitha faturat e leximit. Në vijim do t'ju mësojmë hapat konkretë në detaje.

Fshij në grup të gjitha faturat e leximit

1. Në fillim, start Outlook-in tuaj.
2. Pastaj, shkoni te redaktori VBA i Outlook përmes "Alt + F11" sipas "Si të ekzekutoni kodin VBA në Outlook tuaj".
3. Më pas, në dritaren e re, hapni një modul bosh dhe vendosni kodin e mëposhtëm në të.

Dim objOutlookFile As Outlook.Folder

Sub BatchDeleteAllReadReceipts()
    Dim objStore As Outlook.Store
    Dim objFolder As Outlook.Folder
    Dim lTotalCount As Long
 
    lTotalCount = 0
   'Process all Outlook files
    For Each objStore In Outlook.Application.Session.Stores
        Set objOutlookFile = objStore.GetRootFolder
        For Each objFolder In objOutlookFile.Folders
            If objFolder.DefaultItemType = olMailItem Then
               Call ProcessFolders(objFolder, lTotalCount)
            End If
        Next
    Next
 
    'Prompt you of the results
    MsgBox lTotalCount & " read receipts are deleted!", vbInformation + vbOKOnly
End Sub

Sub ProcessFolders(ByVal objCurrentFolder As Outlook.Folder, lCount As Long)
    Dim i As Long
    Dim objDeliveryReceipt As Outlook.ReportItem
    Dim objSubfolder As Outlook.Folder
    Dim objDeletedItems As Outlook.Items
    Dim objItem As Object
 
    For i = objCurrentFolder.Items.Count To 1 Step -1
        'Find read receipts
        If (TypeOf objCurrentFolder.Items(i) Is ReportItem) And (Left(objCurrentFolder.Items(i).Subject, 5) = "Read:") Then
           Set objDeliveryReceipt = objCurrentFolder.Items.Item(i)
           objDeliveryReceipt.Delete
 
           lCount = lCount + 1
 
           'Permanently delete them
           Set objDeletedItems = objOutlookFile.Folders("Deleted Items").Items
           For Each objItem In objDeletedItems
               If (TypeOf objItem Is ReportItem) And (Left(objItem.Subject, 5) = "Read:") Then
                  objItem.Delete
               End If
           Next
         End If
    Next
 
    'Loop subfolders recursively
    If objCurrentFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.Folders
           Call ProcessFolders(objSubfolder, lCount)
       Next
    End If
End Sub

4. Pas kësaj, klikoni në nënprogramin e parë.
5. Në fund, shtypni butonin "F5".
6. Menjëherë, makro do të funksionojë për të fshirë të gjitha faturat e leximit nga Outlook juaj.
7. Kur të përfundojë, do të merrni një kërkesë për rezultatin, si pamja e ekranit më poshtë.
8. Aktualisht, ju mund të kontrolloni dosjet tuaja të postës. Të gjitha faturat e leximit janë zhdukur.

Mbroni të dhënat e Outlook

Megjithëse skedari Outlook është pa dyshim i ndjeshëm ndaj korrupsionit, ne mund të ndërmarrim veprime për ta mbrojtur atë. Për shembull, ne duhet ta mbajmë skedarin Outlook në madhësi të vogël, ta mbrojmë atë nga faktorët keqdashës dhe ta kopjojmë rregullisht. E fundit, por jo më pak e rëndësishme, është më mirë të përgatisni një mjet të jashtëm të fuqishëm riparimi PST, si p.sh DataNumen Outlook Repair. Do të ketë ndikim të madh në riparim Outlook i korruptuar fotografi.

Hyrje e autorit:

Shirley Zhang është një eksperte për rikuperimin e të dhënave DataNumen, Inc., e cila është lider botëror në teknologjitë e rikuperimit të të dhënave, duke përfshirë riparimi sql dhe produkte softuerike të riparimit të pamjes. Për më shumë informacion vizitoni www.datanumen.com