How to Auto Use Different Font Colors for Replying and Forwarding Emails with Outlook VBA

By default, you cannot let Outlook auto use different font colors for replying and forwarding emails. Therefore, if you have such a requirement, you can read this post to learn a smart approach.

Outlook only permits you to specify a font used for both replying and forwarding emails. You can go to “File” > “Options”. Then, in “Outlook Options”, turn to “Mail” tab and click “Stationery and Fonts…” button. In the subsequent window, you can see the “Font” button in “Replying or forwarding messages”. Click it, and then you can set a specific font color for replying and forwarding emails.

However, many users hope to use different font colors for replying or forwarding emails. Though Outlook doesn’t provide any direct features for this, it still can be realized with VBA code. Now, read on to get such a piece of VBA code.

Auto Use Different Font Colors for Replying and Forwarding Emails

1. For a start, launch Outlook application.
2. Then, trigger the VBA editor with reference to “How to Run VBA Code in Your Outlook“.
3. Next, in accordance to “How to Add an Object Library Reference in VBA“, add the reference to “MS Word Object Library”.
4. Subsequently, copy the following code into “ThisOutlookSession” project.

Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objMail As Outlook.MailItem

Private Sub Application_Startup()
    Set objInspectors = Outlook.Application.Inspectors
    Set objExplorer = Outlook.Application.ActiveExplorer
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If TypeOf Inspector.CurrentItem Is MailItem Then
       Set objMail = Inspector.CurrentItem
    End If
End Sub

Private Sub objExplorer_SelectionChange()
    On Error Resume Next
    If TypeOf objExplorer.Selection.Item(1) Is MailItem Then
       Set objMail = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objMail_Reply(ByVal Response As Object, Cancel As Boolean)
    Dim objReply As Outlook.MailItem
    Dim objReplyDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objReply = objMail.Reply
    objReply.Display
    Set objReplyDoc = objReply.GetInspector.WordEditor
    objReplyDoc.Range(0, 0).Select
    Set objDocSelection = objReplyDoc.Application.Selection
    'Use "Pink" font in "Reply"
    objDocSelection.Font.ColorIndex = wdPink
End Sub

Private Sub objMail_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Dim objReplyAll As Outlook.MailItem
    Dim objReplyAllDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objReplyAll = objMail.ReplyAll
    objReplyAll.Display
    Set objReplyAllDoc = objReplyAll.GetInspector.WordEditor
    objReplyAllDoc.Range(0, 0).Select
    Set objDocSelection = objReplyAllDoc.Application.Selection
    'Use "Green" font in "Reply All"
    objDocSelection.Font.ColorIndex = wdGreen
End Sub

Private Sub objMail_Forward(ByVal Forward As Object, Cancel As Boolean)
    Dim objForward As Outlook.MailItem
    Dim objForwardDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objForward = objMail.Forward
    objForward.Display
    Set objForwardDoc = objForward.GetInspector.WordEditor
    objForwardDoc.Range(0, 0).Select
    Set objDocSelection = objForwardDoc.Application.Selection
    'Use "Blue" font in Forward
    objDocSelection.Font.ColorIndex = wdBlue
End Sub

5. After that, restart Outlook to activate this macro.
6. Finally, you can have a try.

• Select or open an email.
• Then, click “Reply” button. In replying email, you can type some words in body. The font color must be pink.
• Or click “Reply All” button. In the new “replying all” mail, input words in body. The font color is surely green.
• Similarly, click “Forward” button. In the forwarding mail, the new words will be shown in blue.

Take Recourse to Reliable Software

In the event of Outlook corruption, most users tend to resort to Outlook recovery software. There are a great amount of such programs available in market. And some of them are even free of charge. Nevertheless, you ought to beware of those from unknown sources in that they may make the current case worse and worse. You ought to take aid of a reliable and experienced tool, like DataNumen Outlook Repair.

Author Introduction:

Shirley Zhang is a data recovery expert in DataNumen, Inc., which is the world leader in data recovery technologies, including corrupted sql and outlook repair software products. For more information visit www.datanumen.com