2 Metoda për të eksportuar një gamë të caktuar datash të kalendarit tuaj Outlook si skedar iCalendar (.ics)

Ky artikull do t'ju ndajë 2 mënyra për të eksportuar një gamë të caktuar datash të kalendarit Outlook si një skedar iCalendar (.ics). Ju mund të zgjidhni ose sipas dëshirës tuaj.

Në Outlook, mund të eksportoni një kalendar të tërë si skedar iCalendar (.ics) vetëm nëpërmjet veçorisë "Ruaj si". Megjithatë, nëse dëshironi të eksportoni shpejt një gamë të caktuar datash të kalendarit si iCalendar, funksioni i integruar "Ruaj si" ose "Eksport" nuk mund të ndihmojë. Kështu, këtu do t'ju prezantojmë 2 mjete.

Metoda 1: Eksporto me funksionin "Kalendari i postës elektronike".

1. Në radhë të parë, hapni aplikacionin tuaj Outlook.
2. Pastaj kaloni në zonën "Kalendar".
3. Më pas duhet të zgjidhni kalendarin specifik në panelin e majtë të navigimit.
4. Pas kësaj, duhet të gjeni dhe shtypni butonin "Kalendari i postës elektronike" në shirit.
5. Menjëherë, një email i ri do të shfaqet me një kuti dialogu "Dërgo një kalendar përmes postës elektronike".
6. Tani, mund të specifikoni intervalin e datave në këtë kuti dialogu, si imazhi më poshtë:
7. Pasi të klikoni në butonin "OK", kalendari në intervalin e caktuar të datave do të konvertohet në një skedar iCalendar, bashkangjitur në emailin aktual.
8. Më pas, mund të kufizoni inspektorët aktualë të Outlook derisa të shihni desktopin tuaj të Windows.
9. Përfundimisht, mund të tërhiqni dhe lëshoni skedarin ics të bashkangjitur në desktop, i paraqitur si pamja e ekranit më poshtë:

Metoda 2: Eksporto përmes Outlook VBA

1. Të start me, në dritaren kryesore të Outlook, shtypni butonat "Alt + F11"/
2. Më pas do të futni me sukses redaktorin VBA të Outlook, në të cilin duhet të hapni një modul bosh.
3. Më pas, kopjoni kodin e mëposhtëm VBA në këtë modul.

Sub ExportCalender_inSpecificDateRange_AsiCalendarFile()
    Dim objCalendarFolder As Outlook.Folder
    Dim objCalendarExporter As Outlook.CalendarSharing
    Dim dStartDate As Date
    Dim dEndDate As Date
    Dim objShell As Object
    Dim objSavingFolder As Object
    Dim strSavingFolder As String
    Dim striCalendarFile As String
 
    'Get the current Calendar folder
    Set objCalendarFolder = Outlook.Application.ActiveExplorer.CurrentFolder
 
    If Not objCalendarFolder Is Nothing And objCalendarFolder.DefaultItemType = olAppointmentItem Then
       Set objCalendarExporter = objCalendarFolder.GetCalendarExporter
 
       'Enter the specific start date and end date
       dStartDate = InputBox("Enter the start date, such as 7/1/2017:", "Specify Start Date")
       dEndDate = InputBox("Enter the end date, such as 8/31/2017:", "Specify End Date")
 
       If dStartDate <> #1/1/4501# And dEndDate <> #1/1/4501# Then
          'Select a Windows folder for saving the exported iCalendar file
          Set objShell = CreateObject("Shell.Application")
          Set objSavingFolder = objShell.BrowseForFolder(0, "Select a folder:", 0, "")
          strSavingFolder = objSavingFolder.self.Path
 
          If strSavingFolder <> "" Then
             striCalendarFile = strSavingFolder & "\" & "Calendar from " & Format(dStartDate, "YYYY-MM-DD") & " to " & Format(dEndDate, "YYYY-MM-DD") & ".ics"
 
             'Export the calendar in specific date range
             With objCalendarExporter
                  .IncludeWholeCalendar = False
                  .StartDate = dStartDate
                  .EndDate = dEndDate
                  .CalendarDetail = olFullDetails
                  .IncludeAttachments = True
                  .IncludePrivateDetails = False
                  .RestrictToWorkingHours = False
                  .SaveAsICal striCalendarFile
            End With
 
            MsgBox "Calendar Exported Successfully!", vbInformation
          End If
      Else
          MsgBox "Open a calendar folder, please!", vbExclamation + vbOKOnly
      End If
    End If
End Sub

4. Më vonë, mund të shtoni makro të re në shiritin e veglave të aksesit të shpejtë.
5. Në fund të fundit, mund ta provoni këtë projekt VBA.

• Së pari, hyni në kalendarin që dëshironi të eksportoni.
• Pastaj klikoni butonin e ri makro në shiritin e veglave të aksesit të shpejtë.
• Më pas do t'ju kërkohet të specifikoni intervalin e datave - start dhe data e përfundimit.
• Pas kësaj, duhet të zgjidhni një dosje Windows për ruajtjen e skedarit ics.
• Së fundi, kalendari në intervalin specifik të datave do të eksportohet si skedar ics.

Merrni masa paraprake adekuate për të shmangur korrupsionin PST

Ju duhet të pranoni një fakt të padiskutueshëm që Outlook është i prekshëm. Prandaj, këshillohet të bëni kopje rezervë periodike të PST. Plus, ju duhet të mbani një sy në të gjitha rreziqet e mundshme, të tilla si viruset e maskuar në email. Përveç kësaj, është e kujdesshme të përgatitet një e specializuar Rimëkëmbja e opinionit mjet, si p.sh DataNumen Outlook Repair.

Hyrje e autorit:

Shirley Zhang është një eksperte për rikuperimin e të dhënave DataNumen, Inc., e cila është lider botëror në teknologjitë e rikuperimit të të dhënave, duke përfshirë rikuperoni sql dhe produkte softuerike të riparimit të pamjes. Për më shumë informacion vizitoni www.datanumen.com