How to Set Different Quick Click Flags for Different Kinds of Outlook Items

“Quick Click Flag” refers to the default flag when you single-click on the flag column of an Outlook item. Outlook only allows you to set one quick click flag regardless of the item type. So, if you wish to set different quick click flags on basis of item types, you can use the way introduced in this article.

To set quick click flag, you can right click on “flag” column of an item and select “Set Quick Click”. Then, in the popup small dialog box, choose the flag at will. By default, Outlook will apply this quick click flag for all kinds of items. Nevertheless, in reality, a majority of users hope to apply different quick click flags to different types of Outlook items. Therefore, in the followings, we will teach you get it using an example of emails and contacts.Set Quick Click

Set Different Quick Click Flags for Different Kinds of Outlook Items

  1. At the very outset, start Outlook VBA editor with reference to “How to Run VBA Code in Your Outlook“.
  2. Then, copy the VBA code below into the “ThisOutlookSession” project.
Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objMail As Outlook.MailItem
Public WithEvents objContact As Outlook.ContactItem

Private Sub Application_Startup()
    Set objExplorer = Outlook.Application.ActiveExplorer
End Sub

Private Sub objExplorer_SelectionChange()
    On Error Resume Next
    If objExplorer.Selection.Item(1).Class = olMail Then
       Set objMail = objExplorer.Selection.Item(1)
    ElseIf TypeOf objExplorer.Selection.Item(1) Is ContactItem Then
       Set objContact = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objMail_PropertyChange(ByVal Name As String)
    If Name = "ToDoTaskOrdinal" Then
       If objMail.IsMarkedAsTask = True Then
          '"Tomorrow" Flag for Emails
          objMail.TaskStartDate = Now + 1
       End If
   End If
End Sub

Private Sub objContact_PropertyChange(ByVal Name As String)
    If Name = "ToDoTaskOrdinal" Then
       If objContact.IsMarkedAsTask = True Then
          '"Today" Flag for Contacts
          objContact.TaskStartDate = Date & " 17:00"
       End If
    End If
End Sub

VBA Code - Set Different Quick Click Flags for Different Kinds of Outlook Items

  1. Afterwards, place cursor into the “Application_Startup” subroutine and press “F5” key to activate this macro.
  2. Eventually, you can have a try.
  • Select an email and click the “Flag” column. At once, the “Tomorrow” flag will be added to the email.Quick Click Flag for Emails
  • Then, pitch on a contact and click the “Flag” column. Immediately, the “Today” flag will be added to the selected contact.Quick Click Flag for Contacts

Prohibit Malicious Emails

Though macro contributes a lot to our working in Outlook, you still watch out for macros, especially those from the external unknown emails. It’s because that the macros may contain viruses, which can attack your Outlook data with ease. Once your Outlook file is infected, aside from killing the viruses, you have to repair the Outlook file. Generally, inbox repair tool will not make effects. Your only resort is a more potent and creditworthy third party Outlook fix tool, such as DataNumen Outlook Repair.

Author Introduction:

Shirley Zhang is a data recovery expert in DataNumen, Inc., which is the world leader in data recovery technologies, including repair mdf and outlook repair software products. For more information visit

Leave a Reply

Your email address will not be published. Required fields are marked *