How to Set Different Default Reminder Time for Different Kinds of Flagged Items in Your Outlook

By default, Outlook will auto use the default reminder time of tasks to all kinds of flagged items. Yet, if you would like to use different reminder time for flagged items on basis of item type, you can refer to the method introduced in this article.

Outlook allows you to set default reminder time for all flagged items, regardless of the item type. You can go to “File” menu and click “Options”. Then, in “Outlook Options” window, you can see the “Default reminder time” option on “Tasks” tab, as shown in the following screenshot.

Default reminder time

Nevertheless, most users hope to use different reminder time for different kinds of flagged items, such as “9:00” for flagged mails and “17:30” for flagged contacts. Now, in the followings, we will focus on this example to introduce a method.

Set Different Default Reminder Time for Different Kinds of Flagged Items

  1. To start with, launch Outlook application.
  2. Then, access Outlook VBA editor with reference to “How to Run VBA Code in Your Outlook“.
  3. In the subsequent “Microsoft Visual Basic for Applications” window, copy the following code into “ThisOutlookSession” project.
Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objMail As Outlook.MailItem
Public WithEvents objContact As Outlook.ContactItem

Private Sub Application_Startup()
    Set objExplorer = Outlook.Application.ActiveExplorer
    Set objInspectors = Outlook.Application.Inspectors
End Sub

Private Sub objExplorer_SelectionChange()
    On Error Resume Next
    If objExplorer.Selection.Item(1).Class = olMail Then
       Set objMail = objExplorer.Selection.Item(1)
    ElseIf TypeOf objExplorer.Selection.Item(1) Is ContactItem Then
       Set objContact = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If Inspector.CurrentItem.Class = olMail Then
       Set objMail = Inspector.CurrentItem
    ElseIf Inspector.CurrentItem.Class = olContact Then
       Set objContact = Inspector.CurrentItem
    End If
End Sub

Private Sub objMail_PropertyChange(ByVal Name As String)
    If Name = "ToDoTaskOrdinal" Then
       If objMail.IsMarkedAsTask = True Then
          If objMail.TaskDueDate <> "1/1/4501" Then
             With objMail
                  .ReminderSet = True
                  'Change the reminder time for flagged emails
                  .ReminderTime = objMail.TaskDueDate & " 10:00"
                  .Save
             End With
          End If
       End If
    End If
End Sub

Private Sub objContact_PropertyChange(ByVal Name As String)
    If Name = "ToDoTaskOrdinal" Then
       If objContact.IsMarkedAsTask = True Then
          If objContact.TaskDueDate <> "1/1/4501" Then
             With objContact
                  .ReminderSet = True
                  'Change the reminder time for flagged contacts
                  .ReminderTime = objContact.TaskDueDate & " 17:30"
                  .Save
             End With
          End If
       End If
    End If
End Sub

VBA Code - Set Different Default Reminders for Different Kinds of Flagged Items

  1. After that, restart Outlook to activate this macro.
  2. From now on, every time when you flag an email, the reminder time will be set to “10:00” on flag due date.Default Reminder Time for Flagged Emails
  3. And when you flag a contact, the reminder time will be set to “17:30” on flag due date.Default Reminder Time for Flagged Contacts

Tackle Outlook Problems Flexibly

You can come across all kinds of problems in your Outlook. So, you have to learn some measures to deal with them in advance. For instance, if your Outlook often restarts, you need to repair Office or disable the third party add-ins, etc. Or if your Outlook PST gets compromised, you can first try the inbox repair tool. When it fails, you can continue resorting to a powerful external tool, like DataNumen Outlook Repair.

Author Introduction:

Shirley Zhang is a data recovery expert in DataNumen, Inc., which is the world leader in data recovery technologies, including mdf recovery and outlook repair software products. For more information visit www.datanumen.com

Leave a Reply

Your email address will not be published. Required fields are marked *