Si të regjistroni automatikisht numrin total të emaileve hyrëse çdo ditë në një skedar Excel

Ky artikull do t'ju mësojë se si ta lejoni Outlook të numërojë automatikisht sa email keni marrë çdo ditë dhe të shkruani numrin në një skedar Excel.

Shumë përdoruesve u kërkohet të numërojnë numrin total të emaileve të marra çdo ditë. Përveç kësaj, për një kontroll më të përshtatshëm në të ardhmen, shumë janë mësuar të regjistrojnë numrin total në një skedar Excel. Në këtë rast, sigurisht që mund të zgjidhni të numëroni dhe regjistroni manualisht çdo ditë. Megjithatë, është pak e mundimshme. Dhe ndonjëherë mund të harroni ta bëni atë. Prandaj, duhet të dëshironi një metodë të dobishme, e cila mund ta bëjë Outlook që ta bëjë atë automatikisht. Në përgjigje të kësaj kërkese, ne do t'ju mësojmë se si të përdorni VBA për ta realizuar atë në vijim.

Regjistroni automatikisht numrin total të emaileve hyrëse çdo ditë në një skedar Excel

1. Që në fillim, hapni aplikacionin tuaj Outlook.
2. Më pas shtypni shkurtoret e tastit "Alt + F11" në dritaren kryesore të Outlook.
3. Më pas, në dritaren e redaktuesit të VBA-së, hapni projektin "ThisOutlookSession".
4. Më pas, kopjoni dhe ngjisni kodet e mëposhtme VBA në këtë projekt.

Private Sub Application_Reminder(ByVal Item As Object)
    If Item.Class = olTask And Item.Subject = "Update Email Count" Then
       Call GetAllInboxFolders
    End If
End Sub

Private Sub GetAllInboxFolders()
    Dim objInboxFolder As Outlook.Folder
    Dim strExcelFile As String
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim nNextEmptyRow As Integer
    Dim lEmailCount As Long
 
    lEmailCount = 0
    Set objInboxFolder = Outlook.Application.Session.GetDefaultFolder(olFolderInbox)
    Call UpdateEmailCount(objInboxFolder, lEmailCount)
 
    ‘Change the path to the Excel file
    strExcelFile = "E:\Email\Email Count.xlsx"
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Open(strExcelFile)
    Set objExcelWorksheet = objExcelWorkbook.Sheets("Sheet1")
 
    nNextEmptyRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
 
    'Add the values into the columns
    objExcelWorksheet.Range("A" & nNextEmptyRow) = nNextEmptyRow - 1
    objExcelWorksheet.Range("B" & nNextEmptyRow) = Year(Date - 1) & "-" & Month(Date - 1) & "-" & Day(Date - 1)
    objExcelWorksheet.Range("C" & nNextEmptyRow) = lEmailCount
 
    'Fit the columns from A to C
    objExcelWorksheet.Columns("A:C").AutoFit
   
    'Save the changes and close the Excel file
    objExcelWorkbook.Close SaveChanges:=True
End Sub

Private Sub UpdateEmailCount(objFolder As Outlook.Folder, ByRef lCurEmailCount As Long)
    Dim objItems As Outlook.Items
    Dim objItem As Object
    Dim objMail As Outlook.MailItem
    Dim strDay As String
    Dim strReceivedDate As String
    Dim lEmailCount As Long
    Dim objSubFolder As Outlook.Folder
 
    Set objItems = objFolder.Items
 
    objItems.SetColumns ("ReceivedTime")
    strDay = Year(Date - 1) & "-" & Month(Date - 1) & "-" & Day(Date - 1)
 
    For Each objItem In objItems
        If objItem.Class = olMail Then
           Set objMail = objItem
           strReceivedDate = Year(objMail.ReceivedTime) & "-" & Month(objMail.ReceivedTime) & "-" & Day(objMail.ReceivedTime)
           If strReceivedDate = strDay Then
              lCurEmailCount = lCurEmailCount + 1
           End If
        End If
    Next
 
    'Process the subfolders in the folder recursively
    If (objFolder.Folders.Count > 0) Then
       For Each objSubFolder In objFolder.Folders
           Call UpdateEmailCount(objSubFolder, lCurEmailCount)
       Next
    End If
End Sub

5. Më pas, nënshkruani këtë kod dhe ndryshoni cilësimet e makrove të Outlook për të lejuar makro të nënshkruara.
6. Pas kësaj, ju duhet të krijoni një detyrë të përsëritur në baza ditore.

• Së pari, klikoni butonin "Detyrë e re" në panelin Tasks.
• Në dritaren që shfaqet "Detyra e re", klikoni butonin "Përsëritje".
• Më pas, në kutinë e dialogut pasues, zgjidhni "Daily", "Çdo 1 ditë" dhe "Pa datë përfundimi" dhe së fundi shtypni "OK".
• Më vonë ndryshoni temën e detyrës dhe kujtesën sipas nevojave tuaja.
• Në fund, klikoni në butonin "Ruaj & Mbyll".

7. Tani e tutje, sa herë që alarmet rikujtuese të kësaj detyre, Outlook do të numërojë automatikisht emailet e marra dje dhe më pas do të regjistrojë numrin në skedarin Excel, si pamja e mëposhtme e ekranit:

Ik nga humbja e përhershme e të dhënave PST

Askush nuk është i gatshëm të pranojë humbje të përhershme të të dhënave PST. Megjithatë, skedari Outlook PST është i prirur për korrupsion. Prandaj, duhet të merrni masa paraprake të mjaftueshme, të tilla si krijimi i një kopje rezervë të qëndrueshme dhe të përditësuar të të dhënave PST dhe mbajtja e një të fuqishme Rimëkëmbja e PST mjet në afërsi, si DataNumen Outlook Repair.

Hyrje e autorit:

Shirley Zhang është një eksperte për rikuperimin e të dhënave DataNumen, Inc., e cila është lider botëror në teknologjitë e rikuperimit të të dhënave, duke përfshirë riparimi sql dhe produkte softuerike të riparimit të pamjes. Për më shumë informacion vizitoni www.datanumen.com