2 mënyra për të printuar listat e detyrave të Outlook me kategori të ndryshme në faqe të ndryshme

Nëse u keni caktuar kategori të ndryshme ngjyrash detyrave tuaja të Outlook dhe tani dëshironi të printoni listat e detyrave me kategori të ndryshme në faqe të ndryshme, mund t'i referoheni këtij artikulli. Këtu do t'ju ndajmë 2 mënyra për ta marrë atë.

Për të klasifikuar dhe menaxhuar mirë detyrat tuaja, ndoshta keni aplikuar kategori ngjyrash për detyrat tuaja. Tani, nëse dëshironi të printoni listat e detyrave tuaja me kategori të ndryshme në faqe të ndryshme, ju lutemi lexoni më tej. Në vijim do t'ju prezantojmë 2 mënyra për ta marrë atë.

Metoda 1: Printoni manualisht listat e detyrave një nga një

1. Së pari, në Outlook, hyni në panelin "Detyrat".
2. Pastaj, hapni një dosje Detyra.
3. Më pas, shtypni "Ctrl + E" për të aktivizuar shiritin "Kërko".
4. Pas kësaj, në skedën "Kërko", kliko butonin "Kategori".
5. Nga lista rënëse, zgjidhni një kategori ngjyrash.
6. Më pas, në listë do të mbeten vetëm detyrat me kategorinë e zgjedhur.
7. Tani, shkoni te "File" > "Print" për të printuar këtë listë detyrash.
8. Më pas, në të njëjtën mënyrë, printoni me dorë listat e detyrave me kategoritë e tjera të ngjyrave një nga një.

Metoda 2: Printimi i grupeve të listave të detyrave nga VBA

1. Që në fillim, aktivizoni redaktorin VBA në përputhje me "Si të ekzekutoni kodin VBA në Outlook tuaj".
2. Pastaj, shtoni referencën te "MS Excel Object Library" sipas "Si të shtoni një referencë të bibliotekës së objekteve në VBA".
3. Më pas, kopjoni kodin e mëposhtëm VBA në një modul.

Sub PrintTaskList_SpecificColorCategory()
    Dim objTasks As Outlook.Items
    Dim objTask As Outlook.TaskItem
    Dim objDictionary As Object
    Dim arrCategory As Variant
    Dim varCategory As Variant
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim varKey As Variant
    Dim strKey As String
    Dim i As Long
    Dim bSheetFound As Boolean
    Dim nLastRow As Integer
    Dim objSheet As Excel.Worksheet
 
    Set objTasks = Application.Session.GetDefaultFolder(olFolderTasks).Items
    Set objDictionary = CreateObject("Scripting.Dictionary")
 
     'Get All Tasks' Categories
    For Each objTask In objTasks
        arrCategory = Split(objTask.Categories, ",")
        For Each varCategory In arrCategory
            If objDictionary.Exists(Trim(varCategory)) = False Then
               objDictionary.Add Trim(varCategory), 0
            End If
        Next
    Next
 
    'Export the Tasks with Different Categories into Different Sheet in an Excel Workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    objExcelApp.Visible = True
 
    i = 0
    For Each varKey In objDictionary.Keys
        strKey = CStr(varKey)

        On Error Resume Next
        objExcelWorkbook.Sheets(strKey).Select
        bSheetFound = (Err = 0)
        On Error GoTo 0
        If bSheetFound = False Then
           i = i + 1
           If i < 4 Then
              Set objExcelWorksheet = objExcelWorkbook.Sheets(i)
           Else
              Set objExcelWorksheet = objExcelWorkbook.Sheets.Add(After:=objExcelWorkbook.Sheets(objExcelWorkbook.Sheets.Count))
           End If
           objExcelWorksheet.Name = strKey
        End If
 
        With objExcelWorksheet
             .Cells(1, 1) = strKey
             .Cells(1, 1).Font.Bold = True
             .Cells(1, 1).Font.Size = 18
             .Cells(2, 1) = "Subject"
             .Cells(2, 1).Font.Bold = True
             .Cells(2, 2) = "Start Date"
             .Cells(2, 2).Font.Bold = True
             .Cells(2, 3) = "Due Date"
             .Cells(2, 3).Font.Bold = True
        End With
 
        For Each objTask In objTasks
            If InStr(objTask.Categories, strKey) > 0 Then
               nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
               With objExcelWorksheet
                    .Range("A" & nLastRow) = objTask.Subject
                    .Range("B" & nLastRow) = objTask.startDate
                    .Range("C" & nLastRow) = objTask.DueDate
               End With
            End If
        Next
 
        objExcelWorksheet.Columns("A:C").AutoFit
    Next
 
    'Print out All Sheets in this Excel Workbook
    For Each objSheet In objExcelWorkbook.Sheets
        objSheet.PrintOut
    Next
 
    objExcelWorkbook.Close False
    objExcelApp.Quit
End Sub

4. Më pas, shtypni butonin "F5" për të ekzekutuar këtë makro menjëherë.
5. Kur të përfundojë makro, listat e detyrave me kategori të ndryshme do të printohen në faqe të ndryshme, siç tregohet në pamjen e mëposhtme të ekranit.

Merrni të dhëna të vlefshme nga skedari PST i komprometuar

Nëse jeni subjekt i skedarit PST të paarritshëm, hapi juaj i ardhshëm është padyshim Riparimi i PST. Në këtë rast, fillimisht mund të provoni mjetin e riparimit të kutisë hyrëse. Me kusht që të dështojë, mund të vazhdoni të provoni një mjet tjetër të jashtëm, si p.sh DataNumen Outlook Repair. Është në gjendje të rikuperojë të dhënat e PST në një kohë të shpejtë.

Hyrje e autorit:

Shirley Zhang është një eksperte për rikuperimin e të dhënave DataNumen, Inc., e cila është lider botëror në teknologjitë e rikuperimit të të dhënave, duke përfshirë rikuperoni mdf dhe produkte softuerike të riparimit të pamjes. Për më shumë informacion vizitoni www.datanumen.com