2 Metoda të thjeshta për të krijuar shpejt një detyrë të Outlook për një libër pune në Excel

Disa përdorues janë të etur për të krijuar shpejt një detyrë Outlook për një libër pune Excel. Kështu, në këtë artikull, ne do të prezantojmë 2 mënyra të thjeshta për ta marrë atë.

Ndonjëherë, mund të dëshironi të krijoni një detyrë Outlook nga një skedar Excel për ndjekje ose arsye të tjera. Në fakt, Microsoft Excel vjen me një veçori origjinale të "Krijo detyrën e Microsoft Outlook", si Metoda 1 e prezantuar në vijim. Por, ai do të bashkëngjisë vetëm librin e punës të Excel në një detyrë të Outlook. Nëse ajo që dëshironi është të kopjoni me shpejtësi të gjithë përmbajtjen e të gjitha fletëve të punës në trupin e një detyre të Outlook, mund të përdorni metodën 2 në vend të kësaj. Tani lexoni për të marrë 2 mjetet në detaje.

Metoda 1: Përdorni komandën "Create Microsoft Outlook Task" në MS Excel

1. Në radhë të parë, hapni librin specifik të punës Excel.
2. Më pas, klikoni butonin e shigjetës poshtë në shiritin e veglave të aksesit të shpejtë.
3. Tjetra, zgjidhni "Më shumë komanda" nga lista rënëse.
4. Më vonë, në dritaren e re "Opsionet e Excel", në skedën "Shiri i veglave të aksesit të shpejtë", shtoni komandën "Krijo detyrën e Microsoft Outlook" në shiritin e veglave të aksesit të shpejtë.

• Së pari, zgjidhni "Commands Not in the Ribbon" nga lista e "Zgjidhni komandat nga".
• Më pas, gjeni dhe vendosni komandën "Krijo detyrën e Microsoft Outlook".
• Më pas, klikoni butonin "Shto >>" në qendër.
• Së fundi, shtypni butonin "OK".

5. Përfundimisht, pasi të ktheheni në librin e punës të Excel, klikoni butonin e ri në shiritin e veglave të aksesit të shpejtë.
6. Menjëherë, do të shfaqet një detyrë e re e Outlook, e cila është bashkangjitur me librin aktual të punës në Excel, si pamja e mëposhtme e ekranit.

Metoda 2: Kopjoni librin e punës Excel në trupin e një detyre të Outlook përmes kodit VBA

1. Fillimisht, hapni skedarin burim Excel.
2. Më pas, shtypni "Alt + F11" për të aktivizuar redaktorin Excel VBA.
3. Më pas, aktivizoni "Biblioteka e Objekteve të Microsoft Outlook", për të cilën mund të referoheni te "Si të shtoni një referencë të bibliotekës së objekteve në VBA".
4. Pas kësaj, vendosni kodin VBA më poshtë në një modul ose projekt "ThisWorkbook".

Sub CreateOutlookTaskforExcelWorkbook()
    Dim objOutlookApp As Outlook.Application
    Dim objTask As Outlook.TaskItem
    Dim objWorksheet As Excel.Worksheet
    Dim objTempWorkbook As Excel.Workbook
    Dim objTempWorksheet As Excel.Worksheet
    Dim strTempFolder As String
    Dim strHTMLFile As String
    Dim objHTMLFile As Object
    Dim objFileSystem As Object
    Dim objTextStream As Object
    Dim objTempMail As Outlook.MailItem
 
    Set objOutlookApp = CreateObject("Outlook.Application")
    Set objTask = objOutlookApp.CreateItem(oltaskitem)
    objTask.Subject = ActiveWorkbook.Name
    objTask.Display
 
    For Each objWorksheet In ActiveWorkbook.Sheets
        objWorksheet.UsedRange.Copy
 
        Set objTempWorkbook = Excel.Application.Workbooks.Add(1)
        Set objTempWorksheet = objTempWorkbook.Sheets(1)
        With objTempWorksheet.Cells(1)
             .PasteSpecial xlPasteValues
             .PasteSpecial xlPasteColumnWidths
             .PasteSpecial xlPasteFormats
        End With
 
        strTempFolder = CStr(Environ("USERPROFILE")) & "\AppData\Local\Temp"
        strHTMLFile = strTempFolder & "\Temp" & Format(Now, "yyyymmddhhmmss") & ".htm"
        Set objHTMLFile = objTempWorkbook.PublishObjects.Add(xlSourceRange, strHTMLFile, objTempWorksheet.Name, objTempWorksheet.UsedRange.Address)
        objHTMLFile.Publish (True)

        Set objTempMail = objOutlookApp.CreateItem(olMailItem)
 
        Set objFileSystem = CreateObject("Scripting.FileSystemObject")
        Set objTextStream = objFileSystem.OpenTextFile(strHTMLFile)
        objTempMail.HTMLBody = objTextStream.ReadAll
        objTempMail.Display
 
        objTask.Body = objTask.Body & vbCr & "-----------------------" & vbCr & objTempMail.Body

        objTextStream.Close
        objTempWorkbook.Close False
        Kill strHTMLFile
        objTempMail.Close olDiscard
    Next
End Sub

5. Përfundimisht, shtypni butonat "F5".
6. Kur makro të përfundojë, do të merrni një detyrë të Outlook, e cila përmban përmbajtjen e librit të punës të Excel në trup, të paraqitur si pamja e mëposhtme e ekranit.

Rikthe të dhënat e Outlook nga kopjet rezervë

Rekomandohet shumë të bëni kopje rezervë të të dhënave të kompjuterit tuaj në intervale të rregullta, natyrisht duke përfshirë skedarët tuaj të të dhënave Outlook. Në këtë mënyrë, nuk duhet të shqetësoheni për humbjen e të dhënave të Outlook. Edhe nëse skedari juaj Outlook dëmtohet, mund t'i rikuperoni të dhënat nga kopjet rezervë me lehtësi. Por, duke supozuar se nuk keni bërë kopje rezervë të të dhënave, në raste të tilla, ju duhet të provoni rikuperimin e PST përmes një mjeti të aftë të rregullimit, si p.sh. DataNumen Outlook Repair. Mundet rikuperoni PST pa thyer djersë.

Hyrje e autorit:

Shirley Zhang është një eksperte për rikuperimin e të dhënave DataNumen, Inc., e cila është lider botëror në teknologjitë e rikuperimit të të dhënave, duke përfshirë riparim mdf dhe produkte softuerike të riparimit të pamjes. Për më shumë informacion vizitoni www.datanumen.com