알 수없는 보낸 사람이 보낸 Outlook 전자 메일에서 하이퍼 링크를 자동으로 비활성화하는 방법

Outlook 솔루션 2025 년 9 월 29 일

악성 링크를 차단하려면 알 수 없는 발신자로부터 수신되는 이메일의 하이퍼링크를 자동으로 비활성화하도록 Outlook을 구성하는 것이 좋습니다. 이 기사에서는 코르크 마개처럼 얻을 수 있도록 도와주는 VBA 코드를 공개합니다.

많은 사용자가 전자 메일 기반 바이러스가 Outlook 파일을 공격했다고 불평했습니다. 대부분의 경우 알 수 없는 발신자가 보낸 이메일을 쉽게 신뢰하기 때문입니다. 그래서 그들은 메일에 있는 하이퍼링크를 다운로드하거나 클릭합니다. 이제부터 방법을 공유하겠습니다. Outlook이 알 수 없는 발신자로부터 들어오는 이메일의 하이퍼링크를 자동으로 비활성화하도록 할 수 있습니다. 그러한 요구 사항이 있는 경우 자세한 내용을 보려면 계속 읽으십시오.

알 수 없는 발신자로부터 받는 이메일의 하이퍼링크 자동 비활성화

로tart, Outlook에서 "Alt + F11"을 사용하여 VBA 편집기로 이동합니다.
다음으로 새 화면에서 p에 따라 "MS VBScript 정규식" 개체를 추가합니다.ost "개체 라이브러리를 추가하는 방법rary VBA의 참조".
그런 다음 다음 코드를 복사하여 "ThisOutlookSession" 프로젝트에 붙여넣습니다.

Public WithEvents objInboxItems As Outlook.Items

Private Sub Application_Startup()
    Set objInboxItems = Outlook.Application.Session.GetDefaultFolder(olFolderInbox).Items
End Sub

'Occurs when new mail arrives in your Inbox
Private Sub objInboxItems_ItemAdd(ByVal Item As Object)
    Dim objMail As MailItem
    Dim objContacts As Outlook.Items
    Dim strFilter As String
    Dim objFoundContact As Outlook.ContactItem
    Dim bUnknownSender As Boolean
    Dim objRegExp As Object
    Dim objFoundResults As Object
    Dim i, n As Long
 
    If TypeOf Item Is MailItem Then
       Set objMail = Item
 
       'Check if the sender is in your default Contact folder
       Set objContacts = Application.Session.GetDefaultFolder(olFolderContacts).Items
       For i = 1 To 3
           strFilter = "[Email" & i & "Address] = " & objMail.SenderEmailAddress
           Set objFoundContact = objContacts.Find(strFilter)
           If Not (objFoundContact Is Nothing) Then
              bUnknownSender = False
              Exit For
           End If
       Next
       If objFoundContact Is Nothing Then
          bUnknownSender = True
       End If
 
       'If the sender is unknown
       If bUnknownSender = True Then
          'Find the urls within "<a href=" tags in HTMLbody of Mail
          Set objRegExp = CreateObject("vbscript.RegExp")
          With objRegExp
               .Pattern = "<?href\s*=\s*[""'].+?[""'][^>]*?"
               .IgnoreCase = True
               .Global = True
          End With
 
          If objRegExp.Test(objMail.HTMLBody) Then
             Set objFoundResults = objRegExp.Execute(objMail.HTMLBody)
             For n = 1 To objFoundResults.Count
                 'Disable the hyperlinks in HTMLbody
                 objMail.HTMLBody = Replace(objMail.HTMLBody, objFoundResults.Item(n - 1).Value, "")
             Next
          End If
 
          'Save the mail
          objMail.Save
       End If
    End If
End Sub

그런 다음 res로 이 매크로를 활성화합니다.tart Outlook 또는 “Application_S”에서 “F5” 키 버튼을 누르면tartup”서브 루틴.
그 이후로 기본 연락처 폴더에 저장되지 않은 보낸 사람의 전자 메일이 받은 편지함에 도착할 때마다 Outlook은 해당 전자 메일의 하이퍼링크를 자동으로 비활성화합니다.

Outlook 보호의 몇 가지 필요성

Outlook은 손상되기 쉽기 때문에 Outlook 파일을 보호하기가 매우 어렵습니다. 여기서는 Outlook 데이터 보호 중 몇 가지 필수 항목을 나열합니다. 우선 정기적으로 Outlook 데이터를 백업해야 합니다. 또한 악의적인 첨부 파일이나 하이퍼링크와 같은 모든 잠재적 위험에 주의하는 것이 중요합니다. 마지막으로 다음과 같은 강력한 Outlook 수정 도구를 미리 준비해야 합니다. DataNumen Outlook Repair. 필요할 때 확실히 도움이 될 것입니다. PST 수리 파일이지만 받은 편지함 오류 수정 도구는 실패를 증명합니다.

저자 소개 :

Shirley Zhang은 데이터 복구 전문가입니다. DataNumen, Inc.는 다음과 같은 데이터 복구 기술 분야의 세계적 리더입니다. 손상된 mdf 및 전망 수리 소프트웨어 제품. 자세한 내용은 WWW.datanumen.COM