2 metoda për të numëruar shpejt email-et nga dërguesi në Outlook tuaj

Nëse dëshironi të numëroni emailet sipas dërguesit, mund t'i referoheni këtij artikulli. Këtu do t'ju ekspozojmë 2 qasje të shpejta.

Për të ditur dërguesin më aktiv për ju, mund të dëshironi të numëroni emailet sipas dërguesit. Edhe pse Outlook nuk ofron një funksion të drejtpërdrejtë për këtë, ju prapë mund të kërkoni disa zgjidhje alternative, siç është Metoda 1 e mëposhtme. Nëse mendoni se Metoda 1 është shumë e lodhshme, mund të zgjidhni Metodën 2. Është shumë më efektive pasi përdor VBA për të numëruar shpejt emailet sipas dërguesit dhe për të eksportuar numërimet në Excel. Tani lexoni dy mënyrat në detaje. Këtu do të marrim emailet në Kutinë Postare si shembull.

Metoda 1: Merrni numërimin pas grupimit të artikujve sipas fushës "Nga".

1. Për të filluar, hapni aplikacionin Outlook.
2. Pastaj hapni dosjen e kutisë hyrëse.
3. Tjetra, kaloni në skedën "Shiko".
4. Më pas, zgjidhni "Nga" në grupin "Arangement".
5. Menjëherë, të gjithë artikujt e kutisë hyrëse janë ndarë në grupe të ndryshme sipas dërguesve të ndryshëm.
6. Tani, për të numëruar artikujt nga një dërgues specifik, mund të zgjidhni të gjithë artikujt në grupin përkatës dhe të shtypni tastin "Enter". Në paralajmërimin që shfaqet, mund të shihni numërimin.

Kjo do të thotë është mjaft e lehtë, por numërimi i artikujve në të vërtetë përfshin llojet e tjera të artikujve, si ftesat për takime, kërkesat për detyra dhe faturat, jo vetëm numërimin e postës elektronike. Kështu, nëse dëshironi të numëroni vetëm emailet, në vend të kësaj mund të përdorni mënyrën e mëposhtme.

Metoda 2: Numëroni emailet nga dërguesi me Outlook VBA

1. Për të filluar, shtypni butonat "Alt + F11" në Outlook.
2. Pastaj, aktivizoni "MS Excel Object Library" sipas "Si të shtoni një referencë të bibliotekës së objekteve në VBA".
3. Më pas, kopjoni kodin më poshtë në një modul të papërdorur.

Sub CountInboxEmailsbySender()
    Dim objDictionary As Object
    Dim objInbox As Outlook.Folder
    Dim i As Long
    Dim objMail As Outlook.MailItem
    Dim strSender As String
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim varSenders As Variant
    Dim varItemCounts As Variant
    Dim nLastRow As Integer
 
    Set objDictionary = CreateObject("Scripting.Dictionary")
    Set objInbox = Outlook.Application.Session.GetDefaultFolder(olFolderInbox)
 
    For i = objInbox.Items.Count To 1 Step -1
        If objInbox.Items(i).Class = olMail Then
           Set objMail = objInbox.Items(i)
           strSender = objMail.SenderEmailAddress
 
           If objDictionary.Exists(strSender) Then
              objDictionary.Item(strSender) = objDictionary.Item(strSender) + 1
           Else
              objDictionary.Add strSender, 1
           End If
        End If
    Next

    Set objExcelApp = CreateObject("Excel.Application")
    objExcelApp.Visible = True
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
 
    With objExcelWorksheet
         .Cells(1, 1) = "Sender"
         .Cells(1, 2) = "Count"
    End With
 
    varSenders = objDictionary.Keys
    varItemCounts = objDictionary.Items
 
    For i = LBound(varSenders) To UBound(varSenders)
        nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
        With objExcelWorksheet
             .Cells(nLastRow, 1) = varSenders(i)
             .Cells(nLastRow, 2) = varItemCounts(i)
        End With
    Next
 
    objExcelWorksheet.Columns("A:B").AutoFit
End Sub

3. Pas kësaj, shtypni butonin "F5".
4. Kur të përfundojë makro, do të shfaqet një skedar i ri Excel.
5. Siç mund ta shihni, ai përmban numrin e emaileve në kutinë hyrëse nga dërgues të ndryshëm.

Hiqni problemet frustruese të Outlook

Ndoshta ju keni qenë ndonjëherë subjekt i shumë problemeve në Outlook-un tuaj. Për t'i trajtuar ato në mënyrë efektive, mund të dëshironi një mënyrë të gjithanshme dhe të fuqishme. Megjithatë, në fakt, nuk ekziston një metodë e tillë. Ajo që mund të bëni është të keni kujdes nga operacionet tuaja në Outlook dhe të bëni kopje rezervë të rregullt. Natyrisht, nëse është e mundur, ju sugjerojmë që më mirë të mbani në dorë një mjet rregullimi me përvojë, si p.sh DataNumen Outlook Repair. Mund të rregullojë dhe riparojë çështje të ndryshme PST PST e korruptuar skedar si një fllad.

Hyrje e autorit:

Shirley Zhang është një eksperte për rikuperimin e të dhënave DataNumen, Inc., e cila është lider botëror në teknologjitë e rikuperimit të të dhënave, duke përfshirë shërohem Sql Server dhe produkte softuerike të riparimit të pamjes. Për më shumë informacion vizitoni www.datanumen.com