2 Methods to Batch Send Outlook Email to All Contacts in a Specific Color Category

If you would like to send Outlook email to all contacts in a specific color category in batches, you could utilize the 2 methods introduced in this article.

For some reasons, at times, you may need to send a same email to all contacts in a specific color category. Without any doubts, sending one by one is pretty tedious. Hence, here we will share you 2 approaches. Both have their own pros and cons, you could choose either to your liking.

Method 1: Batch Send to All Contacts in a Specific Category in One Contact Folder

1. To start with, launch your Outlook application.
2. Then, access “Contacts” area and open a contact folder.
3. Subsequently, click into the search box, and then hit the “Categorize” button and choose a specific color category from the drop down list.
4. After that, you will see that only the contacts in a specific color category are listed. Now you could select all the search results by pressing “Ctrl + A” key.
5. Later you can switch back to “Home” tab and click on the “E-mail” button.
6. At once, a new email will display. Now you can compose it as per your needs and finally hit “Send” button to send it out.

If you have multiple contacts folders in a specific Outlook data file and would like to loop through all these folders and find the contacts in a specific color category and then bulk send an email to them, you could utilize the following way.

Method 2: Batch Send to All Contacts in a Specific Category in All Contact Folders

1. First off, press “Alt + F11” keys in the main Outlook screen.
2. Next, in the new window, you can open a new module.
3. Then copy the following VBA code into this module.

Dim objSourcePSTFile As Outlook.Folder
Dim objMail As Outlook.MailItem
Dim objMailRecipients As Outlook.Recipients

Sub SendanEmailtoAllContactsinSpecificColorCategory()
    Dim objFolder As Outlook.Folder

    Set objMail = Application.CreateItem(olMailItem)
    Set objMailRecipients = objMail.Recipients
 
    'Get the source PST file
    'Change "John Smith" to the displaying name of your own PST file
    Set objSourcePSTFile = Application.Session.Folders("John Smith")
 
    For Each objFolder In objSourcePSTFile.Folders
        Call Processfolders(objFolder)
    Next
 
    'Change or add more email details here:
    With objMail
         .Recipients.ResolveAll
         .Subject = "Test Mail"
         .Body = "Input the mail details..."
         .Send
    End With
End Sub

Sub Processfolders(objCurrentFolder As Outlook.Folder)
    Dim objItem As Object
    Dim objContact As Outlook.ContactItem
    Dim objSubfolder As Outlook.Folder
 
    If objCurrentFolder.DefaultItemType = olContactItem Then
       For Each objItem In objCurrentFolder.Items
           If TypeOf objItem Is ContactItem Then
              Set objContact = objItem
 
              'Find all contacts in a specific color category
              If InStr(objContact.Categories, "Colleagues") > 0 Then
                 objMailRecipients.Add objContact.Email1Address
              End If
           End If
       Next objItem
    End If
 
    'Process all contact folders recursively
    If objCurrentFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.Folders
           Call Processfolders(objSubfolder)
       Next
    End If
End Sub

4. Eventually, you could run this macro just by pressing F5 key button.
5. Immediately, you will see that a new email is in your Outbox, being sent out.

Eliminate Vexing Outlook Errors

Outlook cannot be immune to errors. Hence, it is vitally important for us regular users to learn how to deal with various errors. First of all, you can try to fix them by starting Outlook in safe mode, using Scanpst or rebuilding the mail profile or repairing the MS office suite. If all fail, you can take aid of a potent external repair tool, such as DataNumen Outlook Repair.

Author Introduction:

Shirley Zhang is a data recovery expert in DataNumen, Inc., which is the world leader in data recovery technologies, including corrupted mdf and outlook repair software products. For more information visit www.datanumen.com