4 Metoda për nxjerrjen e tabelave nga një dokument fjalësh në tjetrin

Në këtë artikull, ne jemi të lumtur t'ju tregojmë me 4 metoda për të nxjerrë tabela të shumta nga një dokument Word në tjetrin.

Tabela është mjeti më i përdorur që përdorim për të ruajtur informacionin tabelar. Ajo i rendit të dhënat në rreshta dhe kolona, ​​duke u paraqitur lexuesve një pamje të qartë të të gjithë informacionit. Një dokument i gjatë mund të përmbajë shumë tabela, kështu që ekziston nevoja për t'i eksportuar ato në një dokument të ri për qëllime të ndryshme.

Këtu janë 4 qasjet tona.

Metoda 1: Eksporto në grup të gjitha tabelat nga një dokument në tjetrin

1. Para së gjithash, shtypni "Alt + F11" për të aktivizuar redaktorin VBA në Word.
2. Pastaj klikoni projektin "Normal" dhe më pas skedën "Fut".
3. Zgjidhni "Modul" në menunë rënëse.
4. Dhe klikoni dy herë për të hapur modulin dhe për të nxjerrë hapësirën e redaktimit në anën e djathtë.
5. Tani kopjoni dhe ngjisni makronë e mëposhtme atje:

Sub ExtractTablesFromOneDoc()
  Dim objTable As Table
  Dim objDoc As Document
  Dim objNewDoc As Document
  Dim objRange As Range
 
  Set objDoc = ActiveDocument
  Set objNewDoc = Documents.Add
 
  For Each objTable In objDoc.Tables
    objTable.Range.Select
    Selection.Copy
 
    '  Paste tables to new document in rich text format.
    Set objRange = objNewDoc.Range
    objRange.Collapse Direction:=wdCollapseEnd
    objRange.PasteSpecial DataType:=wdPasteRTF
    objRange.Collapse Direction:=wdCollapseEnd
    objRange.Text = vbCr
  Next objTable
 
End Sub

6. Në fund, klikoni "Run".

Kjo makro do të nxjerrë të dy tabelat dhe titrat e tyre gjithashtu.

Metoda 2: Nxjerr një tabelë specifike nga një dokument

Tani, në rast se ka shumë tabela në dokumentin tuaj, por ju duhet t'i dërgoni një tabelë të veçantë dikujt. Atëherë makroja e mëposhtme do t'ju ndihmojë shumë.

1. Së pari, instaloni dhe ekzekutoni makro hapat e mëposhtëm në metodën 1.
2. Së dyti, zëvendësoni atë makro me këtë:

Sub ExtractSpecificTables()
  Dim objTable As Table
  Dim objDoc As Document
  Dim objNewDoc As Document
  Dim objRange As Range
  Dim strTable As String
 
  strTable = InputBox("Enter the table number: ")
  Set objDoc = ActiveDocument
  Set objNewDoc = Documents.Add
 
  objDoc.Tables(strTable).Range.Select
  Selection.Copy
 
  Set objRange = objNewDoc.Range
  objRange.Collapse Direction:=wdCollapseEnd
  objRange.PasteSpecial DataType:=wdPasteRTF
 
End Sub

3. Tani do të shfaqet një kuti hyrëse.
4. Futni numrin e tabelës dhe klikoni "OK".

Metoda 3: Ekstraktimi i grupit të të gjitha tabelave nga shumë dokumente

1. Për të filluar, vendosni të gjitha skedarët në një dosje.
2. Pastaj instaloni dhe ekzekutoni një makro me udhëzimet e sakta të mësipërme.
3. Zëvendësoni makro me këtë:

Sub ExtractTablesFromMultiDocs()
  Dim objTable As Table
  Dim objDoc As Document, objNewDoc As Document
  Dim objRange As Range
  Dim strFile As String, strFolder As String
 
  '  Initialization
  strFolder = InputBox("Enter folder address here: ")
  strFile = Dir(strFolder & "\" & "*.docx", vbNormal)
 
  Set objNewDoc = Documents.Add
 
  '  Process each file in the folder.
  While strFile <> ""
    Set objDoc = Documents.Open(FileName:=strFolder & "\" & strFile)
    Set objDoc = ActiveDocument
 
    For Each objTable In objDoc.Tables
      objTable.Range.Select
      Selection.Copy
 
      Set objRange = objNewDoc.Range
      objRange.Collapse Direction:=wdCollapseEnd
      objRange.PasteSpecial DataType:=wdPasteRTF
      objRange.Collapse Direction:=wdCollapseEnd
      objRange.Text = vbCr
    Next objTable
 
    objDoc.Save
    objDoc.Close
    strFile = Dir()
  Wend
 
End Sub

4. Tani në kutinë e kërkesës, futni adresën e dosjes ku ruani dokumentet tuaja dhe klikoni "OK".

Metoda 4: Kopjoni tabelat me dorë

Megjithatë, nëse nuk ndiheni rehat me VBA, ju jeni mirë ta bëni punën manualisht për sa kohë që ka një numër të kufizuar tabelash.

1. Së pari, klikoni shenjën plus në këndin e sipërm të majtë për të zgjedhur tabelën e synuar.
2. Më pas shtypni “Ctrl+ C” për ta kopjuar.
3. Pastaj hapni një dokument të ri.
4. Dhe shtypni "Ctrl+ V" për të ngjitur tabelën në një dokument të ri.
5. Mos harroni të ruani dokumentin e ri.

Trajtoni problemet e dokumenteve

Për sa kohë që ne vazhdojmë të përdorim Word, do të ketë gjithmonë Dëmtimi i fjalës. Megjithatë, mos kini frikë më. Nuk është më një problem i pazgjidhshëm. Me një mjet të kualifikuar rikuperimi, ju keni një shans të lartë për të tërhequr të gjitha të dhënat tuaja të vlefshme.

Hyrje e autorit:

Vera Chen është një eksperte për rikuperimin e të dhënave DataNumen, Inc., e cila është lider botëror në teknologjitë e rikuperimit të të dhënave, duke përfshirë i korruptuar xlsx pdf riparimin e produkteve softuerike. Për më shumë informacion vizitoni www.datanumen.com