So legen Sie unterschiedliche Standarderinnerungszeiten für verschiedene Arten von markierten Elementen in Ihrem Outlook fest

Standardmäßig verwendet Outlook automatisch die Standarderinnerungszeit für Aufgaben für alle Arten von gekennzeichneten Elementen. Wenn Sie jedoch für markierte Elemente je nach Elementtyp eine andere Erinnerungszeit verwenden möchten, können Sie auf die in diesem Artikel vorgestellte Methode verweisen.

In Outlook können Sie die Standarderinnerungszeit für alle markierten Elemente festlegen, unabhängig vom Elementtyp. Sie können zum Menü "Datei" gehen und auf "Optionen" klicken. Anschließend sehen Sie im Fenster "Outlook-Optionen" die Option "Standarderinnerungszeit" auf der Registerkarte "Aufgaben", wie im folgenden Screenshot gezeigt.

Dennoch möchten die meisten Nutzer unterschiedliche Erinnerungszeiten für verschiedene Arten von markierten Elementen verwenden, beispielsweise „9:00 Uhr“ für markierte E-Mails und „17:30 Uhr“ für markierte Kontakte. Im Folgenden werden wir uns auf dieses Beispiel konzentrieren, um eine entsprechende Methode vorzustellen.

Legen Sie unterschiedliche Standarderinnerungszeiten für verschiedene Arten von markierten Elementen fest

1. Starten Sie zunächst die Outlook-Anwendung.
2. Rufen Sie dann den Outlook VBA-Editor mit dem Verweis auf „So führen Sie VBA-Code in Outlook aus".
3. Kopieren Sie im nachfolgenden Fenster "Microsoft Visual Basic für Applikationen" den folgenden Code in das Projekt "ThisOutlookSession".

Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objMail As Outlook.MailItem
Public WithEvents objContact As Outlook.ContactItem

Private Sub Application_Startup()
    Set objExplorer = Outlook.Application.ActiveExplorer
    Set objInspectors = Outlook.Application.Inspectors
End Sub

Private Sub objExplorer_SelectionChange()
    On Error Resume Next
    If objExplorer.Selection.Item(1).Class = olMail Then
       Set objMail = objExplorer.Selection.Item(1)
    ElseIf TypeOf objExplorer.Selection.Item(1) Is ContactItem Then
       Set objContact = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If Inspector.CurrentItem.Class = olMail Then
       Set objMail = Inspector.CurrentItem
    ElseIf Inspector.CurrentItem.Class = olContact Then
       Set objContact = Inspector.CurrentItem
    End If
End Sub

Private Sub objMail_PropertyChange(ByVal Name As String)
    If Name = "ToDoTaskOrdinal" Then
       If objMail.IsMarkedAsTask = True Then
          If objMail.TaskDueDate <> "1/1/4501" Then
             With objMail
                  .ReminderSet = True
                  'Change the reminder time for flagged emails
                  .ReminderTime = objMail.TaskDueDate & " 10:00"
                  .Save
             End With
          End If
       End If
    End If
End Sub

Private Sub objContact_PropertyChange(ByVal Name As String)
    If Name = "ToDoTaskOrdinal" Then
       If objContact.IsMarkedAsTask = True Then
          If objContact.TaskDueDate <> "1/1/4501" Then
             With objContact
                  .ReminderSet = True
                  'Change the reminder time for flagged contacts
                  .ReminderTime = objContact.TaskDueDate & " 17:30"
                  .Save
             End With
          End If
       End If
    End If
End Sub

4. Starten Sie anschließend Outlook neu, um dieses Makro zu aktivieren.
5. Von nun an wird jedes Mal, wenn Sie eine E-Mail markieren, die Erinnerungszeit am Fälligkeitsdatum der Markierung auf "10:00" gesetzt.
6. Wenn Sie einen Kontakt markieren, wird die Erinnerungszeit am Fälligkeitsdatum der Flagge auf „17:30“ gesetzt.

Outlook-Probleme flexibel angehen

In Outlook können die unterschiedlichsten Probleme auftreten. Daher ist es ratsam, sich im Vorfeld mit möglichen Lösungsansätzen vertraut zu machen. Startet Outlook beispielsweise häufig neu, sollten Sie Office reparieren oder Drittanbieter-Add-Ins deaktivieren. Ist Ihre Outlook-PST-Datei beschädigt, können Sie zunächst versuchen, … Reparaturwerkzeug für den Posteingang. Wenn dies fehlschlägt, können Sie weiterhin auf ein leistungsstarkes externes Tool zurückgreifen, z DataNumen Outlook Repair.

Einführung des Autors:

Shirley Zhang ist eine Datenrettungsexpertin in DataNumen, Inc., das weltweit führend bei Datenwiederherstellungstechnologien ist, einschließlich MDF-Wiederherstellung und Outlook-Reparatursoftwareprodukte. Für weitere Informationen besuchen Sie www.datanumen.com €XNUMX