Si të anuloni grupe të gjitha takimet e Outlook të planifikuara në një interval të caktuar datash

Nëse dëshironi të anuloni të gjitha takimet e planifikuara në një interval të caktuar datash në Outlook tuaj, mund të përdorni mjetet e paraqitura në këtë artikull. Mund t'ju shpëtojë nga kërkimi dhe anulimi manual i takimeve të tilla.

Nëse, për disa arsye, nuk mund të organizoni ose të merrni pjesë në takimet që do të mbahen në një interval të caktuar datash në të ardhmen, mund të dëshironi të anuloni të gjitha takimet e tilla. Në përgjithësi, së pari duhet t'i zbuloni dhe më pas t'i anuloni ato një nga një. Do të jetë mjaft e mundimshme. Prandaj, në vijim do t'ju ndajmë një mënyrë tjetër, e cila është shumë më e përshtatshme.

Anuloni në grup të gjitha takimet e planifikuara në një interval të caktuar datash

1. Në fillim, nisni programin tuaj Outlook.
2. Pastaj, në Outlook, duhet të shtypni butonat "Alt + F11".
3. Më pas, do të futeni në dritaren "Microsoft Visual Basic për Aplikime".
4. Në këtë dritare, duhet të hapni një modul të papërdorur ose thjesht të futni një të ri.
5. Më pas, mund të kopjoni kodin e mëposhtëm VBA në këtë modul.

Sub BatchCancelAllMeetingsInSpecificDateRange()
    Dim dStartDate As Date
    Dim dEndDate As Date
    Dim objCalendarFolder As Outlook.folder
    Dim objItems As Outlook.Items
    Dim objItemsInDateRange As Outlook.Items
    Dim objAppointment As Outlook.AppointmentItem
    Dim objResponse As Outlook.MeetingItem
 
    'Specify the start date and end date
    dStartDate = InputBox("Enter the start date:", , "10/1/2017")
    dEndDate = InputBox("Enter the end date:", , "10/8/2017")
 
    If dStartDate <> #1/1/4501# And dEndDate <> #1/1/4501# Then
       'Select a calendar folder
       Set objCalendarFolder = Outlook.Application.Session.PickFolder
       Set objItems = objCalendarFolder.Items
       objItems.IncludeRecurrences = True
       objItems.Sort "[Start]"
 
       'Get the appointments in the specific date range
       strFilter = "[Start] >= " & Chr(34) & dStartDate & " 00:00 AM" & Chr(34) & " AND [End] <= " & Chr(34) & dEndDate & " 11:59 PM" & Chr(34)
       Set objItemsInDateRange = objItems.Restrict(strFilter)
 
       objItemsInDateRange.Sort "[Start]"
       For Each objAppointment In objItemsInDateRange
           'Cancel the meetings in this date range
           If objAppointment.MeetingStatus = olMeeting Then
              If objAppointment.Organizer = Outlook.Session.CurrentUser Then
                 objAppointment.MeetingStatus = olMeetingCanceled
                 objAppointment.Save
                 objAppointment.Send
                 objAppointment.Delete
              Else
                 Set objResponse = objAppointment.Respond(olMeetingDeclined)
                 objResponse.Send
                 objAppointment.Delete
              End If
            End If
       Next
    End If
End Sub

6. Përfundimisht, ju mund ta ekzekutoni këtë makro tani.

• Në dritaren aktuale makro, shtypni butonin "F5".
• Më pas, do t'ju kërkohet të specifikoni intervalin e datave.
• Pas kësaj, do të shfaqet një kuti tjetër dialogu, e cila kërkon që ju të zgjidhni një dosje kalendarike burimore dhe të klikoni "OK".
• Së fundi, kur makroja përfundon, mund të shihni se të gjitha takimet në intervalin specifik të datave janë anuluar.
• Në dosjen "Artikuj të dërguar", mund të gjeni anulimet e takimeve, si pamja e ekranit më poshtë:

Rregulloni gabimet e Outlook

Nëse keni përdorur Outlook për dekada, duhet të keni hasur në disa gabime. Për fat të mirë Outlook vjen i mbushur me një mjet riparimi të integruar – Scanpst. Mund ta përdorni për rregulloni Outlook gabimet. Megjithatë, nëse dështon, zgjidhja juaj e fundit janë mjetet e jashtme të rregullimit si DataNumen Outlook RepairMund të skanojë skedarët e Outlook dhe të rregullojë shumicën e gabimeve, madje edhe të rikthejë lehtësisht të dhënat e dëmtuara të Outlook-ut.

Hyrje e autorit:

Shirley Zhang është një eksperte për rikuperimin e të dhënave DataNumen, Inc., e cila është lider botëror në teknologjitë e rikuperimit të të dhënave, duke përfshirë rregulloni sql dhe produkte softuerike të riparimit të pamjes. Për më shumë informacion vizitoni www.datanumen.com