How to Quickly Exclude Original “CC” Recipients when Using “Reply All” in Outlook

When using “Reply All”, the responding email will also include the “CC” recipients of the original email in “CC” field. But, if you wish to exclude this type of recipient, you can use the method introduced this article.

At times, you wish to reply an email to the original sender and “To” recipients. In this scenario, you’ll definitely think of using “Reply All” option. However, by this means, if the original mail also has “CC” recipients, the “Reply All” email will auto copy the “CC” recipients to the “CC” field. If you do not want to reply to them, you have to manually remove them, which is a bit troublesome. Now, in the followings, we will teach you how to let Outlook auto accomplish it as per your needs.

Auto Included Original "CC" Recipients

Quickly Exclude Original “CC” Recipients when Using “Reply All”

  1. For a start, launch Outlook.
  2. Then, access VBA editor by reading the previous article – “How to Run VBA Code in Your Outlook“.
  3. Next, copy the following VBA code into the “ThisOutlookSession” project.
Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objMail As Outlook.MailItem

Private Sub Application_Startup()
    Set objInspectors = Outlook.Application.Inspectors
    Set objExplorer = Outlook.Application.ActiveExplorer
End Sub

Private Sub objExplorer_Activate()
    On Error Resume Next
    If TypeOf objExplorer.Selection.Item(1) Is MailItem Then
       Set objMail = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If TypeOf Inspector.CurrentItem Is MailItem Then
       Set objMail = Inspector.CurrentItem
    End If
End Sub

'Occurs when you click "Reply All"
Private Sub objMail_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Dim objRecipient As Outlook.Recipient
    Dim i As Long
 
    'Ask you if to exclude CC recipients
    If MsgBox("Do you want to exclude original CC recipients? " , vbQuestion + vbYesNo) = vbYes Then
       'If select Yes, remove CC recipients
       For i = Response.Recipients.Count To 1 Step -1
           If Response.Recipients(i).Type = olCC Then
              Response.Recipients.Remove (i)
           End If
       Next
    End If
End Sub

VBA Code - Quickly Exclude Original "CC" Recipients when Using "Reply All"

  1. Subsequently, restart your Outlook to activate this new project.
  2. Since then, every time when you hit “Reply All” button, you’ll get a prompt, as shown in the following image, asking if you would like to exclude original CC recipients.Confirmation
  3. If you select “Yes”, Outlook will auto remove the recipients in “CC” field.Original "CC" Recipients Are Removed

Keep Well-Prepared for Outlook Damage

As we all know, no one can 100% ensure that they are able to be immune from Outlook damage. Hence, it is essential for all Outlook regular users to make many precautions. First of all, one of the most imperative ones is to keep a consistent and updated Outlook data backup. Then, it is necessary to learn how to make use of inbox repair tool. Last but not least, it is prudent and recommended to keep an experienced Outlook fix tool in vicinity, such as DataNumen Outlook Repair.

Author Introduction:

Shirley Zhang is a data recovery expert in DataNumen, Inc., which is the world leader in data recovery technologies, including recover mdf and outlook repair software products. For more information visit www.datanumen.com

4 responses to “How to Quickly Exclude Original “CC” Recipients when Using “Reply All” in Outlook”

  1. We wish to thank you again for the wonderful ideas you offered Jesse when preparing a post-graduate
    research in addition to, most importantly, with regard to providing the many ideas in one blog post.
    In case we had been aware of your web site a year
    ago, we’d have been rescued from the needless measures we were taking.

    Thanks to you. sex shop

  2. We would like to thank you once again for the stunning ideas you
    offered Janet when preparing her own post-graduate research in addition to,
    most importantly, pertaining to providing each of the ideas in one blog post.
    In case we had been aware of your web page a year ago, we will have been kept
    from the unnecessary measures we were employing. Thank you
    very much. toys for adults

  3. We wish to thank you just as before for the beautiful ideas you offered Jesse
    when preparing her post-graduate research and,
    most importantly, regarding providing every one of the ideas in a single blog post.

    Provided we had been aware of your web page a year ago,
    we might have been kept from the nonessential
    measures we were taking. Thank you very much. toys for adults

Leave a Reply

Your email address will not be published. Required fields are marked *