Si të vendosni automatikisht Outlook në linjë ose jashtë linje bazuar në orët tuaja të punës

Disa përdorues dëshirojnë të bëjnë Outlook të kalojë automatikisht midis statusit në linjë dhe jashtë linje bazuar në orët e tyre të punës. Pra, në këtë artikull, ne do të ndajmë një metodë të shpejtë me ju.

Në fakt, vendosja e Outlook online ose offline është shumë e lehtë. Për ta kthyer Outlook në status offline, thjesht mund të kaloni në skedën "Dërgo/Merr" dhe të shtypni butonin "Punoni jashtë linje". Dhe për t'u kthyer në statusin në linjë, thjesht shtypni përsëri këtë buton. Megjithatë, disa përdorues shpresojnë se Outlook mund të kalojë automatikisht në statusin offline kur është jashtë orarit të punës dhe të kthehet në linjë në orarin e punës. Megjithëse Outlook nuk ofron një veçori të tillë, ju prapë mund të përdorni kodin e mëposhtëm VBA për ta arritur atë.

Vendosni automatikisht Outlook në linjë ose jashtë linje bazuar në orët tuaja të punës

1. Që në fillim, nisni aplikacionin tuaj Outlook.
2. Më pas, pasi të keni akses në Outlook, duhet të hapni dosjen tuaj Tasks.
3. Më tej, duhet të krijoni një artikull Detyre të përsëritur çdo ditë.

• Klikoni në butonin "Detyrë e re" në shirit.
• Pastaj futni "Offline" në rreshtin e temës së detyrës.
• Pastaj klikoni në butonin "Përsëritje" nën skedën "Detyra".
• Në kutinë e dialogut që shfaqet, zgjidhni modelin e përsëritjes "Ditore", aktivizoni "Pa datë përfundimi" dhe shtypni "OK".
• Më pas duhet të aktivizoni një Përkujtues në "5:00 PM".
• Së fundi, shtypni butonin "Ruaj & Mbyll".

4. Më pas, ju duhet të krijoni një tjetër detyrë të përsëritur ditore të quajtur "Online" dhe të aktivizoni një kujtesë në "8:00 AM", e paraqitur si imazhi më poshtë:
5. Pas kësaj, në dritaren kryesore të Outlook, shtypni butonat "Alt + F11".
6. Më pas do të keni akses në redaktuesin VBA të Outlook, në të cilin duhet të gjeni dhe hapni projektin "ThisOutlookSession".
7. Më vonë kopjoni kodin e mëposhtëm VBA në këtë projekt.

Dim objNameSpace As Outlook.NameSpace

'Set Online/Offline Status on Outlook Startup
Private Sub Application_Startup()
    Set objNameSpace = Application.GetNamespace("MAPI")
 
    'If now is before 8:00 AM or after 5:00 PM on Outlook startup
    If Now() < DateSerial(Year(Now), Month(Now), Day(Now)) + #8:00:00 AM# Or Now() > DateSerial(Year(Now), Month(Now), Day(Now)) + #5:00:00 PM# Then
 
       'If Outlook is online
       If objNameSpace.Offline = False Then
          'set it offline
          ActiveExplorer().CommandBars.FindControl(, 5613).Execute
       End If
 
       'If now is between 8:00 AM and 5:00 PM
    Else
 
       'If Outlook is offline
       If objNameSpace.Offline = True Then
          'Set it online
          ActiveExplorer().CommandBars.FindControl(, 5613).Execute
       End If
    End If
End Sub

'Change Online/Offline Status at Specific Time
Private Sub Application_Reminder(ByVal Item As Object)
    Dim objOfflineTask As Outlook.TaskItem
    Dim objOnlineTask As Outlook.TaskItem
 
    Set objNameSpace = Application.GetNamespace("MAPI")
 
    If TypeOf Item Is TaskItem Then
       If Item.Subject = "Offline" Then
          Set objOfflineTask = Item
 
          'If Outlook is online when "Offline" task reminder alerts
          If objNameSpace.Offline = False Then
             'Set Outlook offline
             ActiveExplorer().CommandBars.FindControl(, 5613).Execute
          End If
 
          'Clear the reminder by marking task complete
          objOfflineTask.MarkComplete
 
       ElseIf Item.Subject = "Online" Then
          Set objOnlineTask = Item
 
          'If Outlook is offline when "Online" task reminder alerts
          If objNameSpace.Offline = True Then
             'Set Outlook online
             ActiveExplorer().CommandBars.FindControl(, 5613).Execute
          End If
 
          objOnlineTask.MarkComplete
 
       End If
    End If
End Sub

8. Përfundimisht, mund ta rinisni Outlook-un për të aktivizuar këtë makro.
9. Tani e tutje, Outlook juaj do të jetë në linjë gjatë orarit të punës dhe do të kalojë automatikisht në statusin offline jashtë orarit të punës.

Vendpushimi juaj i fundit në rast të rrëzimeve të Outlook

Edhe pse Outlook krenohet me veçori të shumta, Outlook ende nuk mund të qëndrojë larg gabimeve dhe dëmtimeve. Por mos u frikësoni. Për sa kohë që bëni masa paraprake të mjaftueshme, mund t'i mbroni në mënyrë efektive të dhënat tuaja të Outlook. Për shembull, duhet të bëni kopje rezervë të skedarëve tuaj PST rregullisht pasi kopjet rezervë do t'ju mundësojnë të ktheheni PST e korruptuar të dhëna. Gjithashtu, mbajtja e një mjeti të fuqishëm riparimi, si p.sh DataNumen Outlook Repair, është gjithashtu një çështje domosdoshmërie.

Hyrje e autorit:

Shirley Zhang është një eksperte për rikuperimin e të dhënave DataNumen, Inc., e cila është lider botëror në teknologjitë e rikuperimit të të dhënave, duke përfshirë rregulloni mdf dhe produkte softuerike të riparimit të pamjes. Për më shumë informacion vizitoni www.datanumen.com